Office: Urlaubstage anzeigen lassen (Summewenn mit 2 Bedingungen)

Hallo zusammen,

ich habe eine Problem mit den Urlaubstagezählungen.

Vorraussetzung: Person kann bis zum 31.03. Resturlaub aus Vorjahr verwenden. Deshalb möchte ich erst einmal alle Urlaubstage anzeigen lassen, die die Person bis zum 31.03. genommen hat. Die Tabellen der einzelnen Personen sind auf extra Tabelleblättern mit den Spalten "DATUM VON", "DATUM BIS" und "ANZAHL TAGE" hinterlegt.

Stand: Ich habe im ersten Tabellenblatt eine Übersicht und möchte hier anzeigen lassen, wie viele Urlaubstage die Person vom 01.01.YYYY bis zum 31.03.YYYY (immer des jeweiligen Jahres) genommen hat.

Die Formel hierfür sieht bis jetzt so aus:

=SUMMENPRODUKT((Urlaubstage_Person[DATUM BEGINN]>DATUM(2012;1;1))*(Urlaubstage_Person[DATUM BEGINN]<DATUM(2012;4;1))*Urlaubstage_Person[ANZAHL])

Als Wert erhalte ich immer nur eine 0, egal welche Daten ich in der Tabelle der jeweiligen Person eingebe.

 

Hallo!

Falls im Folgenden die Tabelle "Urlaubstage_Person" im Bereich A1:C4 angesiedelt ist, die Jahreszahl (zB. 2012) in B7 einzugeben ist und schließlich die Abfrageformel sich in B8 befindet:

	A	B	C
1	DATUM VON	DATUM BIS	ANZAHL TAGE
2	03.01.2012	05.01.2012	3
3	10.01.2012	10.01.2012	1
4	01.04.2012	05.04.2012	5
5
6
7		2012
8		4
9

Zelle	Formel
B8	=SUMMENPRODUKT((Urlaubstage_Person[DATUM VON]>=DATUM(B7;1;1))*(Urlaubstage_Person[DATUM BIS]<=DATUM(B7;3;31))*Urlaubstage_Person[ANZAHL TAGE])

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

 

Hallo!

Da Du offenbar im Besitz von Excel2007 bzw. Excel2010 bist, hast Du die Wahl zwischen 2 Abfrageformeln (in B8 bzw. in C8):

	A	B	C
1	DATUM VON	DATUM BIS	ANZAHL TAGE
2	03.01.2012	05.01.2012	3
3	10.01.2012	10.01.2012	1
4	01.04.2012	05.04.2012	5
5
6
7		2012
8		4	4
9

Zelle	Formel
B8	=SUMMENPRODUKT((Urlaubstage[DATUM VON]>=DATUM(B7;1;1))*(Urlaubstage[DATUM BIS]<=DATUM(B7;3;31))*Urlaubstage[ANZAHL TAGE])
C8	=SUMMEWENNS(Urlaubstage[ANZAHL TAGE];Urlaubstage[DATUM VON];">="&DATUM(B7;1;1);Urlaubstage[DATUM BIS];"<="&DATUM(B7;3;31))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg