Office: UDF mit Range.Find funktioniert nicht

Fluppi_no1 · 8. Dezember 2020

Hallo zusammen,

ich habe herausgefunden, dass man mit UDFs eigene Funktionen für die Sheets schreiben kann. Nun habe ich mir ein paar Funktion in eine .xlma-Datei geschrieben und in den Addin-Ordner gespeichert. Soweit funktionert das schon mal.

Nun suche ich in einer Funktion die in einem übergebenen Range-Bereich einen Text und gebe dann den Zellinhalt bezüglich dazu mit Zeilen-/Spalten-Offset aus. Dies funktioniert, auch. Doch, wenn ich im Sheet mit einem Makro eine Zelle lösche, verliert die Zelle ihren gefundenen Wert.
Beim Aufruf findet die Range.Find() Funktion keinen Wert, obwohl der gesuchte Wert enthalten ist.
Wenn ich die automatische Berechnung abschalte, bleibt natürlich der Wert, doch wird dann meine Berechnung für alles andere gestoppt. Das ist für mich keine saubere Lösung.
Ich habe auch schon "Application.Volatile True" als Lösungsvorschlag gelesen, was aber auch nicht zur Lösung führt.

Könnt ihr mir da bitte helfen:
Hier ist mein Code:
Code:

Function FindValue(ByVal vSearch As Range, _
ByVal rgArea As Range, _
ByVal RowOffset As Integer, _
ByVal ColOffset As Integer) As Variant
Dim rgFound As Range

Set rgFound = rgArea.Find(What:=vSearch.Value, _
After:=rgArea.Cells(rgArea.Cells.Count), _
LookAt:=xlWhole, _
MatchCase:=False, _
searchorder:=xlRows, _
searchdirection:=xlNext, _
matchbyte:=False, _
searchformat:=False)

If Not rgFound Is Nothing Then
FindValue = rgFound(1 + RowOffset, 1 + ColOffset).Value
Else
FindValue = "NotFound"
End If
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich suche im Rangebereich D3:H7 und lösche in einem anderen Makro aus einem Modul vom Arbeitsblatt mit:
ThisWorkbook.ActiveSheet.Range("A14").Delete

Vielen Dank für eure Hilfe

:)

EarlFred · 10. Dezember 2020

Find in UDFs... *brrr*

Probier mal:
Code:

Option Explicit

Function FindValue(ByVal vSearch As Range, _
ByVal rgArea As Range, _
ByVal RowOffset As Integer, _
ByVal ColOffset As Integer) As Variant

Dim fvData As Variant
Dim vSuche As Variant
Dim s As Long
Dim z As Long

fvData = rgArea.Value
vSuche = vSearch.Value
FindValue = "NotFound"

For z = LBound(fvData, 1) To UBound(fvData, 1)
For s = LBound(fvData, 2) To UBound(fvData, 2)
If fvData(z, s) = vSuche Then
FindValue = fvData(z + RowOffset, s + ColOffset)
Exit Function
End If
Next s
Next z

End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

oder
Code:

Function FindValue2(ByVal vSearch As Range, _
ByVal rgArea As Range, _
ByVal RowOffset As Integer, _
ByVal ColOffset As Integer) As Variant

Dim r As Range
Dim rgFound As Range
Dim vRet As Variant

For Each r In rgArea.Rows
vRet = Application.Match(vSearch.Value, r, 0)
If IsNumeric(vRet) Then
Set rgFound = r.Cells(vRet)
Exit For
End If
Next r

If Not rgFound Is Nothing Then
FindValue2 = rgFound.Offset(RowOffset, ColOffset).Value
Else
FindValue2 = "NotFound"
End If
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Fluppi_no1 · 15. Dezember 2020

Super *Smilie das funktioniert.

Warum sollte ich Find nicht im UDF-benötigen? Ansonsten geht das doch auch recht schon und ich benötige keine Schleife. Darum hätte ich gedacht, dass so die Funktion schneller durchläuft.

EarlFred · 15. Dezember 2020

ich benötige keine Schleife. Darum hätte ich gedacht, dass so die Funktion schneller durchläuft.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Im Vergleich zu Match / Array ist Find eine Schnecke:
https://fastexcel.wordpress.com/2011...ance-shootout/

Die Menge der Codezeilen sagt nichts über die Performance des Codes. Die Wahl der richtigen Mittel ist entscheidend.

Fluppi_no1 · 15. Dezember 2020

Somit ist es klar.

Vielen Dank für die Hilfe

Office: UDF mit Range.Find funktioniert nicht

UDF mit Range.Find funktioniert nicht

UDF mit Range.Find funktioniert nicht

UDF mit Range.Find funktioniert nicht

UDF mit Range.Find funktioniert nicht - Similar Threads - UDF Range Find

Rangfolge stimmt nicht, doppelte Zeilen

Range der Abfrage erhöhen

User Defined Functions (UDF) auch ohne VBA / Makro möglich ?

UDF in PQ

LAMBDA()-UDF (ben.def. Tabellenfunktionen ohne VBA/xl4m)

VBA-UDF-Sammlung von Luc

UDF gibt Fehler nach anderer Makro-Ausführung