Office: (Office 2010) Userform dauerhaft im Vordergrund

Hallo Mitstreiter,

gibt es eine Möglichkeit, eine kleine Userform, dauerhaft im Vordergrund auf dem Desktop zu halten, selbst wenn eine andere Anwendung aktiviert ist?

:)

 

Hallo,

klar geht das:

Option Explicit

Private Declare PtrSafe Function SetWindowPos Lib "user32.dll" ( _
ByVal hwnd As LongPtr, _
ByVal hWndInsertAfter As LongPtr, _
ByVal x As Long, _
ByVal y As Long, _
ByVal cx As Long, _
ByVal cy As Long, _
ByVal wFlags As Long) As Long
Private Declare PtrSafe Function FindWindowA Lib "user32.dll" ( _
ByVal lpClassName As String, _
ByVal lpWindowName As String) As LongPtr

Private Const HWND_TOPMOST As LongPtr = -1
Private Const SWP_NOSIZE As Long = &H1
Private Const SWP_NOMOVE As Long = &H2
Private Const GC_CLASSNAMEUSERFORM As String = "ThunderDFrame"

Private Sub UserForm_Activate()
Dim lngptrHwnd As LongPtr
lngptrHwnd = FindWindowA(GC_CLASSNAMEUSERFORM, Caption)
Call SetWindowPos(lngptrHwnd, HWND_TOPMOST, _
0&, 0&, 0&, 0&, SWP_NOMOVE Or SWP_NOSIZE)
End Sub

 

Hallo Nepumuk,

danke erstmal, aber kannst Du mir auch was dazu schreiben?
Wo packe ich den Code rein Wie heisst die UserForm in deinem Code?
"ThunderDFrame"?
Bin Anfänger und verstehe den Code nicht,,

 

Hallo,

ThunderDFrame ist der Klassenname des Userforms, das ist eine interne Bezeichnung und danach sucht die Funktion FindWindowA.

Du kannst den Code so wie er ist in das Modul deines Userforms kopieren, eine Anpassung ist nicht nötig.

 

Hab es versucht, aber wenn ich z.B. danach den Explorer öffne, fällt die Userform dahinter...
Oder sollte man die Userform in bestimmeten Zeitintervallen neu aktivieren, hatte sowieso vor, einen Countdown oder Uhr mit darzustellen?

 

Hallo,

kann ich mir nicht vorstellen, das hat bisher immer funktioniert. Hast du den Code auch in das Modul des Userforms kopiert und nicht irgendwoandershin?

 

Ja, hab ich. Wenn ich dann auf die UserForm gehe und starte geht sie in der Fenstermitte auf und ich kann sie schieben. Aktiviere ich dann den Explorer ist sie dahinter verschwunden. *frown.gif*

 

Hallo,

teste mal mit der Mappe im Anhang:

 

Diese Datei funktioniert, danke.

 

Hallo,

und was ist an deiner Mappe anders dass es damit nicht funktioniert?

 

Hallo,

auch ich habe versucht diesen Code zu verwenden und dieser funktioniert auch so wie von Stefan67! gewünscht.
Ich möchte aber gerne, dass Excel ausgeblendet bleibt und die Userform sich so verhält, wie andere Windows Anwendungen auch, also nur beim erstmaligen Start sollte dieser im Vordergrund aufscheinen. Ecxel selbst sollte ausgeblendet bleiben.

Wie müsste der Code abgeändert werden?

Danke und Gruß, Elmar