Office: Teilergebnisse kopieren

Hallo,

gibt es eine Möglichkeit, wenn ich eine Tabelle mit Teilergebnissen habe, diese in eine andere Tabelle zu kopieren. Es sollen aber nur die Summen kopiert werden, nicht die Zwischenzeilen.

Vielen Dank schon mal im Voraus!!

mfg an alle

 

Hallo,

soweit ich weiß, kann man das nur mit VBA (vernünftig) realisieren:

Nachfolgendes Makro geht davon aus,

1) dass der Quellbereich (der die Teilergebnisformeln enthält) sich im Arbeitsblatt Tabelle1 um die Zelle A1 herum befindet und die linke obere Ecke des Zielbereichs sich im Arbeitsblatt Tabelle2 in Zelle A1 befindet.
Falls das bei Dir anders sein sollte, musst Du die beiden speziell kommentierten Makrozeilen anpassen, was in der Regel nicht allzu schwierig sein sollte.

2) dass, falls in einer Zeile des Quellbereichs eine Teilergebnsiformel entdeckt wird, alle Zellwerte/Zahlenformate dieser Zeile in eine neue Zeile des Zielbereichs kopiert werden.

Code:

Public Sub Teilergebnisse_kopieren()
  Dim RgQu As Range, RgZl As Range
  Dim Zeile As Range, Zelle As Range
  Dim ZeileMitTeilerg As Boolean
  Dim ZeileZl As Long
  
  'Quellbereich: Alle Zellen in der Umgebung von Zelle 'Tabelle1!A1'
  '              bis zur 1. Leerzeile und 1. Leerspalte
  Set RgQu = Worksheets("Tabelle1").Range("A1").CurrentRegion
  
  'Zielbereich: Linke obere Zelle ist 'Tabelle2!A1'
  Set RgZl = Worksheets("Tabelle2").Range("A1")
  
  ZeileZl = 0
  
  For Each Zeile In RgQu.Rows
  
    ZeileMitTeilerg = False
    
    For Each Zelle In Zeile.Cells
      If Zelle.Formula Like "*SUBTOTAL(*" Then ZeileMitTeilerg = True: Exit For
    Next Zelle
    
    If ZeileMitTeilerg Then
      ZeileZl = ZeileZl + 1
      Zeile.Copy
      RgZl.Cells(ZeileZl, 1).PasteSpecial Paste:=xlPasteValuesAndNumberFormats
    End If
    
  Next Zeile
  
  Application.CutCopyMode = False
End Sub

Zur Installation des Makros:
1) Obigen Code markieren und in die Zwischenablage kopieren (Tastenkombination Strg+C ).
2) In Excel in den VBA-Editor gehen (Tastenkombination Alt+F11)
3) In ein allgem. Codemodul (Menü des VBA-Editors: Einfügen > Modul) den Code aus der Zwischenablage einfügen (Tastenkombination Strg+V).
4) Danach wieder nach Excel zurückgehen (Tastenkombination Alt+F11).

Aufruf des Makros:
Die Tastenkombination Alt+F8 drücken und anschließend die EINGABE-Taste drücken, um das Makro 'Teilergebnisse_kopieren' auszuführen.