Office: Ton bei Kennzeichen ausgeben

Hallo,
ich habe mir ein Sub erstellt wo ich 5x einen Ton ausgebe.
nun möchte ich wenn nach Eingabe einer Zahl in Spalte B dieses Makro aufrufen wenn in einer der Spalten V bis X ein Kennzeichen in der nächsten Zeile aufscheint.
Beispiel: Eingabe in Zelle B52, prüfen on Kennzeichen in Zellen V53 bis X53. usw.
Beste Grüße
Werner

 

Hallo Werner,

benutze das Change Ereignis unter der Tabelle.

 

Moin Werner,
mal abgesehen, dass Du Deine Werte überraschenderweise nicht in einer linearen Tabelle bearbeitest, (B52, V53...) gibt es noch etliche weitere Events (Ereignisse), die ein Makro auslösen können. Schau mal hier:

@Hajo: schnell die Augen schließen! Jetzt kommt ein Bild....

Grüße

 

Hallo,

nachfolgender VBA-Code gehört in das Code-Modul des Arbeitsblattes kopiert, in welchem die besagten Spalten B, V:X enthalten sind. Um dorthin zu gelangen, einen Rechtsklick auf den Arbeitsblatttabulator machen, den Befehl "Code anzeigen" aus der Liste auswählen, sodass das Codemodul des betreffenden Arbeitsblattes angezeigt wird. In den weißen Bereich den folgenden VBA-Code mittels Copy+Paste einfügen.

Code:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
  With Target
    If .Cells.CountLarge > 1 Then Exit Sub  'Mehr als 1 Zelle geändert
    If .Column <> 2 Then Exit Sub           'Nicht in Spalte B
    If Not IsNumeric(.Value) Then Exit Sub  'Zellinhalt nicht numerisch
  
    'Target befindet sich in Spalte B, wobei dort eine Zahl eingegeben wurde
  
    With .EntireRow
      'Überprüfe in der nächsten Zeile,
      'ob in einer der Spalten V,W,X eine nichtleere Zelle ist:
      If Not (IsEmpty(.Cells(2, "V").Value) And _
              IsEmpty(.Cells(2, "W").Value) And _
              IsEmpty(.Cells(2, "X").Value)) Then
         'Rufe SUB zur 5-Ton-Erzeugung auf:
         Call Sub5Töne
      End If
    End With
  End With
 
End Sub

In der Zeile "Call Sub5Töne" muss du anstelle von "Sub5Töne" den Aufruf deines 5-Töne-Makros einsetzen.