Office: Text mit Zahlen

Servus Zusammen,

ich bräuchte eine Formel die mir gleichen Text addiert bei ungleichen Zahlen

z.b. kauf 1234
verkauf4567
kauf 3456
verkauf 7890


summe kauf
summe verkauf

Danke für die Hilfe

flug57

 

Hallo!

Das ginge z. B. mit SUMMEWENN():

	A	B	C	D
1	Kauf	1234	Kauf	4690
2	Verkauf	4567	Verkauf	12457
3	Kauf	3456
4	Verkauf	7890

Zelle	Formel
D1	=SUMMEWENN(A$1:A$100;C1;B$1:B$100)
D2	=SUMMEWENN(A$1:A$100;C2;B$1:B$100)

Oder mit Pivot-Tabelle:
Dies wäre z. B. Deine Tabelle (Überschriften notwendig):

	A	B
1	Transaktion	Anzahl
2	Kauf	1234
3	Verkauf	4567
4	Kauf	3456
5	Verkauf	7890

Tabelle markieren.
DATEN > PIVOT-TABLE > FERTIGSTELLEN.
Ziehe dann das Element Transaktionen auf die Zeilenfelder und Anzahl auf die Datenfelder. Ergebnis:

	A	B
3	Summe von Anzahl
4	Transaktion	Summe
5	Kauf	4690
6	Verkauf	12457
7	Gesamtergebnis	17147

 

Vielen Dank Krino,

A B
1 kauf 1234
2 verkauf 2345
3 kauf 2345
4 verkauf 4567
5
6

Bitte nochmals um Hilfe, wie ist die Formel, wenn Text und Zahl in einer Zelle sind und das Ergebnis z.b. in Zeile A6 sich auf die anzahl kauf ohne die Zahl beziehen soll. Als wäre die Zahl nur eine Bezeichnung von kauf

Danke nochmals
flug57

 

Hallo!

Ich war mir bei der ersten Anfrage nicht ganz sicher, ob das vielleicht alles in einer Zelle steht.

Man würde sich viel unnötige Mühe ersparen, wenn Du Dich entschließen könntest, den Text von der Zahl zu trennen.

Dazu brauchst Du nur hinter Spalte A eine neue leere Spalte B anzulegen, dann Spalte A markieren und:

DATEN > TEXT IN SPALTEN; dann dem Menü folgen, dabei als Trennzeichen das Leerzeichen angeben.

Wie wär's damit?

------------------------------------------------------------------------------

Sollte das nicht möglich sein, hier eine Lösung mit komplizierter Formel:

	A	B	C
1	kauf 1234	kauf	3579
2	verkauf 2345	verkauf	6912
3	kauf 2345
4	verkauf 4567

Zelle	Formel
C1	=SUMMENPRODUKT((LINKS(A$1:A$4;FINDEN(" ";A$1:A$4)-1)=B1)*(TEIL(A$1:A$4;FINDEN(" ";A$1:A$4)+1;99)))
C2	=SUMMENPRODUKT((LINKS(A$1:A$4;FINDEN(" ";A$1:A$4)-1)=B2)*(TEIL(A$1:A$4;FINDEN(" ";A$1:A$4)+1;99)))

------------------------------------------------------------------------------

Oder möchtest Du nur wissen, wie oft "kauf" bzw. "verkauf" vorkommt?
Dann so:

	A	B	C
1	kauf 1234	kauf	2
2	verkauf 2345	verkauf	2
3	kauf 2345
4	verkauf 4567

Zelle	Formel
C1	=SUMMENPRODUKT(1*(LINKS(A$1:A$4;FINDEN(" ";A$1:A$4)-1)=B1))
C2	=SUMMENPRODUKT(1*(LINKS(A$1:A$4;FINDEN(" ";A$1:A$4)-1)=B2))