Office: (Office 365) Urlaubsplan für mitarbeiter

Ich hab einen urlaubsplan für 80 kolegen erstellt
Spalte a stehen die namen und ab b2 steht das datum die urlaube werden mit einem buchstabe makiert.
Nun versuche ich einen ausdruck für jeden mitarbeiter zu erstellen der durch auswahl des namen die urlaubsdaten ausgibt
Hat jemand eine idee wie ich das anstellen kann

 

Hi,

vielleicht mit FILTER?

 

Kann die funktion 2 parameter suche?
Einmal der name und dann den buchstabe "x" und dann oben das datum zurück geben?

 

Hallo,

in der beiliegenden Datei habe ich dir in Zelle E5 folgende Formel eingefügt:
=FILTER(tbUrlaube;(tbUrlaube[Name]=F2)*(tbUrlaube[Kennung]=G2);"kein Eintrag")

Diese Formel greift dabei auf die intelligente Tabelle "tbUrlaube" (Bereich: A2:C9) zu und filtert die Einträge dieser Tabelle mit Hilfe des Namens (Zelle F2) und der Kennung (Zelle G2).

 

Hey ich hab mal schnell mein aufbau meines kalenders nachgestellt damit ihr besser versteht was ich vorhab

 

Hallo,

Urlaub am Feiertag? Und am Wochenende (Sa, So)?
Gibt's bei euch keine arbeitsfreien Tage??
Wie soll denn die Ausgabe aussehen?

Gruß Sigi

 

Hola,
in K1 steht der gesuchte Name.
=WENNFEHLER(INDEX($B$3:$H$3;AGGREGAT(15;6;SPALTE($B$3:$H$3)-1/(($A$4:$A$12=$K$1)*($B$4:$H$12="x"));ZEILE(A1)));"")
Die Formel nach unten ziehen.
Gruß,
steve1da

 

Doch natürlich gibt es we und feiertage hab die datei eben schnell erstellt damit ihr euch vorstellen wie der aufbau ist
Blatt zwei wäre die ausgabe an den mitarbeiter

 

Hallo,

in K3 steht der gesuchte Arbeitnehmername und in A3:H12 die Tabelle.
in K4 folgende Formel in die Formeleditierzeile eingeben/kopieren:
=LET(
m; $A$3:$H$12;
dt; WEGLASSEN(ZEILENWAHL(m; 1); ; 1);
ma; WEGLASSEN(SPALTENWAHL(m; 1); 1);
daten; WEGLASSEN(m; 1; 1);
xma; XVERWEIS($K$3; ma; daten; ""; 0);
MTRANS(FILTER(dt; (xma = "x"); "kein Datum")))

 

Hallo,

beiliegend die Datei mit deinen neuen Anforderungen - zusammen mit mehreren Kommentaren.

 

Aber die formel soll mir auf dem 2ten blatt das datum (von-bis) allein raus suchen
So das in b7 und c7 start und ende steht
Der name wird oben per dropdown ausgewählt und er sucht von bis jeden urlaub raus von der ersten seite

 

Hallo,

in der beiliegenden Datei habe ich im Arbeitsblatt "ausdruck" in Zelle B7 eine Formel eingebaut, die die mit "x" gekennzeichneten Datumsintervalle auflistet, die zu dem betreffenden Mitarbeiter aus Zelle B3 gehören.

Der maximal berücksichtigte Zellbereich im Arbeitsblatt "Tabelle1" befindet sich in Tabelle1!A3:.NZ99.
Der zusätzliche Punkt (nach dem Doppelpunkt) bewirkt Folgendes: Dieser Zellbereich wird von der Formel automatisch auf die notwendige Größe verkleinert. Damit das Ganze funktioniert, darf dieser Zellbereich nur für besagten Zweck verwendet werden.
Formel:
=LET(nma; $B$3; m; Tabelle1!$A$3:.$NZ$99; dt; WEGLASSEN(ZEILENWAHL(m; 1); ; 1); ma; WEGLASSEN(SPALTENWAHL(m; 1); 1); daten; WEGLASSEN(m; 1; 1); xma; XVERWEIS(nma; ma; daten; ""; 0); fma; FILTER(dt; xma = "x"; "kein Datum"); REDUCE({"von"."bis"}; SEQUENZ(1; SPALTEN(fma)); LAMBDA(Akk;j; LET(dtv; WENN(j = 1; 0; INDEX(fma; 1; j - 1)); dtj; INDEX(fma; 1; j); WENN(dtv + 1 = dtj; LET(a; WEGLASSEN(Akk; -1); dta; INDEX(Akk; ZEILEN(Akk); 1); VSTAPELN(a; HSTAPELN(dta; dtj))); VSTAPELN(Akk; HSTAPELN(dtj; dtj)))))))

 

Leider zeigt er mir nen fehler an

 

Und was "nen Fehler" ist dürfen wir jetzt selber raten?

 

Ich probiere die formel morgen mal am pc bin heute leider unterwegs und hab es mit dem handy probiert