Office: Tabellenblatt(Namen) aus Zelle beziehen

Hi Paul,

vielleicht wäre das eine Möglichkeit, dass in den SVERWEIS-Formeln der Tabellenname ausgetauscht wird, sobald in eine Zelle der Tabellenname eingetragen wird (im Beispiel D1 - musst du an deine Bedingungen anpassen)

Code:

Option Explicit
Const strPfadDatei As String = "'D:\Excel\Office-hilfe.com\PaulW90\[PaulW90.xls]"

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rngZelle As Range
    Dim strFormel As String
    Dim intStart As Integer
    Dim intEnde As Integer
    If Target.Address = "$D$1" Then
        Application.EnableEvents = False
        Application.ScreenUpdating = False
        If TabelleExistiert(Target.Value) Then
            For Each rngZelle In ActiveSheet.UsedRange.SpecialCells(xlCellTypeFormulas)
                If InStr(rngZelle.FormulaLocal, "SVERWEIS(") > 0 And InStr(rngZelle.FormulaLocal, strPfadDatei) > 0 Then
                    intStart = InStrRev(rngZelle.FormulaLocal, "]") + 1
                    intEnde = InStrRev(rngZelle.FormulaLocal, "!") - 1
                    strFormel = Application.Substitute(rngZelle.FormulaLocal, Mid(rngZelle.FormulaLocal, intStart, intEnde - intStart), Target)
                    rngZelle.FormulaLocal = strFormel
                End If
            Next rngZelle
        Else
            MsgBox "Diese Tabelle gibt es nicht"
        End If
        Application.ScreenUpdating = True
        Application.EnableEvents = True
    End If
End Sub

Function TabelleExistiert(strTableName As String) As Boolean
' Code von bst [url]http://clever-forum.de/read.php?11,233409,233508#msg-233508[/url]
   Dim strText As String
   strText = strPfadDatei & strTableName & "'!R1C1"
   Application.DisplayAlerts = False
   On Error Resume Next
   TabelleExistiert = Not (IsError(Application.ExecuteExcel4Macro(strText)))
   On Error GoTo 0
   Application.DisplayAlerts = True
End Function

Bis später,
Karin