Office: Text transponieren

Hallo zusammen,

Ich habe eine Tabelle mit unterschiedlichen Nummern in Spalte A, die sich jedoch wiederholen. Zu diesen Nummern gibt es in Spalte B unterschiedliche Texte. Ich möchte nun eine neue Tabelle erstellen, in denen in einer Spalte untereinander jeweils nur einmal eine Nummer steht und in den Spalten daneben alle möglichen Texte jeweils in einer Zelle.

Beispiel:





Oben ist die Form wie meine Daten momentan aussehen, unten wie sie sein sollen.



Vielen Dank schonmal für eure Mühe!

Gruß, Christinschen

 

Hallo!

	A	B	C	D	E	F	G	H
1	Nummer	Text			1	Apfel	Birne	Banane
2	1	Apfel			2	Tomate	Apfel
3	1	Birne			3	Kiwi	Birne	Mango
4	1	Banane			4	Traube
5	2	Tomate
6	2	Apfel
7	3	Kiwi
8	3	Birne
9	3	Mango
10	4	Traube

Zelle	Formel
E1	=MIN(A:A)
F1	{=WENN(SPALTE(A$1)>ZÄHLENWENN($A:$A;$E1);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E1;ZEILE($2:$999));SPALTE(A$1))))}
G1	{=WENN(SPALTE(B$1)>ZÄHLENWENN($A:$A;$E1);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E1;ZEILE($2:$999));SPALTE(B$1))))}
H1	{=WENN(SPALTE(C$1)>ZÄHLENWENN($A:$A;$E1);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E1;ZEILE($2:$999));SPALTE(C$1))))}
E2	=KKLEINSTE(A:A;ZÄHLENWENN(A:A;"<="&E1)+1)
F2	{=WENN(SPALTE(A$1)>ZÄHLENWENN($A:$A;$E2);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E2;ZEILE($2:$999));SPALTE(A$1))))}
G2	{=WENN(SPALTE(B$1)>ZÄHLENWENN($A:$A;$E2);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E2;ZEILE($2:$999));SPALTE(B$1))))}
H2	{=WENN(SPALTE(C$1)>ZÄHLENWENN($A:$A;$E2);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E2;ZEILE($2:$999));SPALTE(C$1))))}
E3	=KKLEINSTE(A:A;ZÄHLENWENN(A:A;"<="&E2)+1)
F3	{=WENN(SPALTE(A$1)>ZÄHLENWENN($A:$A;$E3);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E3;ZEILE($2:$999));SPALTE(A$1))))}
G3	{=WENN(SPALTE(B$1)>ZÄHLENWENN($A:$A;$E3);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E3;ZEILE($2:$999));SPALTE(B$1))))}
H3	{=WENN(SPALTE(C$1)>ZÄHLENWENN($A:$A;$E3);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E3;ZEILE($2:$999));SPALTE(C$1))))}
E4	=KKLEINSTE(A:A;ZÄHLENWENN(A:A;"<="&E3)+1)
F4	{=WENN(SPALTE(A$1)>ZÄHLENWENN($A:$A;$E4);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E4;ZEILE($2:$999));SPALTE(A$1))))}
G4	{=WENN(SPALTE(B$1)>ZÄHLENWENN($A:$A;$E4);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E4;ZEILE($2:$999));SPALTE(B$1))))}
H4	{=WENN(SPALTE(C$1)>ZÄHLENWENN($A:$A;$E4);"";INDEX($B:$B;KKLEINSTE(WENN($A$2:$A$999=$E4;ZEILE($2:$999));SPALTE(C$1))))}

Achtung, Matrixformel enthalten!Die geschweiften Klammern{} werden nicht eingegeben.Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

 

edit:

Die Formel aus E2 kannst du runterziehen, die Formel aus F1 sowohl nach rechts wie auch nach unten.

 

Puuh, Schatzi- Du bist soo schnell!!

Was ist denn, wenn die Nummern nicht fortlaufend und nicht immer ansteigend sind?

 

Hallo!

Die Nummern werden von der Formel aufsteigend sortiert, egal, ob sie im Original aufsteigend und/oder fortlaufend sind.

 

Einwandfrei!! Das aktualisiert sich ja sogar wenn ich neue Zeilen dazwischenschreibe- Faszination Excel :D

Vielen Dank, Schatzi!!