Office: (Office 2013) Textfeld auslesen für Recordset.FindFirst

Philipp4563 · 11. Oktober 2015

Guten Tag,

ich möchte einen Datensatz ändern. Die Bedingungen dafür sind, dass das Rueckgabedatum leer ist und das die Technik_ID einem Textfeld entspricht. Hierzu habe ich folgen Code:

Public Sub RecordsetVermieten()
Dim RecordsetID As Recordset
Dim Db As Database
Set Db = CurrentDb

Set RecordsetID = Db.OpenRecordset("Miete", RecordsetTypeEnum.dbOpenDynaset)

RecordsetID.FindFirst ("Rueckgabe IS NULL And CInt(TextfeldTest.Value)")

If RecordsetID.NoMatch Then
MsgBox "Fehler"

Else

RecordsetID.Edit
RecordsetID.Fields("Rueckgabe").Value = "20.10.2012"
RecordsetID.Update

End If

End Sub

Problem an der sache ist, dass er mir immer "Laufzeitfehler 3070" anzeigt, aufgrund des Textfeldes, welches in der Findfirst Zeile nicht richtig ausgelesen werden kann.

Mfg Philipp

:)

hcscherzer · 13. Oktober 2015

Im Kriterium fehlt rechts vom "And" ein Vergleich.
Mit welchem Datenfeld soll den der Wert vom Testfeld verglichen werden?

Philipp4563 · 13. Oktober 2015

Oh der Vergleich ist wohl wieder verloren gegangen beim ganzen ausprobieren aber daran alleine liegt es nicht.

Das Testfeld soll mit dem Feld Technik_ID verglichen werden (Primärschlüssel aus Tabelle Technik).

maikek · 13. Oktober 2015

Versuch's mal so:

Code:

Public Sub RecordsetVermieten()
Dim RecordsetID As DAO.Recordset 'eindeutig deklarieren
Dim Db As DAO.Database
Set Db = CurrentDb

Set RecordsetID = Db.OpenRecordset("Miete", dbOpenDynaset)

With RecordsetID
.FindFirst "Rueckgabe is null And Technik_ID = " & CInt(Me.TextfeldTest) 'Formularfeld verketten
If .NoMatch Then
MsgBox "Fehler"
Else
.Edit
.Fields("Rueckgabe") = "#2012-12-20#" 'Datum formatieren
.Update
End If
End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

maike

ebs17 · 13. Oktober 2015

Oder so:
Code:

Public Sub RecordsetVermieten()
Dim RecordsetID As DAO.Recordset 'eindeutig deklarieren
Dim Db As DAO.Database
Dim sSQL As String

Set Db = CurrentDb

' Per SQL Filtern ist schneller als Suchen per VBA (Recordset-FindFirst).
' Nur benötigtes Feld und nur benötigte Datensätze laden statt ganze Tabelle.
' Schlanke Recordsets sind performancezuträglich.
' CInt sollte bei ordentlicher Formulargestaltung verzichtbar sein.

sSQL = "SELECT Rueckgabe FROM Miete WHERE Rueckgabe is null And Technik_ID = " & CInt(Me.TextfeldTest)
Set RecordsetID = Db.OpenRecordset(sSQL, dbOpenDynaset)
With RecordsetID
If .EOF Then
MsgBox "Fehler"
Else
.Edit
.Fields("Rueckgabe") = "#2012-12-20#" 'Datum formatieren
.Update
End If
.Close ' nicht vergessen
End With
Set RecordsetID = Nothing
Set Db = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Josef P. · 13. Oktober 2015

... oder einfach eine Update-Anweisung verwenden. *wink.gif*

Code:

UpdateSql = "update Miete set Rueckgabe = #2012-12-20# where Rueckgabe is null and Technik_ID=" & me.TextfeldTest
currentdb.execute updatesql, dbfailonerror
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

mfg
Josef

hcscherzer · 13. Oktober 2015

einfach eine Update-Anweisung
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Genau. Ganz einfach.

Philipp4563 · 14. Oktober 2015

Danke an alle!

Habe die Variante von Joseph genommen und sie tut genau das was sie soll.

Office: (Office 2013) Textfeld auslesen für Recordset.FindFirst

Textfeld auslesen für Recordset.FindFirst

Textfeld auslesen für Recordset.FindFirst

Textfeld auslesen für Recordset.FindFirst

Textfeld auslesen für Recordset.FindFirst

Textfeld auslesen für Recordset.FindFirst - Similar Threads - Textfeld auslesen Recordset

Zahlen aus Textfeld auslesen

VBA Text aus einem Textfeld auslesen

Textfelder aus Powerpoint auslesen

mit Excel Makro aus Word Datei Textfeld auslesen

Listenfeld mit VBA auslesen und Textfeld befüllen

Text auslesen und in Textfelder schreiben

Ungebundene Textfelder auslesen