Office: Teil aus Zelle in andere Zelle extrahieren

Hallo Zusammen,

Ich will aus einer Zelle die zweite Angabe in eine andere Zelle schreiben .
Ich habe es versucht mit der Formen =links aber da nimmt er ja den ganzen linken Teil mit.
Die träge sehen so aus:
Spalte B Spalte C
157-1"-K-117A-20456-S 1"
157-1½"-K-A3-1710-S 11/2"
157-1"-K-322A-N99-29265-W
61-11/2"-K-A3-6103
61-2"-K-A3-6106
61-1½"-K-322A-N-28800-W
61-1½"-K-A3-6006-H
61-1½"-K-A1-66007-S
10-1½"-K-A3-6017-S
61-2"-K-A1-6002-S
61-2"-K-A1-6004-S

Quasi soll eigentlich nur die Zollangabe extrahiert werden.
Hab es auch schon mit der Funktion =Teil() probiert aber da ich ja als erste Zahl immer unterschiedliche längen habe und als Zollangaben auch unterschiedliche Längen habe ist es ein wenig kompliziert.
Was halt immer gleich ist sind die "-" vor und nach der Zoll Angabe.

Hat jemand einen Idee wie man das mache könnte einfach nur mit ner Formel?

Gruß CX

 

Hola,
TEIL() kannst du schon nehmen.
=FINDEN("-";B2) gibt die Position vom ersten "-" aus, =FINDEN("""";B2) die Position des ersten ".
Damit solltest du etwas basteln können
Gruß,
steve1da

 

Moin!
Excel-Version?
Grob mit INDEX oder SPALTENWAHL iVm TEXTTEILEN
Bin noch nicht am Rechner, später mehr.

Gruß Ralf

 

Hi,

Office 365:
=INDEX(TEXTTEILEN(A1;"-");2)

Vorher:
=TEIL(A1;FINDEN("-";A1)+1;FINDEN("""";A1)-FINDEN("-";A1))

 

Mit Excel 365:

=TEXTVOR(TEXTNACH(B1;"-");"-")

 

Hallo
@ Boris

ja eigentlich haben wir hier MSO365
aber ich glaube mein Excel hat die Funktion =INDEX(TEXTTEILEN... irgendwie nicht

Mit der Formel bekomm ich bei 1 1/2" nur die 2" angezeigt.

@ BoskoBiati
bei deiner Formel bekomm ich auch nicht raus.
Ich denke es liegt dann wohl am Office.


Hab gerad noch mal geschaut wir haben das MSO Standard 2016.

 

Hi,

wenn Dein Excel die Funktion TEXTTEILEN nicht kennte, dann erhieltest du #NAME?. Da das nicht der Fall ist, zeig bitte mal Deine Datei mit den fehlerhaften Formelergebnissen, denn ich habe die Formel an alle Deinen Beispielen getestet.

 

Mal die gesammelten Werke:

	A	B	C	D	E
1	157-1"-K-117A-20456-S 1"	1"	1"	1"	1"
2	157-1½"-K-A3-1710-S 11/2"	1½"	1½"	1½"	1½"
3	157-1"-K-322A-N99-29265-W	1"	1"	1"	1"
4	61-11/2"-K-A3-6103	11/2"	11/2"	11/2"	11/2"
5	61-2"-K-A3-6106	2"	2"	2"	2"
6	61-1½"-K-322A-N-28800-W	1½"	1½"	1½"	1½"
7	61-1½"-K-A3-6006-H	1½"	1½"	1½"	1½"
8	61-1½"-K-A1-66007-S	1½"	1½"	1½"	1½"
9	10-1½"-K-A3-6017-S	1½"	1½"	1½"	1½"
10	61-2"-K-A1-6002-S	2"	2"	2"	2"
11	61-2"-K-A1-6004-S	2"	2"	2"	2"

Zelle	Formel
B1	=INDEX(TEXTTEILEN(A1;"-");2)
C1	=GLÄTTEN(TEIL(WECHSELN($A1;"-";WIEDERHOLEN(" ";9));SPALTE(B1)*9-8;9))
D1	=TEIL(A1;FINDEN("-";A1)+1;FINDEN("""";A1)-FINDEN("-";A1))
E1	=TEXTVOR(TEXTNACH(A1;"-");"-")

 

Hallo,

in Ergänzung zu der Formelauflistung von Ralf könnte man in Zelle F1 folgende Formel einfügen:
=REGEXEXTRACT(A1:A11;"-(.+?"")";2)
Sie ist aber zur Zeit nur in Excel365-Insider verfügbar.

 

Sehr schön!
Ich hatte zwar auch an REGEXEXTRACT() gedacht, aber auf das Pattern bin ich nicht gekommen.
Ich muss mich da mal dringend intensiv einlesen!
Kennst Du da ein gutes Tutorial?

Gruß Ralf

 

Da wir hier so viel Spaß mit den diversen Lösungen haben, hier noch eine Spill-Variante ;-)

=MAP(A1:A11;LAMBDA(a;INDEX(TEXTTEILEN(a;"-");2)))

 

Ihr seid doch alle komplett bekloppt und durchgeknallt!

Liebs!

(Aber ohne SCAN lass ich euch hier nicht raus!)

 

Hallo Ralf,

laut Info in einem Microsoft-Hilfeforum zu den 3 neuen REGEX-Funktionen soll es sich dabei um die PCRE2-Variante (Perl Compatible Regular Expressions) handeln. Mit dem Link PCRE - Perl-kompatible reguläre Ausdrücke gelangst du direkt auf die zuständige Homepage - mit all den Links zu diversen weiteren Informationen.
(Das Problem mit RegExpr ist, dass es hier sehr viele unterschiedliche Varianten gibt - sowohl bei Einschränkungen als auch Erweiterungen)

 

Aber ohne SCAN lass ich euch hier nicht raus!

Kein Problem ;-)

=SCAN("";A1:A11;LAMBDA(a;b;INDEX(TEXTTEILEN(b;"-");2)))

 

Hallo @schatzi,

=WEGLASSEN(REDUCE("";$A$1:$A$11;LAMBDA(a;b;VSTAPELN(a;INDEX(TEXTTEILEN(b;"-");2))));1)