Office: Umgang mit Application.Match fehlerhaft

Helfe beim Thema Umgang mit Application.Match fehlerhaft in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo an Alle, findet evt. jemand den Fehler , warum die Variable "var" nicht gefüllt wird?!! Code: With Sheets("Accounts Payable Voucher") For... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Hammer, 28. März 2010.

Seite 1 von 2

HAMMER

Hammer

Umgang mit Application.Match fehlerhaft

Hallo an Alle,

findet evt. jemand den Fehler
, warum die Variable "var" nicht gefüllt wird?!!

Code:

With Sheets("Accounts Payable Voucher")
For intRow = 10 To 23
If .Cells(intRow, 3) = "59930" Then
Nettx = .Cells(intRow, 13).Value
var = Application.Match(CDbl(.Cells(intRow, 5).Value), Sheets("Purchase Recap").Row(2), 0)
Sheets("Purchase Recap").Cells(lngAnzahl, var).Value = Nettx
End If
Next intRow
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Vielen Dank!!!

:)

Hammer, 28. März 2010

#1
JINX

jinx

Moin, Marco,

Du verwendest kein Option Explicit - würde ich Dir dringend anraten. Es heißt nicht Row(2), sondern Rows(2).

lngAnzahl ist im Codeabschnitt nicht gefüllt, und ich finde es verwunderlich, mit unterschiedlichen Präfixen für Zeilenvariablen zu arbeiten...

jinx, 29. März 2010

#2
HAMMER

Hammer

Moin jinx,

erst mal Danke für die schnelle Antwort.

Ich hätte vielleicht auch gleich den ganzen Code posten sollen, um keine Unklarheiten aufkommen zu lassen. *upps

Code:

Sub rechnung()

Dim lngAnzahl As Long
Dim Datum As Long
Dim REnummer As Long
Dim Vendor As String
Dim intRow As Integer
Dim Nettx As Long
Dim var As Variant

Sheets("Accounts Payable Voucher").Select
Datum = Cells(5, 7)
REnummer = Cells(5, 3)
Vendor = Cells(3, 13)

With Sheets("Purchase Recap")
lngAnzahl = .Cells(103, 2).End(xlUp).Row + 1

.Cells(lngAnzahl, 2).Value = Vendor
.Cells(lngAnzahl, 3).Value = REnummer
.Cells(lngAnzahl, 4).Value = Datum
End With

With Sheets("Accounts Payable Voucher")
For intRow = 10 To 23
If .Cells(intRow, 3) = "59930" Then
Nettx = .Cells(intRow, 13).Value
var = Application.Match(CDbl(.Cells(intRow, 5).Value), Sheets("Purchase Recap").Rows(2), 0)
Sheets("Purchase Recap").Cells(lngAnzahl, var).Value = Nettx
End If

Next intRow

End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Also Option Explicit habe ich jetzt gesetzt. Und (na klar *wink.gif* ) auch die Variable lngAnzahl ist gefüllt. Klappt auch erstmal soweit.

Vielen Tausend Dank!!!

Hammer, 29. März 2010

#3
HAMMER

Hammer

Umgang mit Application.Match fehlerhaft

...habe da doch noch ein Problem:

Wenn eine Zahl nicht gefunden wird bei Appl.Match soll er diese in Spalte 20 eintragen. Leider funktioniert das nicht.

Weiss jemand was falsch ist???

Code:

Sub rechnung()

Dim lngAnzahl As Long
Dim Datum As Date
Dim REnummer As Long
Dim Vendor As String
Dim intRow As Double
Dim Nettx As Single
Dim var As Single

Sheets("Accounts Payable Voucher").Select
Datum = Cells(5, 7)
REnummer = Cells(5, 3)
Vendor = Cells(3, 13)

With Sheets("Purchase Recap")
lngAnzahl = .Cells(103, 2).End(xlUp).Row + 1

.Cells(lngAnzahl, 2).Value = Vendor
.Cells(lngAnzahl, 3).Value = REnummer
.Cells(lngAnzahl, 4).Value = Datum
End With

With Sheets("Accounts Payable Voucher")
For intRow = 10 To 23
If .Cells(intRow, 3) 0 Or .Cells(intRow, 5) 0 Then
Nettx = .Cells(intRow, 13).Copy
var = Application.Match(CLng(.Cells(intRow, 5).Value), Sheets("Purchase Recap").Rows(2), 0)
If IsError(var) Then
Sheets("Purchase Recap").Cells(lngAnzahl, 20).PasteSpecial Paste:=xlPasteAll, Operation:=xlAdd, SkipBlanks:= _
False, Transpose:=False
Else
Sheets("Purchase Recap").Cells(lngAnzahl, var).PasteSpecial Paste:=xlPasteAll, Operation:=xlAdd, SkipBlanks:= _
False, Transpose:=False
End If
End If
Application.CutCopyMode = False
Next intRow

End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Hammer, 29. März 2010

#4
HAMMER

Hammer

*frown.gif* Hat keiner eine Idee???

Hammer, 30. März 2010

#5
JINX

jinx

Moin, Marco,

die Variable auf den Status IsEmpty abfragen oder auf "" vergleichen:

Code:

If IsEmpty(Var) Then
MsgBox "Hier die Anweisung für den Leerwert"
Else
Sheets("Purchase Recap").Cells(lngAnzahl, var).Value = Nettx
End If
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Hat keiner eine Idee???
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wenn Du meine Arbeit machst, kannst Du auch eher eine Antwort von mir erhalten - aber ich bekomme weiterhin mein Gehalt... *wink.gif*

jinx, 30. März 2010

#6
RANSI

ransi

HAllo

Versuch mal so:

Public Sub tewastr()
Dim var As Variant
var = Application.Match("ABC", Range("a1:A100"), 0)
If Not IsError(var) Then
MsgBox "Treffer"
Else:
MsgBox "Wert gibts nicht"
End If
End Sub

ransi

ransi, 30. März 2010

#7
HAMMER

Hammer

Umgang mit Application.Match fehlerhaft

Hallo,

@ransi: Vielen Dank, aber leider gehts auch damit nicht! *frown.gif*

@jinx:

Wenn Du meine Arbeit machst, kannst Du auch eher eine Antwort von mir erhalten - aber ich bekomme weiterhin mein Gehalt...
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

...ja die liebe Arbeit, deswegen antworte ich auch erst jetzt. Und ob ich Deiner Arbeit gewachsen bin....??? *wink.gif*

Also zum Problem zurück, es funzt irgendwie nicht richtig! Die Variable "var" ist ja nie richtig leer (Empty). Entweder hat sie noch die Werte vom letzten Schleifen Durchgang und zeigt dann deswegen den "Fehler 2042" an, oder woran es auch sonst noch liegt...??? Habe deswegen mal die Beispieldatei mit angehangen. Da lässt es sich sicherlich leichter erkennen was, wie & wo passieren soll.

PS: Meine Varriante die Werte jedesmal dazu zu addieren, ist bestimmt nicht die Schönste, wusste mir aber nicht anders zu helfen. *upps
Geht bestimmt auch anders, oder?

Hammer, 31. März 2010

#8
JINX

jinx

Moin, Marco,

irgendwie habe ich das Gefühl, dass Du nicht einen wirklich geeigneten Code für Deine Aufgabenstellung gewählt hast.

Code:

Option Explicit
Public status As Integer

Sub Rechnung()

Dim lngAnzahl As Long
Dim lngRow As Long
Dim lngColumn As Long
Dim var As Variant
Dim rngFound As Range
Dim strSearch As String
Dim wsRecap As Worksheet
Dim wsVoucher As Worksheet

Set wsRecap = Sheets("Purchase Recap")
Set wsVoucher = Sheets("Accounts Payable Voucher")

With wsRecap
lngAnzahl = .Cells(103, 2).End(xlUp).Row + 1
.Cells(lngAnzahl, 2).Value = Sheets("Accounts Payable Voucher").Cells(3, 13)
.Cells(lngAnzahl, 3).Value = Sheets("Accounts Payable Voucher").Cells(5, 3)
.Cells(lngAnzahl, 4).Value = Sheets("Accounts Payable Voucher").Cells(5, 7)
End With

With wsVoucher
For lngRow = 10 To 23
If .Cells(lngRow, 3) 0 Or .Cells(lngRow, 5) 0 Then
strSearch = .Cells(lngRow, 5).Value
Set rngFound = wsRecap.Rows(2).Find( _
what:=strSearch, _
LookIn:=xlValues, _
lookat:=xlWhole, _
searchorder:=xlByRows)
If rngFound Is Nothing Then
lngColumn = WorksheetFunction.Max(Cells(lngAnzahl, Columns.Count).End(xlToLeft).Column + 1, 20)
wsRecap.Cells(lngAnzahl, lngColumn).Value = wsRecap.Cells(lngAnzahl, lngColumn).Value + .Cells(lngRow, 13).Value
wsRecap.Cells(lngAnzahl, lngColumn + 1).Value = .Cells(lngRow, 3).Value & "/" & .Cells(lngRow, 5)
Else
wsRecap.Cells(lngAnzahl, rngFound.Column).Value = wsRecap.Cells(lngAnzahl, rngFound.Column).Value + .Cells(lngRow, 13).Value
End If
End If
Next lngRow
End With

Set rngFound = Nothing
Set wsVoucher = Nothing
Set wsRecap = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich weiß nicht, wofür die Variable im Prozedurkopf gedacht ist...

jinx, 1. April 2010

#9
HAMMER

Hammer

Hallo jinx,

WOW!!! Das ist echt KLASSE!!! ... Da fehlen mir noch so die einen oder anderen Feinheiten im Basiswissen für VBA *wink.gif*

Ohne jetzt Gierig und Unverschämt zu sein, ist es möglich, um Deinen Code besser zu verstehen, dass Du noch paar kleine Funktionsbemerkungen hinter die Codezeilen schreibst?!?

Ich will doch hier auch irgendwann mal (wenn ich groß bin *wink.gif* ) anderen was erklären können. *Smilie

Dann nochmal Vielen Dank!!!

Hammer, 5. April 2010

#10
JINX

jinx

Moin, Hammer,

das Verstehen der Befehle des Codes ist eine Sache - wichtiger erscheint mir das Suchen/Finden einer geeigneten Vorgehensweise zur Lösung des Problems (und die kann man meiner Meinung nach nicht durch Kommentierung im Code ableiten - wie heißt es noch: nicht in Problemen denken, sondern in Lösungen).

Code:

Option Explicit
Public status As Integer

Sub Rechnung_kommentiert()

Dim lngAnzahl As Long
Dim lngRow As Long
Dim lngColumn As Long
Dim var As Variant
Dim rngFound As Range
Dim strSearch As String
Dim wsRecap As Worksheet
Dim wsVoucher As Worksheet

'Setzen von Objekten zur Verkürzung der Ansprache der Tabellen
'also statt Sheets("Purchase Recap") dann wsRecap
'Vorteil: nur an einer Stelle im Text bei der Festlegung oder in einer
' Konstanten festzulegen; Verkürzung des Quellcodes, da innerhalb
' einer With-Anweisung immer nur auf ein Basis-Objekt Bezug genommen werden kann
Set wsRecap = Sheets("Purchase Recap")
Set wsVoucher = Sheets("Accounts Payable Voucher")

'Übertragen der Daten
'Anmerkung: Verkürzung vorgenommen, da hier noch die lange Ansprache der Zellen
' verwendet wurde
With wsRecap
'ggf. sollte hier eine Prüfung vorgenommen werden,
'falls der Bereich durchgehend gefüllt ist
lngAnzahl = .Cells(103, 2).End(xlUp).Row + 1
.Cells(lngAnzahl, 2).Value = wsVoucher.Cells(3, 13)
.Cells(lngAnzahl, 3).Value = wsVoucher.Cells(5, 3)
.Cells(lngAnzahl, 4).Value = wsVoucher.Cells(5, 7)
End With

'Bereich "abklappern", alternativ könnte SpecialCells(xlCellTypeConstants, 23)
'für einen Bereich zur Beschränkung auf die gefüllten Zellen eingesetzt werden;
'Parallelzelle dann auf Inhalt prüfen
With wsVoucher
For lngRow = 10 To 23
If .Cells(lngRow, 3) 0 Or .Cells(lngRow, 5) 0 Then
'Suchbegriff in String-Variable, könnte auch direkt in Suchterm erfolgen
strSearch = .Cells(lngRow, 5).Value
'Objekt auf die Fundzelle setzen
Set rngFound = wsRecap.Rows(2).Find( _
what:=strSearch, _
LookIn:=xlValues, _
lookat:=xlWhole, _
searchorder:=xlByRows)
'Prüfung, ob es eine Fundstelle gibt
If rngFound Is Nothing Then
'Feststellen der letzten Spalte zum Schreiben von nicht vorkommenden Werten.
'Einsatz der Tabellenfunktion MAX, um ab Spalte T die Werte einzufügen
lngColumn = WorksheetFunction.Max(Cells(lngAnzahl, Columns.Count).End(xlToLeft).Column + 1, 20)
'Übertrag der Werte, bei keiner Fundstelle kann auch keine Addition stattfinden (Korrektur)
wsRecap.Cells(lngAnzahl, lngColumn).Value = .Cells(lngRow, 13).Value
wsRecap.Cells(lngAnzahl, lngColumn + 1).Value = .Cells(lngRow, 3).Value & "/" & .Cells(lngRow, 5)
Else
'Übertrag der Werte mit Addition
wsRecap.Cells(lngAnzahl, rngFound.Column).Value = wsRecap.Cells(lngAnzahl, rngFound.Column).Value + .Cells(lngRow, 13).Value
End If
End If
Next lngRow
End With

'Freigeben der Objekte in umgekehrter Reihenfolge des Setzens
Set rngFound = Nothing
Set wsVoucher = Nothing
Set wsRecap = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Mir ist die Bedeutung der Variablen status immer noch nicht klar...

jinx, 5. April 2010

#11
HAMMER

Hammer

Moin jinx,

das Verstehen der Befehle des Codes ist eine Sache - wichtiger erscheint mir das Suchen/Finden einer geeigneten Vorgehensweise zur Lösung des Problems (und die kann man meiner Meinung nach nicht durch Kommentierung im Code ableiten - wie heißt es noch: nicht in Problemen denken, sondern in Lösungen).
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

...es hilft mir trotzdem sehr gut weiter, VIELEN DANK dafür!!! *Smilie

...ABER, ich muß nochmal auf den Code zurück kommen.

Code:

'Prüfung, ob es eine Fundstelle gibt
If rngFound Is Nothing Then
'Feststellen der letzten Spalte zum Schreiben von nicht vorkommenden Werten.
'Einsatz der Tabellenfunktion MAX, um ab Spalte T die Werte einzufügen
lngColumn = WorksheetFunction.Max(Cells(lngAnzahl, Columns.Count).End(xlToLeft).Column + 1, 20)
'Übertrag der Werte, bei keiner Fundstelle kann auch keine Addition stattfinden (Korrektur)
wsRecap.Cells(lngAnzahl, lngColumn).Value = .Cells(lngRow, 13).Value
wsRecap.Cells(lngAnzahl, lngColumn + 1).Value = .Cells(lngRow, 3).Value & "/" & .Cells(lngRow, 5)
Else
'Übertrag der Werte mit Addition
wsRecap.Cells(lngAnzahl, rngFound.Column).Value = wsRecap.Cells(lngAnzahl, rngFound.Column).Value + .Cells(lngRow, 13).Value
End If
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

...Du schreibst hier, dass bei keiner Fundstelle die Addition nicht stattfinden kann! WARUM??? In Deinem ersten Code (ohne Kommentierung) ging es doch aber auch, und war auch gut so! Nur das Feststellen der letzten Spalte funktioniert scheinbar nur einmal, bzw. wird es scheinbar in Spalte U nur überschrieben. Also es steht bei mehreren nicht zuordnungsfähigen Produktnummern immer nur die Letzte in Spalte U. Richtig wäre aber, wenn ALLE nicht zuordnungsfähigen Konto & Produktnummern ab Spalte U (Spalte für Spalte) aufgelistet wären. Ich dachte auch, dass dieser Code das schon so macht, klappt nur leider nicht!

ICH DANKE DIR SCHON MAL FÜR DEINE BEMÜHUNGEN!!! *Smilie

Hammer, 11. April 2010

#12
HAMMER

Hammer

Umgang mit Application.Match fehlerhaft

Hi jinx,

kannst Du mir bitte zu meinem letzten Beitrag noch eine Lösung vorschlagen?

Danke!!!

Mir ist die Bedeutung der Variablen status immer noch nicht klar...
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

...weil dieser Code noch aus anderen Codes heraus aufgerufen wird. ...ist das nicht richtig?

Hammer, 12. April 2010

#13
HAMMER

Hammer

....SORRY, ich muss doch nochmal eine Änderung vornehmen. (wollte dies zwar im letzten Beitrag direkt, aber es waren schon über 120 min. vorbei *frown.gif* )

Also die Produktnummern aus dem Accounts Payable Voucher werden ja mit denen im Purchase Recap Zeile zwei verglichen. Wenn sich da aber keine Übereinstimmung findet muss als nächstes die Kontonummer aus Accounts Payable Voucher Spalte C mit den im Purchase Recap Zeile zwei verglichen werden. was ich jetzt nicht weiss wie es geht, ist dass es so viele verschiedene Kontonummern gibt das diese Zusammengefasst werden. Da ist dann eine Spalte für alle Nummern zwischen 64000 - 65000 und die nächste Spalte 78000 - 79000 u.s.w. Nun muss die Nummer aus dem Accounts Payable Voucher Spalte C der entsprechenden Spalte in Purchase Recap zugeordnet werden. Erst jetzt sollen nicht zuordnungsfähige Produkte ganz hinten angestellt werden. (Also Nettowerte in Spalte T -other - addiert werden, und die Konto- & Produktnummern in die nächste frei Spalte hintendran eingefügt.

Ich hoffe das ist nicht zu umständlich. ;-)

Habe die Beispieldatei nochmal mit angehangen.

Vielen Dank!!!

Hammer, 12. April 2010

#14
JINX

jinx

Moin, Marco,

solange Du in der Überschriftenzeile leere Zellen hast, werden diese zuerst gefunden und die Konten nicht hinten auf Wunsch addiert....

Code:

Sub Rechnung()

Dim lngAnzahl As Long
Dim lngRow As Long
Dim lngColumn As Long
Dim rngFound As Range
Dim strSearch As String
Dim wsRecap As Worksheet
Dim wsVoucher As Worksheet

Set wsRecap = Sheets("Purchase Recap")
Set wsVoucher = Sheets("Accounts Payable Voucher")

With wsRecap
lngAnzahl = .Cells(103, 2).End(xlUp).Row + 1
.Cells(lngAnzahl, 2).Value = Sheets("Accounts Payable Voucher").Cells(3, 13)
.Cells(lngAnzahl, 3).Value = Sheets("Accounts Payable Voucher").Cells(5, 3)
.Cells(lngAnzahl, 4).Value = Sheets("Accounts Payable Voucher").Cells(5, 7)
End With

With wsVoucher
For lngRow = 10 To 23
If .Cells(lngRow, 5) 0 Then
strSearch = .Cells(lngRow, 5).Value
ElseIf .Cells(lngRow, 3) 0 Then
Select Case .Cells(lngRow, 3).Value
Case 64000 To 65000
strSearch = 64000
Case 78000 To 79000
strSearch = 78000
Case Else
strSearch = .Cells(lngRow, 3).Value
End Select
End If
Set rngFound = wsRecap.Range(wsRecap.Cells(2, "F"), wsRecap.Cells(2, "S")).Find( _
what:=strSearch, _
LookIn:=xlValues, _
lookat:=xlWhole, _
searchorder:=xlByRows)
If rngFound Is Nothing Then
lngColumn = WorksheetFunction.Max(Cells(lngAnzahl, Columns.Count).End(xlToLeft).Column + 1, 21)
wsRecap.Cells(lngAnzahl, 20).Value = wsRecap.Cells(lngAnzahl, 20).Value + .Cells(lngRow, 13).Value
wsRecap.Cells(lngAnzahl, lngColumn).Value = .Cells(lngRow, 3).Value & "/" & .Cells(lngRow, 5)
Else
wsRecap.Cells(lngAnzahl, rngFound.Column).Value = wsRecap.Cells(lngAnzahl, rngFound.Column).Value + .Cells(lngRow, 13).Value
End If
Next lngRow
End With

Set rngFound = Nothing
Set wsVoucher = Nothing
Set wsRecap = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

jinx, 13. April 2010

#15

(Du musst angemeldet oder registriert sein, um eine Antwort erstellen zu können.)

Seite 1 von 2

Thema:

Umgang mit Application.Match fehlerhaft

Die Seite wird geladen...

Umgang mit Application.Match fehlerhaft - Similar Threads - Umgang Application Match
Praktischer Umgang mit Zellenschutz
in Microsoft Excel Hilfe
Praktischer Umgang mit Zellenschutz: Hallo, ich habe ja einige Tabellen, die auch von anderen Mitarbeiter eingesehen werden können. Die haben allerdings nicht so viel Ahnung von Excel und wenn die mal irgendwo einen Wert ändern,...
Application Guard für Office
in Microsoft Excel Tutorials
Application Guard für Office: Application Guard für Office Excel für Microsoft 365 Word für Microsoft 365 PowerPoint für Microsoft 365 Mehr... Weniger...
Umgang mit Phishing in Outlook.com
in Microsoft Outlook Tutorials
Umgang mit Phishing in Outlook.com: Umgang mit Phishing in Outlook.com Outlook.com Mehr... Weniger Eine Phishing-e-Mail ist eine e-Mail-Nachricht, die...
Progressbar / Application-Anzeige
in Microsoft Excel Hilfe
Progressbar / Application-Anzeige: Hallo. Ich habe ein Programm in VBA erstellt, dass Berechnungen vornimmt. Diese Berechnungen dauern manchmal lange, da auch grosse Exceldateien benutzt werden. Nun sieht der Benutzer während das...
Umgang mit (optionalen) ByRef-Parametern / "NULL"-Referenz?
in Microsoft Excel Hilfe
Umgang mit (optionalen) ByRef-Parametern / "NULL"-Referenz?: Hallo! Mein Code sei Code: Public Sub MachWas(Optional ByRef A As Long, Optional ByRef B As String) if ( ... ) Then A = 1 if ( ... ) Then B = "Hallo" End Sub Public Sub Test() Dim A As Long...
Video: Umgang mit schreibgeschützten Abfragen in Access 2013
in Microsoft Access Tutorials
Video: Umgang mit schreibgeschützten Abfragen in Access 2013: Video: Umgang mit schreibgeschützten Abfragen in Access 2013 Access 2013 Mehr... Weniger...
Umgang mit Optionsfeld
in Microsoft Excel Hilfe
Umgang mit Optionsfeld: Hallo! Ich bin ziemlich unerfahren im Umgang mit "Fortgeschrittenen-Funktionen" von Excel, und würde mich freuen wenn mir jemand weiterhelfen könnte: Ich möchte einen Fragebogen in Excel...

Anmelden oder registrieren

Suche

Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.

Akzeptieren Weitere Informationen...

Information ausblenden