Office: (Office 2007) Text per VBA in bestimmter Zelle erweitern

Hallo,

ich habe folgendes vor:

Alle Eingaben in den Zellen B3, B5, B8 und B13 sollen, falls klein geschrieben, nach Eingabe automatisch gross geschrieben werden - das habe ich geschafft.

Was ich aber ich hinbekomme:
In Zelle C17 steht der Text "Verzögert auf: ". Ich will erreichen, daß wenn ein Datum entweder in die Zelle direkt oder über die Eingabeleiste oben eingetragen wird, der Text "Verzögert auf: 04.11.2017" erscheint.
Wenn ich über die Leiste oben die Eintragung vornehme, wird ja automatisch das Datum hinter dem Text eingetragen.
Bei Eingabe über die Zelle wird der Text jedoch überschrieben.

Gibt es hierfür eine Lösung?

Die entsprechende Datei habe ich angefügt.

Gruß
Werner

 

Hi Werner,

eine Möglichkeit:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
'Quelle: Frank Kabel; umgeschrieben und ergänzt 05.11.17
    If Target.Cells.Count > 1 Then Exit Sub
    If Not Intersect(Target, Me.Range("B3:B9,B11:B14")) Is Nothing Then
        On Error GoTo CleanUp:
        With Target
            If .Value <> "" Then
                Application.EnableEvents = False
                .Value = UCase(.Value)
            End If
        End With
    End If
    If Target.Cells(1).Address(False, False) = "C17" Then
        On Error GoTo CleanUp:
        If IsDate(Target.Value) Then
            Application.EnableEvents = False
            Target = "Verzögert auf: " & Target
        End If
    End If
CleanUp:
    Application.EnableEvents = True
End Sub

Bis später,
Karin

 

Super! Genauso hab ich mir das vorgestellt. Auch wenn ich das ganze Script nicht ganz verstehe, bin ich happy, daß Du mir geholfen hast.

LG
Werner

 

Hi Werner,

ich habe den Code mal mit ein paar Kommentaren versehen - vielleicht helfen sie dir ihn besser zu verstehen:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
'Quelle: Frank Kabel; umgeschrieben und ergänzt 05.11.17
    ' wenn mehrere Zellen selektiert dann beenden
    If Target.Cells.Count > 1 Then Exit Sub
    ' Eingabe erfolgte im Berich B3:B9 oder B11:B14
    If Not Intersect(Target, Me.Range("B3:B9,B11:B14")) Is Nothing Then
        ' Falls ein Fehler auftritt direkt zu CleanUp springen um Reaktion auf Eingabe wieder einzuschalten
        On Error GoTo CleanUp:
        ' bezogen auf die Eingabe
        With Target
            ' Eingabe ist nicht leer
            If .Value <> "" Then
                ' Reaktion auf Eingabe abschalten
                Application.EnableEvents = False
                ' eingegebenen Inhalt in Großbuchstaben umwandeln
                .Value = UCase(.Value)
            End If
        End With
    End If
    ' Eingabe erfolgte in C17
    If Target.Cells(1).Address(False, False) = "C17" Then
        ' Falls ein Fehler auftritt direkt zu CleanUp springen um Reaktion auf Eingabe wieder einzuschalten
        On Error GoTo CleanUp:
        ' Eingabe ist ein Datum
        If IsDate(Target.Value) Then
            ' Reaktion auf Eingabe abschalten
            Application.EnableEvents = False
            ' Zellinhalt ersetzen durch Text + Eingabe
            Target = "Verzögert auf: " & Target
        End If
    End If
CleanUp:
    ' Reaktion auf Eingabe einschalten
    Application.EnableEvents = True
End Sub

Bis später,
Karin

 

Danke für deine Mühe. Ich hatte von der Überlegung her diesen Ansatz gedacht:

"Wenn Länge von Zelle C17" <= "10" (05.11.2017 gleich 10 Stellen), dann C17 = "Verzögert auf: " & Zellinhalt von C17.
Ansonsten C17 = "Verzögert auf: "

Aber dein Ansatz ist noch besser.

Gruß
Werner