Office: Tool möglich?

Man kann ja im Outlook mit dem Regel assistenten Regeln erstellen, so das z.B. alle Mails von einem bestimmten Absender sofort in die Muelltonne gehen. Leider kann man mit Outlook keine Macros recorden.

Ich wuerde gerne in der Inbox eine oder mehrere Mails markieren, per button das Macro starten welches fuer die entsprechenden Absender die Loeschen / Verschieben Regel erstellt, so das ich nie wieder Mails von den betreffenden Absendern bekomme, bzw diese sofort in die Muelltonne gehen. Any Idea? Ich glaube das waehre ein sehr schoenes Tool.

Viele Grüße Nico

 

Hallo Nico,

nachfolgender VBA-Code funktioniert leider erst ab Outlook2007 erwartungsgemäß, weil die "Rule(s)"-Objekte erst ab dieser Version existieren.
Bis Outlook2003 kann man zwar auch so etwas Ähnliches wie Automatik-Regeln per VBA programmieren, aber diese sind dann nicht sichtbar in den Regeleinstellungen der Outlook-Oberfläche im Menü Extras. Außerdem muss man die Filterbedingungen fest in den VBA-Code integrieren und kann sie nicht dynamisch über die E-Mail-Auswahl in der Inbox festlegen.

Nachfolgender Code ist in ein allgem. Code-Modul im VBA-Editor zu kopieren und kann von der Outlook2007 bzw. 2010-Oberfläche mit der Tastenkombination Alt+F8 ausgewählt und ausgeführt werden.

Code:

Option Explicit

Public Sub Posteingang_Gelöscht()
    Dim myOlApp As New Outlook.Application
    Dim myOlExp As Outlook.Explorer
    Dim myOlSel As Outlook.Selection

    Dim colRules As Outlook.Rules
    Dim oRule As Outlook.Rule
    Dim colRuleActions As Outlook.RuleActions
    Dim oMoveRuleAction As Outlook.MoveOrCopyRuleAction
    Dim oFromCondition As Outlook.ToOrFromRuleCondition
    Dim oExceptSubject As Outlook.TextRuleCondition
    Dim oInbox As Outlook.Folder
    Dim oMoveTarget As Outlook.Folder
    
    Dim I As Integer
    
    'Ermitteln der selektierten Einträge
    Set myOlExp = myOlApp.ActiveExplorer
    Set myOlSel = myOlExp.Selection

    'Specify target folder for rule move action
    Set oInbox = Application.Session.GetDefaultFolder(olFolderDeletedItems)  'Folder 'Gelöschte Objekte'
    'Assume that target folder already exists
    
    'Get Rules from Session.DefaultStore object
    Set colRules = Application.Session.DefaultStore.GetRules()
    
    'Create the rule by adding a Receive Rule to Rules collection
    Set oRule = colRules.Create("Markierte Posteingänge löschen", olRuleReceive)

    'Specify the condition in a ToOrFromRuleCondition object
    'Condition is if the message is from selected sender-email-address
    Set oFromCondition = oRule.Conditions.From
    With oFromCondition
        .Enabled = True
        For I = 1 To myOlSel.Count
          .Recipients.Add myOlSel(I).SenderEmailAddress
        Next I
        .Recipients.ResolveAll
    End With

    'Specify the action in a MoveOrCopyRuleAction object
    'Action is to move the message to the target folder
    Set oMoveRuleAction = oRule.Actions.MoveToFolder
    With oMoveRuleAction
        .Enabled = True
        .Folder = oInbox  'oMoveTarget
    End With

    'Specify the exception condition for the subject in a TextRuleCondition object (optional!!)
    'Exception condition is if the subject contains "fun" or "chat"
    Set oExceptSubject = oRule.Exceptions.Subject
    With oExceptSubject
        .Enabled = True
        .Text = Array("fun", "chat")
    End With

    'Update the server and display progress dialog
    colRules.Save
  
End Sub

 

cool mal danke soweit. Ich probier das mal aus und melde mich dann wieder. vielen dank für die investierte Arbeit :)