Office: Tabellenblatt abhängig vom datum aus - / einblenden

Hallo, wie kann ich beim öffnen einer Excel Datei verschiedene
Tabellenblätter Datumsabhängig ein- / ausblenden?


Ich habe es so probiert:

Private Sub Workbook_Open()
If Month(Januar) Then
Worksheets("Zeitberechnung FSNFFFA").Visible = False

End If


End Sub

aber das funktioniert nicht.



Kann mir jemand eine Möglichkeit aufzeigen?



Gruß Markus

 

Hi,

Code:

If Month(Date) = 1 Then

Bis später,
Karin

 

Hallo Markus,

was bedeutet hier der Bezeichner "Januar"? Wo ist dieser definiert? Woher kommt er? Welches Datum muss im "Januar" liegen, damit das Arbeitsblatt "Zeitberechnung FSNFFFA" ausgeblendet wird?

Die Funktion "Month(Fortlaufendes_Datum)" benötigt als Parameter ein sogenanntes "fortlaufendes Datum". Da reicht es nicht, einfach nur "Januar" hinzuschreiben. Der Formelausdruck
Month(Date()) oder Month(Now())
überprüft zB., welchen Monat das Systemdatum/Systemzeit des PCs gerade aufweist.

Dim Januar As Date
Januar = DateSerial(2014,1,23)
If Month(Januar)=1 Then ...
Der vorstehende VBA-Code deklariert eine DatumZeit-Variable namens "Januar", setzt diese in der 2. Zeile auf das Datum 23.1.2014 und überprüft in der 3. Zeile, ob diese Datumsvariable ein Datum enthält, das gerade im Januar eines beliebigen Jahres liegt.

 

Seit mir bitte nicht böse aber das verstehe ich nicht.


Ich möchte ja nicht nur den 23.01.2014 abfragen sondern ich möchte folgendes:

Ich habe 12 Tabellenblätter mit den Bezeichnungen Januar ..... Dezember

Ich möchte das vom 01.01.eines Jahres bis zum 31.01.eines Jahres alles 12 Monate angezeigt werden.
ab dem 01.02. nur noch Februar bis Dezember usw.


Vielleicht ist jetzt die Aufgabenstellung etwas besser beschrieben und mir kann jemand erklären wie ich das
realisieren kann.



Danke und Gruß Markus

 

Hi Markus,

lies dir doch mal deinen ersten Beitrag und diesen jetzt durch - das sind doch 2 völlig verschiedene Dinge...

Ich bin jetzt vom geschilderten Sachverhalt in deinem letzten Beitrag ausgegangen:

Code:

Private Sub Workbook_Open()
   Dim wksTab As Worksheet
   Dim arrTabs()
   arrTabs = Array("Januar", "Februar", "März", "April", "Mai", "Juni", "Juli", "August", "September", "Oktober", "November", "Dezember")
   For Each wksTab In Worksheets
      If Not IsError(Application.Match(wksTab.Name, arrTabs(), 0)) Then
         wksTab.Visible = Application.Match(wksTab.Name, arrTabs(), 0) >= Month(Date)
      End If
   Next wksTab
End Sub

Bis später,
Karin

 

Ei suppi, vielen Dank das funktioniert.



Liebe Grüße Markus