Office: UDF gibt Fehler nach anderer Makro-Ausführung

Hallo,

ich weiß nicht recht, wie ich das Problem kürzer umreißen soll. Folgendes Problem:

Ich habe mir eine UDF geschrieben, die die Anzahl nicht ausgeblendeter Zeilen in einem bestimmten Bereich zählt. Das tut auch und der Zellinhalt wird auch korrekt aktualisiert, wenn ich manuell Zeilen aus- oder einblende.
Nun habe ich aber weiterhin ein Makro (wird per Button ausgelöst), welches Zeilen nach bestimmten Regeln aus- oder einblendet. Auch dieses Makro funktioniert einwandfrei, NUR:
Wenn ich es ausführe, aktualisiert sich zwar auch der Zellinhalt mit der o.g. UDF, allerdings erhalte ich dann immer den Inhalt #WERT!
Gebe ich die exakt gleiche Formel dort nochmal ein (bzw. klicke nur den Häckchen-Button neben dem Formel-Eingabefeld), wird die korrekte Anzahl Zeilen berechnet.

Ich schließe daraus also, dass beide Makros korrekt sind, nur deren Zusammenspiel nicht. Was kann ich tun?

Ach ja: In dem Makro zum Ein/Ausblenden wird die UDF nicht aufgerufen, die Aktualisierung der jeweils neu zu berechnenden Zelle(n) mit der UDF wird von Excel selbst angestoßen, fällt dann aber auf die Nase.
Ich kann dieses Problem sowohl in einem Excel 2003 / SP3 als auch einem Excel 2007 / SP1 reproduzieren.

Für alle Fälle füge ich mal die Sourcen an:

Code:

Option Explicit

' Blendet alle Zeilen aus, in denen abgelehnte oder abgesagte Kandidaten stehen,
' d.h. es bleiben nur die verfügbaren übrig
Sub ausblenden()
    Dim zeile As Integer
    
    ' Finde die Zeilennummer, ab der die Kandidaten via Anzeige beginnen
    zeile = startKandAnzeige(1)
    
    ' Prüfe die Spalten 6 (F) und 8 (H)
    ' Wenn die Zelle leer ist, beende die Schleife
    Do Until Cells(zeile, 6).Value = ""
        If InStr(1, UCase(Cells(zeile, 6).Value), "NO", vbTextCompare) _
        Or InStr(1, UCase(Cells(zeile, 8).Value), "ABGESAGT", vbTextCompare) _
        Or InStr(1, UCase(Cells(zeile, 8).Value), "VERFÜGBAR", vbTextCompare) Then
            Rows(zeile).EntireRow.Hidden = True
        Else
            Rows(zeile).EntireRow.Hidden = False
        End If
        zeile = zeile + 1
    Loop
    
    ' Finde die Zeilennummer, ab der die Kandidaten via Personal-Agenturen beginnen
    zeile = startKandPA(zeile)
    
    ' Prüfe die Spalten 6 (F) und 8 (H)
    ' Wenn die Zelle leer ist, beende die Schleife
    Do Until Cells(zeile, 6).Value = ""
        If InStr(1, UCase(Cells(zeile, 6).Value), "NO", vbTextCompare) _
        Or InStr(1, UCase(Cells(zeile, 8).Value), "ABGESAGT", vbTextCompare) _
        Or InStr(1, UCase(Cells(zeile, 8).Value), "VERFÜGBAR", vbTextCompare) Then
            Rows(zeile).EntireRow.Hidden = True
        Else
            Rows(zeile).EntireRow.Hidden = False
        End If
        zeile = zeile + 1
    Loop
End Sub

' Blendet alle Zeilen wieder ein
Sub einblenden()
    Dim zeile As Integer
    
    ' Finde die Zeilennummer, ab der die Kandidaten via Anzeige beginnen
    zeile = startKandAnzeige(1)
    
    ' Prüfe die Spalte 6 (F)
    ' Wenn die Zelle leer ist, beende die Schleife
    Do Until Cells(zeile, 6).Value = ""
        Rows(zeile).EntireRow.Hidden = False
        zeile = zeile + 1
    Loop
    
    ' Finde die Zeilennummer, ab der die Kandidaten via Personal-Agenturen beginnen
    zeile = startKandPA(zeile)
    
    ' Prüfe die Spalte 6 (F)
    ' Wenn die Zelle leer ist, beende die Schleife
    Do Until Cells(zeile, 6).Value = ""
        Rows(zeile).EntireRow.Hidden = False
        zeile = zeile + 1
    Loop
End Sub

' Finde die Zeilennummer, ab der die Kandidaten via Anzeige beginnen
' Dazu wird in Spalte 1 (A) nach dem genauen String der Überschrift gesucht
' Eingabe: Die Zeilennummer, ab der gesucht werden soll
' Rückgabewert: Die Zeilennummer direkt nach der Überschriftszeile
Function startKandAnzeige(zeile)
    Do Until Cells(zeile, 1).Value = "Kandidaten über Anzeige"
        zeile = zeile + 1
    Loop
    zeile = zeile + 1 ' Überspringe nun die Kopfzeile
    
    startKandAnzeige = zeile
End Function

' Finde die Zeilennummer, ab der die Kandidaten via PA beginnen
' Dazu wird in Spalte 1 (A) nach dem genauen String der Überschrift gesucht
' Eingabe: Die Zeilennummer, ab der gesucht werden soll
' Rückgabewert: Die Zeilennummer direkt nach der Überschriftszeile
Function startKandPA(zeile)
    Do Until Cells(zeile, 1).Value = "Kandidaten über Personal-Agenturen"
        zeile = zeile + 1
    Loop
    zeile = zeile + 1 ' Überspringe nun die Kopfzeile
    
    startKandPA = zeile
End Function

' Zählt alle eingeblendeten Zeilen
Function CountVisible(myCells As Range) As Integer
    CountVisible = 0
    Dim loopCount As Integer
    Dim firstRow As Integer
    Dim column As Integer
    
    loopCount = 0
    column = myCells.column
    firstRow = myCells.Row
    
    Do Until loopCount = myCells.Rows.Count
        If Cells(firstRow + loopCount, column).EntireRow.Hidden = False Then
            CountVisible = CountVisible + 1
        End If
        loopCount = loopCount + 1
    Loop
End Function

 

Hi RobOtter...

versuche mal folgendes...

Code:

Sub ausblenden()
  
  Dim zeile As Integer
   
  Application.Calculation = xlCalculationManual
  
' :
' :
' Dein Code wie vorher
' :
' :
  
  Application.Calculation = xlCalculationAutomatic
  Application.Calculate
  
End Sub

Dasselbe auch in einblenden().

Gruß

 

Hallo maninweb,

vielen Dank, das funzt auf Anhieb!
Interessanterweise besteht das Problem nicht, wenn ich nicht einfach die ausgeblendeten Zeilen zähle, sondern nach den Regeln zähle, die zur Ausblendung führen. Das verstehe einer... :-(

Trotzdem, es hat mich sehr weiter gebracht, besten Dank nochmal!