Office: Tablleninhalt richtig zuordnen

einen schönen guten abend an alle...


hoffe jemand kann mir einen ansatz für folgendes problem geben:

Tabelle:

-----A-----B-----C-----Beschreibung-----Material

-----ja----ja----nein---Produkt B---------Holz

-----nein-ja---nein----Produkt D---------Metall

-----nein--ja--ja------Produkt R----------Metall


soll so geordnet werden:


A
Produkt B-----Holz

B
Produkt B-----Holz
Produkt D-----Metall
Produkt R-----Metall

C
Produkt R -----Metall

also wenn bei einem Produkt ein ja Steht soll es zu A, B, oder C zugeordnet werden


hmmm....hoffe das das einigermaßen gescheit erklärt ist, damit jemand helfen kann


grüße
sascha

 

Hallo!

Reicht dir dafür nicht der Autofilter, bzw. Spezialfilter?
Sonst musst du per langer Matrixformel oder gar VBA da ran...

 

hallo schatzi...


hab es mit einer wenn formel probiert zu lösen,... funktioniert soweit auch,...

jetzt hab ich nur das problem, dass in der neuen tabelle immer so viele leerzeilen sind.....(wenn A,B,C "nein" ist)

die neue tabelle lege ich in eine combobox, wo die leerzeilen auch mit ausgegeben werden...->>> kann man das verhindern???

lieben gruß
sascha

 

Hallo!

Wie gesagt, dann wird's echt länger und (rechen)intensiver...
In G1 gibst du deinen "Wunschbuchstaben" ein.

	A	B	C	D	E	F	G	H
1	A	B	C	Beschreibung	Material		B
2	ja	ja	nein	Produkt B	Holz		Produkt B	Holz
3	nein	ja	nein	Produkt D	Metall		Produkt D	Metall
4	nein	ja	ja	Produkt R	Metall		Produkt R	Metall

Zelle	Formel
G2	{=WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN($A:$A;;VERGLEICH($G$1;$1:$1;)-1);"ja")<ZEILE(A1);"";INDEX(D:D;KKLEINSTE(WENN(BEREICH.VERSCHIEBEN($A$2:$A$999;;VERGLEICH($G$1;$1:$1;)-1)="ja";ZEILE($2:$999));ZEILE(A1))))}
H2	{=WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN($A:$A;;VERGLEICH($G$1;$1:$1;)-1);"ja")<ZEILE(B1);"";INDEX(E:E;KKLEINSTE(WENN(BEREICH.VERSCHIEBEN($A$2:$A$999;;VERGLEICH($G$1;$1:$1;)-1)="ja";ZEILE($2:$999));ZEILE(B1))))}
G3	{=WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN($A:$A;;VERGLEICH($G$1;$1:$1;)-1);"ja")<ZEILE(A2);"";INDEX(D:D;KKLEINSTE(WENN(BEREICH.VERSCHIEBEN($A$2:$A$999;;VERGLEICH($G$1;$1:$1;)-1)="ja";ZEILE($2:$999));ZEILE(A2))))}
H3	{=WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN($A:$A;;VERGLEICH($G$1;$1:$1;)-1);"ja")<ZEILE(B2);"";INDEX(E:E;KKLEINSTE(WENN(BEREICH.VERSCHIEBEN($A$2:$A$999;;VERGLEICH($G$1;$1:$1;)-1)="ja";ZEILE($2:$999));ZEILE(B2))))}
G4	{=WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN($A:$A;;VERGLEICH($G$1;$1:$1;)-1);"ja")<ZEILE(A3);"";INDEX(D:D;KKLEINSTE(WENN(BEREICH.VERSCHIEBEN($A$2:$A$999;;VERGLEICH($G$1;$1:$1;)-1)="ja";ZEILE($2:$999));ZEILE(A3))))}
H4	{=WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN($A:$A;;VERGLEICH($G$1;$1:$1;)-1);"ja")<ZEILE(B3);"";INDEX(E:E;KKLEINSTE(WENN(BEREICH.VERSCHIEBEN($A$2:$A$999;;VERGLEICH($G$1;$1:$1;)-1)="ja";ZEILE($2:$999));ZEILE(B3))))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

Vielleicht wäre hier anstatt des Formelmonsters eine Hilfsspalte hilfreich, in der du die Treffer durchnummerieren lässt.

 

mein gott,...

das ist echt beeindruckend,...wie machst du das so schnell, ? da muss mann (frau) ja richtig richtig fit seit in excel um sowas so schnell umsetzen zu können...


aber vielen vielen dank ,werd es gleich ausprobieren

lieben gruß
sascha

 

Hallo!

Mach's lieber mit Hilfsspalte!
Das ist schneller und leichter angepasst.

	A	B	C	D	E	F	G	H	I	J
1	A	B	C	Beschreibung	Material		Hilfe		B
2	ja	ja	nein	Produkt B	Holz		1		Produkt B	Holz
3	nein	ja	nein	Produkt D	Metall		2		Produkt D	Metall
4	nein	ja	ja	Produkt R	Metall		3		Produkt R	Metall

Zelle	Formel
G2	=ZÄHLENWENN(BEREICH.VERSCHIEBEN(A$2:A2;;VERGLEICH(I$1;$1:$1;)-1);"ja")
I2	=WENN(ZEILE(A1)>MAX($G:$G);"";INDEX(D:D;VERGLEICH(ZEILE(A1);$G:$G;)))
J2	=WENN(ZEILE(B1)>MAX($G:$G);"";INDEX(E:E;VERGLEICH(ZEILE(B1);$G:$G;)))
G3	=ZÄHLENWENN(BEREICH.VERSCHIEBEN(A$2:A3;;VERGLEICH(I$1;$1:$1;)-1);"ja")
I3	=WENN(ZEILE(A2)>MAX($G:$G);"";INDEX(D:D;VERGLEICH(ZEILE(A2);$G:$G;)))
J3	=WENN(ZEILE(B2)>MAX($G:$G);"";INDEX(E:E;VERGLEICH(ZEILE(B2);$G:$G;)))
G4	=ZÄHLENWENN(BEREICH.VERSCHIEBEN(A$2:A4;;VERGLEICH(I$1;$1:$1;)-1);"ja")
I4	=WENN(ZEILE(A3)>MAX($G:$G);"";INDEX(D:D;VERGLEICH(ZEILE(A3);$G:$G;)))
J4	=WENN(ZEILE(B3)>MAX($G:$G);"";INDEX(E:E;VERGLEICH(ZEILE(B3);$G:$G;)))

 

Dankeschön!

...dass sieht schon um einiges "leichter" aus.....

werd mal versuchen, die formeln zu verstehen, dass ich das dann auch fortführen kann :)


lieben gruß
sascha

 

Hallo!

Genau!
Denn die Matrix-Variante kann gerade bei langen Listen auch gähnend langsam werden, weil jede Zelle doppelt und dreifach (bzw. tausendfach) berechnet wird...

PS:
Die Funktion BEREICH.VERSCHIEBEN ist auch hier recht ausführlich beschrieben. (Für den "Lern-Effekt")