Office: Uhrzeiteingabe vereinfachen

Hallo,
ich würde gerne die Eingabe der Uhrzeit vereinfachen.
Die Zelle ist formatiert mit hh:mm und ich trage die Uhrzeit z.B. so ein: 11:00

Was ich nun gerne hätte ist, dass ich auch 1100 oder nur 11 eingebe und daraus automatisch 11:00 gemacht wird.

Meine Idee ist es dass ich prüfe ob es eine Ganzzahl (also ohne ":" ) ist und wenn ja, dann füllt man auf 4 Stellen mit Nullen auf und setzt in der Mitte ein Doppelpunkt.

Leider kenne ich mich nur mit richtigen Programmiersprachen aus (C++, Python), aber wie man sowas in Excel realisiert weiß ich leider nicht.

Ich bin für jeden Tipp dankbar.

Gruß,
Holle

 

Hola,
Zeit-Eingabe ohne Doppelpunkt | Excel ist sexy!

Gruß,
steve1da

 

Hi,

das geht z.B. mit folgendem Code im Codemodul des Tabellenblattes:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rngZelle As Range
    ' Code bezieht sich auf Spalte A <== Spaltennummer oder Bereich anpassen!!
    If Not Intersect(Target.Cells(1), Columns(1)) Is Nothing Then
        ' Eingabe ist numerisch und eine Ganzzahl
        If IsNumeric(Target.Cells(1)) And Target.Cells(1) - CInt(Target.Cells(1)) = 0 Then
            ' Schleife über alle Eingabezellen die in Spalte A liegen
            For Each rngZelle In Intersect(Target, Columns(1))
                ' Eingabe ist 2 oder 4 Zeichen lang
                Select Case Len(rngZelle)
                    Case 2, 4
                        On Error GoTo Errorhandler
                        ' Reaktion auf Eingabe abschalten
                        Application.EnableEvents = False
                        ' Eingabe ist 2 Zeichen lang
                        If Len(rngZelle) = 2 Then
                            ' Eingabe ist kleiner als 25 da nur 24 Stunden
                            If rngZelle < 25 Then
                                rngZelle = TimeValue(rngZelle & ":00")
                                Target.NumberFormat = "hh:mm"
                            End If
                        Else
                            ' linke 2 Ziffern sind kleiner 25 und recht 2 Ziffern sind kleiner 60
                            If Left(rngZelle, 2) < 24 And Right(rngZelle, 2) < 60 Then
                                rngZelle = TimeValue(Left(rngZelle, 2) & ":" & Right(rngZelle, 2))
                                Target.NumberFormat = "hh:mm"
                            End If
                        End If
                        On Error GoTo 0
                End Select
            Next rngZelle
        End If
    End If
Errorhandler:
    ' Reaktion auf Eingabe einschalten
    Application.EnableEvents = True
End Sub

---

 

die für mich einfachste Art zur Zeiteingabe ist.
Stelle bei Autokorrektur ein Ersetzen ,, durch : dann kannst Du Zeiten recht schnell mit der Num-Lock-Tastatur eingeben.

 

Herzlichen Dank, das ist genau was ich gesucht habe.
Ich habe den Code noch etwas abgeändet, damit aus "9" "09:00" wird (also einstellig).
Ansonsten konnte ich deinen Code 1:1 übernehmen, vielen dank !!!

Edit: Hier ist der geänderte Code:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rngZelle As Range
    ' Code bezieht sich auf Spalte A <== Spaltennummer oder Bereich anpassen!!
    If Not Intersect(Target.Cells(1), Columns(1)) Is Nothing Then
        ' Eingabe ist numerisch und eine Ganzzahl
        If IsNumeric(Target.Cells(1)) And Target.Cells(1) - CInt(Target.Cells(1)) = 0 Then
            ' Schleife über alle Eingabezellen die in Spalte A liegen
            For Each rngZelle In Intersect(Target, Columns(1))
                ' Eingabe ist 2 oder 4 Zeichen lang
                Select Case Len(rngZelle)
                    Case 1, 2, 4
                        On Error GoTo Errorhandler
                        ' Reaktion auf Eingabe abschalten
                        Application.EnableEvents = False
                        ' Eingabe ist 2 Zeichen lang
                        If Len(rngZelle) <= 2 Then
                            ' Eingabe ist kleiner als 25 da nur 24 Stunden
                            If rngZelle < 25 Then
                                rngZelle = TimeValue(rngZelle & ":00")
                                Target.NumberFormat = "hh:mm"
                            End If
                        Else
                            ' linke 2 Ziffern sind kleiner 25 und recht 2 Ziffern sind kleiner 60
                            If Left(rngZelle, 2) < 24 And Right(rngZelle, 2) < 60 Then
                                rngZelle = TimeValue(Left(rngZelle, 2) & ":" & Right(rngZelle, 2))
                                Target.NumberFormat = "hh:mm"
                            End If
                        End If
                        On Error GoTo 0
                End Select
            Next rngZelle
        End If
    End If
Errorhandler:
    ' Reaktion auf Eingabe einschalten
    Application.EnableEvents = True
End Sub

 

Ich bräuchte nochmal Hilfe:
Wie kann ich das erweitern dass es sowohl für Spalte A, wie auch für Spalte B gilt?

 

Moin!
Ohne VBA entweder so wie Hajo (so mache ich dies auch bereits seit Jahren).
Oder ein schlichtes benutzerdefiniertes Zahlenformat 00\:00
Dann ergibt 9 → 00:09
900 → 09:00
Zwei Nachteile:
1. Minuten müssen zwingend eingegeben werden (bei der Doppelkomma-Methode nicht)
2. da es sich nicht um "echte" Uhrzeiten handelt, müssen beim Weiterrechnen simple Formeln aushelfen.

Ein nicht zu unterschätzender Vorteil ist hingegen, dass man auch negative "Zeiten" darstellen und mit ihnen rechnen kann.

Gruß Ralf

 

Code:

If Target.Column < 3

 

Hi,

ersetze an allen Stellen Columns(1) durch Columns("A:B").

---

 

Nochmals herzlichen Dank, nun ist es perfekt :-)

 

Nochmal eine Kleine Änderung, welche es erlaubt die Uhrzeit 3-Stellig einzugeben (z.B. 945 -> 09:45):

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rngZelle As Range
    ' Code bezieht sich auf Spalte A <== Spaltennummer oder Bereich anpassen!!
    If Not Intersect(Target.Cells(1), Columns("A:B")) Is Nothing Then
        ' Eingabe ist numerisch und eine Ganzzahl
        If IsNumeric(Target.Cells(1)) And Target.Cells(1) - CInt(Target.Cells(1)) = 0 Then
            ' Schleife über alle Eingabezellen die in Spalte A liegen
            For Each rngZelle In Intersect(Target, Columns("A:B"))
                ' Eingabe ist 2 oder 4 Zeichen lang
                Select Case Len(rngZelle)
                    Case 1, 2, 3, 4
                        On Error GoTo Errorhandler
                        ' Reaktion auf Eingabe abschalten
                        Application.EnableEvents = False
                        ' Eingabe ist 1 oder 2 Zeichen lang
                        If Len(rngZelle) <= 2 Then
                            ' Eingabe ist kleiner als 25 da nur 24 Stunden
                            If rngZelle < 25 Then
                                rngZelle = TimeValue(rngZelle & ":00")
                                Target.NumberFormat = "hh:mm"
                            End If
                        ' Eingabe ist 3 Zeichen lang
                        ElseIf Len(rngZelle) = 3 Then
                            ' die rechten 2 Ziffern sind kleiner als 60
                            If Right(rngZelle, 2) < 60 Then
                                rngZelle = TimeValue(Left(rngZelle, 1) & ":" & Right(rngZelle, 2))
                            End If
                        ' Eingabe ist 4 Zeichen lang
                        Else
                            ' linke 2 Ziffern sind kleiner 25 und recht 2 Ziffern sind kleiner 60
                            If Left(rngZelle, 2) < 24 And Right(rngZelle, 2) < 60 Then
                                rngZelle = TimeValue(Left(rngZelle, 2) & ":" & Right(rngZelle, 2))
                                Target.NumberFormat = "hh:mm"
                            End If
                        End If
                        On Error GoTo 0
                End Select
            Next rngZelle
        End If
    End If
Errorhandler:
    ' Reaktion auf Eingabe einschalten
    Application.EnableEvents = True
End Sub