Office: (Office 2010) Textfeld als Suche Benutzen

Hallo, ich habe eine Excel Tabelle mit 3 Spalten

Name Nachname Telefonnummer

Nun habe ich eine Textbox (TextBox1) und ein Knopf (CommandButton1) einfgefügt, jetzt möchte ich gerne das er in den Spalten, nach dem Text sucht den ich in die Textbox eingebe und wenn der Text vorhanden ist, Excel automatisch in die Zeile springt.

Ist das mit VBA möglich?

LG
Dicken

 

Hi Dicken,

möglich ist (fast) alles mit VBA.
Wie wird denn festgelegt, in welcher Spalte gesucht werden soll? Z.B. könnte "Hermann" als Vorname und als Nachname vorkommen - welche Spalte soll dann gelten? Und was soll passieren, wenn der Suchbegriff mehrmals vorkommt?

Übrigens: eine hochgeladene Beispielmappe würde das Helfen erleichtern.

Bis später,
Karin

 

Hey, danke für deine Antwort,

Hier mal meine Datei:
Den Anhang Kundenkartei.xlsm betrachten


(Der Kunden sortieren Button funktioniert, sobald man etwas neues drunter schreibt und den Button drückt, wird es alphabetisch angeordnet)

Die Suche in I1 funktioniert auch: man gibt etwas ein und Excel springt zu der Zelle, wo der gesuchte wert drin steht, egal ob in Spalte A oder B. Es wird immer nur das erste gefundenen Wort gesucht.

Nur möchte ich eben diese Funktion in einer Textbox mit Suchenbutton (Siehe Datei) integrieren. Und wenn es geht sollte vllt beim erneuten drücken einfach weitersuchen, das heißt zum nächsten Treffer springen.

LG
Dicken

 

Hi Dicken,

das kann man mit folgendem Code realisieren:

Code:

Private Sub TextBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    Dim rngZelle As Range
    Dim strStart As String
    Dim intFrage As Integer
    If KeyCode = 13 Then   '<== Taste war Enter/Return
        Set rngZelle = Cells.Find(What:=TextBox1, After:=Range("A2"), LookIn:=xlFormulas, _
            LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
            MatchCase:=False, SearchFormat:=False)
        If Not rngZelle Is Nothing Then
            strStart = rngZelle.Address
            Do
                Application.Goto reference:=rngZelle
                intFrage = MsgBox("Weitersuchen?", vbYesNo, "Suche")
                If intFrage = 7 Then
                    Exit Do
                Else
                    Set rngZelle = Cells.FindNext(rngZelle)
                End If
            Loop While rngZelle.Address <> strStart
        Else
            MsgBox "Nicht gefunden"
        End If
        Set rngZelle = Nothing
    End If
End Sub

Bei Drücken von Enter in der TextBox wird mit der Suche begonnen.

Bis später,
Karin

 

Funktioniert bestens :) Vielen Dank :)