Office: Text aus anderen Spalten herauslesen

Hallo zusammen,

hier mein Problem:

In der Spalte B2 steht ein Text, der zusammengefügt ist aus zig verschiedenen Sätzen, z.B. an welchen Projekten eine Person beteiligt ist. Nun habe ich in der Zelle C1 einen Satz stehen (z.B Projekt/Kst-Reduzierung/Energie/Leiter) und möchte wissen ob dieser Text in der Zelle B2 enthalten ist. Wenn ja, soll er eine 1 ausgeben (in C2), falls nicht eben die 0.
Noch besser wäre es wenn er für den Fall einer 1 die letzten Zeichen bis zum Slash ausgeben könnte, in dem Beispiel Leiter.

Da ich hier knapp 3000 Datensätze abfragen möchte, muss die Zelle mit einem Doppelklick rechts unten nach unten kopiert werden und eben die Zellenbezeichnungen immer eins runter rutschen.

Ich hab versucht das ganze mit dem Summe(Zählenwenn... Befehl aus einem anderen Beitrag zu lösen, habe es aber dabei nicht hinbekommen.

Ich füge noch eine Beispieldatei an, die so in die Richtung meines Problems geht. Hoffentlich habe ich das ganze halbwegs verständlich ausgedrückt und jemand kann mir weiterhelfen.

Vielen Dank und noch nen schönen Sonntag,

weisch

 

Hallo weisch,

in B3 zum kopieren nach rechts und nach unten:

Code:

=N(ISTZAHL(FINDEN(B$2;$A3)))

 

Hallo weisch,

für die Ausgabe des Textes (sorry, hatte ich überlesen), nimm diese Formel in B3 zum rechts/unten kopieren:

Code:

=WENN(ISTZAHL(FINDEN(B$2;$A3));RECHTS(B$2;LÄNGE(B$2)-MAX((TEIL(B$2;ZEILE($1:$100);1)="/")*ZEILE($1:$100)));0)

Die Eingabe der Formel mit Strg+Shift+Enter abschliessen!

 

Hallo fridgenep,

vielen Dank für die schnelle Antwort! Werd das ganze morgen in aller Früh ausprobieren und dir nochmals bescheid sagen.

mfg
weisch

 

Hallo fridgenep,

also die erste Formel schmeisst mir die eine 0 oder 1 aus, so wie geplant. die zweite formel jedoch gibt nicht den letzten teil aus, sondern den kompletten Text, ausser genau den letzten Teil den ich eigentlich brauch. könntest du mir kurz die Formel erklären, da ich diese noch nicht kenne.
dann sollt ichs schaffen :)

Vielen Dank schon mal im Voraus!

VG
weisch

 

Hallo Weisch,

du musst die Eingabe der Formel mit Strg+Shift+Enter abschliessen.

Das ist eine Matrix-Formel.

 

Hallo fridgenep,

das hatte ich übersehen. Jetzt zeigt er mir eine leere Zeile an, wenn der Text enthalten ist. Im Fall das es nicht enthalten ist kommt die 0 bzw. der "-" Bindestrich den ich dort haben möchte.

 

Hallo Weisch,

sorry, ich kann deine Beobachtungen/Ergebnisse nicht nachvollziehen.

Im Anhang dein Beispiel mit meinen Formeln.

Viel Erfolg.

 

Hallo fridgenep,

hab einen Logikfehler in meinem Beispiel gefunden. In der Überschrift kommt der letzte Teil z.B. Schuhgröße 47 nicht vor, er soll die 47 aus der linken Spalte rausziehen und wiedergeben.

Habe das Beispiel nun korrigiert, das zeigt nun dieselben Leerzeichen an wie ich sie in der richtigen Datei habe.
Könntest du da nochmal einen Blick drauf werfen?

Vielen Dank auf jeden Fall, hast mir bislang schon unendlich weiter geholfen.

VG
weisch

 

Hallo Weisch,

okay, nun wird die Aufgabenstellung schon ein bisschen interessanter. :-D

Hintergrundinformation:
Die Formel funktioniert nur, wenn es in einem Suchstring (B2:D2) keine Leerzeichen gibt. Ein Leerzeichen darf nur nach einem Komma verwendet werden. Wenn du aber auch Wörter (Suchstrings) mit Leerzeichen brauchst, dann baue ich es auf Kommata um. Musst nur sagen, bzw. es alleine anpassen.

Folgende Formel in B3:

Code:

=WENN(ISTZAHL(FINDEN(B$2;$A3));WENN(ISTZAHL(FINDEN(" ";$A3;FINDEN(B$2;$A3)));TEIL($A3;FINDEN(B$2;$A3)+LÄNGE(B$2);FINDEN(" ";$A3;FINDEN(B$2;$A3))-1-FINDEN(B$2;$A3)-LÄNGE(B$2));RECHTS($A3;LÄNGE($A3)-FINDEN(B$2;$A3)-LÄNGE(B$2)+1));0)

Das ist keine Matrixformel. Also einfach eingeben und mit Enter bestätigen.

Anbei dein Beispiel:

 

Hallo fridgenep,

schön das ich deinen ehrgeiz wecken konnte :)

also ich hab die neuste formal nun in meine datei eingepflanzt und angepasst, jetzt gibt er mir in jeder trefferzeile ein #Wert aus. bei den nicht-treffern kommt eine 0.
ich kann mir das nicht erklären, ausser das die textfelder leerzeichen beinhalten.
diese leerzeichen stecken überall z.B /Communication Networks/. nun habe ich versucht mittels strg+H die leerzeichen komplett zu entfernen, das macht er allerdings nicht da einige zellen zuviel text enthalten ("Formal zu lang" lautet die fehlermeldung).

mit dem glättenbefehl bekomm ich auch nur die leerzeichen am anfang oder ende des textes weg.
Optimal wäre ein underscore (_) anstatt der leerzeichen im text.

so wie ich dich verstanden habe würdest du jetzt die leerzeichen mit kommas ersetzen? es sind ja kommas im text enthalten, diese trennen einzelne punkte von einander (z.B C&A/1.Stock/Herrenabteilung/Schuhe/47, C&A/Erdgeschoss/Reduziert/Hosen/34-32, fridgenep testet).

Würden da mehr kommas nicht stören?

VG
weisch

 

Hallo,

ich habe nicht gesagt, das Leerzeichen durch Kommas ersetzt werden müssen. Deine Werte in Spalte A sollen so zusammengesetzt sein.

Wort1/Text/Text/test, Wort2/......

Wichtig ist, im ersten Teil (Wort1/Text/Text/test) gibt es kein Leerzeichen, danach kommt ein Komma und dann ein Leerzeichen. Wenn du das so machst, dann passt es auch. Wenn du willst, dass ich mir deine Originaltabelle anschaue, dann schick mir die Datei bzw. einen Download-Link per PN.

 

Hallo fridgenep,

ich kann dir leider nicht die original datei zuschicken, aber ich habe dir jetzt mal per pn den inhalt einer zelle zugeschickt (ein wenig abgeändert). wenn du mir nen weg zeigst, die leerzeichen zu entfernen, dann müsste ich den rest hinbekommen.
mein üblicher weg wäre mit strg+H ein leerzeichen zu suchen und durch nichts zu ersetzen. dann fallen leerstellen normalerweise weg. nur in diesem fall gibt er mir eine fehlermeldung (die formel ist zu lang).

VG
weisch

 

Hallo Weisch,

bearbeite deinen Ausdruck bitte einmal mit dieser Formel und probiere dann ob meine letzte Lösung greift:

Code:

=WECHSELN(WECHSELN(A1;" ";);",";", ")

 

Hallo fridgenep,

so funktionierts!!! jetzt is hoffentlich das letzte problem gelöst (pflicht) und ich kann anfangen die ganze datei zusammen zu setzen (kür).

1000 dank für deine super hilfe!!!

VG
weisch