Office: txt-File durchsuchen und einlesen

Hallo ayba,

dann ersetze im Code doch einfach "*.txt" durch "*.wasweisichfüreinenendung".

Ansonsten wie gesagt: Datei hochladen (eine solche deren Dateityp du nicht verraten willst)




« Gruß Sepp »

 

Hi,

sorry für die späte Antwort. Habe die Dateien angehängt. Die txt-files haben in Wirklichkeit .dat Endung.

Grüße,

ayba

 

Hallo ayba,

ein paar kleine Anpassungen und es läuft.

Sub readTextFile()
Dim strPath As String, strFile As String, strTmp As String
Dim ff As Integer
Dim vntRet As Variant
Dim vntNumber As Variant, vntDate As Variant

Const Begriff As String = "xyz" 'Gesuchter Begriff - Anpassen!

strPath = "E:\Forum\Test" 'Pfad zu den Textdateien - Anpassen!

If Right(strPath, 1) <> "\" Then strPath = strPath & "\"

strFile = Dir(strPath & "*.dat", vbNormal)

Do While strFile <> ""
ff = FreeFile
vntNumber = ""
vntDate = ""

Open strPath & strFile For Input As #ff
Do While Not EOF(ff)
Line Input #ff, strTmp
strTmp = Replace(strTmp, Chr(34), "")
If LCase(strTmp) Like "comments*" & Begriff & "*" Then
vntNumber = Trim(Split(strTmp, ":")(1))
If IsNumeric(vntNumber) Then vntNumber = CDbl(vntNumber)
ElseIf LCase(strTmp) Like "*datum*" Then
vntDate = Trim(Split(strTmp, ",")(1))
If IsDate(vntDate) Then vntDate = CDate(vntDate)
Exit Do
End If
Loop
Close #ff

If vntNumber <> "" And vntDate <> "" Then
With Sheets("Tabelle1") 'Tabellenname -Anpassen!
vntRet = Application.Match(vntNumber, .Columns(3), 0)
If IsNumeric(vntRet) Then .Cells(vntRet, 7) = vntDate
End With
End If

strFile = Dir
Loop

End Sub




« Gruß Sepp »