Office: Tabelle mit 2. Arbeitsblätter

Folgendes Problem:
Habe auf dem 1. Arbeitsblatt eine Tabelle folgenden Spalten:
Anfragenr.
kunde
Projekt
Bezeichnung
Datum
Auftrag

Sobald eine Anfrage Auftrag wird bekommt die Zeile in der Spalte "Auftrag" ein "x".
Die Zeilen sind dann forlaufend nach Anfragenummern.

nun möchte ich auf dem 2. Arbeitsblatt nur die Zeilen in einer Tabelle aufführen die Auftrag geworden sind.

Im Moment sieht es so aus dass die Anfragen wo kein Auftrag geworden sind einfach als Leerzeilen übernommen worden sind.

Mein Problem, wie bekomm ich die Leeerzeilen weg (außer mit ausblenden)?

 

Hallo!

Ich glaube, diese Seite behandelt genau dein Problem:
http://www.excelformeln.de/formeln.html?welcher=28

 

Leerzeilen weg

Hallo Tyler Durden -

... also mit dem AUTOFILTER ist Dir nicht gedient, habe ich das richtig verstanden?

 

hallo.

blick da nicht durch

 

Hallo!

Ich habe neulich mal sowas ähnliches gemacht.
Schau mal rein.

 

Hallo.

Habs mir angeschaut.

Löst mein problem.
Jetzt wollt ich deine Formel in mein Arbeitsblatt übertragen, und komm auf keinen grünen Zweig.
Kannst du mir erklären wie die Formel aufgebaut ist?

 

Hallo!

Ich versuch's mal:

=WENN(ZÄHLENWENN(Liste!$D$2:$D$1000;"x")<ZEILE(A1);"";INDEX(Liste!$A$2:$A$1000;KKLEINSTE(WENN(Liste!$D$2:$D$1000="x";ZEILE($1:$999));ZEILE(A1))))

Der erste Teil
WENN(ZÄHLENWENN(Liste!$D$2:$D$1000;"x")<ZEILE(A1);""
ist ein Fehlerabfang, der verhindert, dass Fehlerwerte ausgegeben werden, wenn keine Treffer mehr vorhanden sind, also für das Verständnis der Formel erstmal "Schickimicki"...
Die Funktionalität der Formel kommt im zweiten Teil:
INDEX(Liste!$A$2:$A$1000;KKLEINSTE(WENN(Liste!$D$2:$D$1000="x";ZEILE($1:$999));ZEILE(A1)))
Mal von innen nach außen:
WENN(Liste!$D$2:$D$1000="x"...
ergibt 999x WAHR oder FALSCH, je nachdem, ob "x" auftaucht oder nicht.
Ist der Wert WAHR (taucht also "x" auf), dann gibt ZEILE(1:999) die Nummer der Zeile zurück. KKLEINSTE filtert hieraus wiederum die erst-kleinste, zweit-kleinste, dritt-kleinste, usw. heraus (der letzte Teil "ZEILE(A1)" wird beim runterziehen zu 1,2,3,...).
Der INDEX holt sich schlussendlich aus den gefundenen Zeilen die entsprechenden Werte.
Wichtig ist, dass ALLE Bereiche gleich groß sind und die Eingabe der Formel mit Strg+Shift+Enter abgeschlossen wird.

Ich hoffe, das reicht als Erklärung.
Falls nicht, dann musst du für weitere Hilfe entweder eine Beispieldatei hochladen, oder genau erklären, wo sich deine Daten befinden und wo sie gefiltert hin sollen.

 

Hallo.

Habe mal die Excel Tabelle im Anhang.
Also auf Blatt 1 sind die anzen Lieferanten aufgeführt. Und in der letzten Spalte steht Produktgruppe.
Dort wo WKZ steht diese sollen auf dem Arbeitsblatt 2 in der Spalte Lieferant erscheinen.

 

Hallo!

Dann diese Formel in B4:

=WENN(ZÄHLENWENN('Neu alle'!$T$3:$T$1000;"WKZ")<ZEILE(A1);"";INDEX('Neu alle'!$A$3:$A$1000;KKLEINSTE(WENN('Neu alle'!$T$3:$T$1000="WKZ";ZEILE($1:$998));ZEILE(A1))))

Eingabe mit Strg+Shift+Enter abschliessen und Formel runterkopieren.

 

Hallo.

Ja danke, so hats funktioniert. Jetzt bräuchte ich erneut deine hilfe. Schau mal bitte den Anhang an. Soll so ähnlich sein wie die Tabelle vorher. Wenn auf Arbeitsblatt 2 in der Spalte Auftrag ein "X" erscheint sollen die ganzen Daten der Zeile in Arbeitsblatt 3 kopiert werden. Wieder ohne die Leerzeilen.

 

Hallo!

Das ist doch das Gleiche in grün.
In Tabelle3!A2

{=WENN(ZÄHLENWENN(Tabelle2!R:R;"x")<ZEILE(A1);"";INDEX(Tabelle2!$A$3:$A$100;KKLEINSTE(WENN(Tabelle2!$R$3:$R$100="x";ZEILE($1:$98));ZEILE(A1))))}
und runterkopieren

Die restlichen Spalten holst du dir per SVERWEIS (wenn es keine doppelten Anfrage-Nr. gibt).

 

kannst du mir auch noch hilfe geben wie ich sverweis hier anwende?

 

Hallo!

In Tabelle3!B2
=SVERWEIS($A2;Tabelle2!$A:$Z;SPALTE(B$1))
und nach rechts und nach unten ausfüllen.

 

Hallo.

Habe ich alles gemacht. Jetzt rechnet er aber jedesmal ewig lange wenn ich in ein Feld einen Wert ergänze oder ändere.
Das ist sehr nervig.

 

Wieviele Zeilen hat denn deine Original-Mappe?
Die SVERWEIS-Formeln dürften eigentlich nicht die Bremse sein. Die Matrix-Formeln dagegen bei großen Bereichen schon.