Office: Variable Range VBA

Hallo zusammen
ich weiß momentan häufen sich meine Probleme, aber das ist wohl so je mehr man sich mit VBA beschäftigt und noch nicht viel weiß. :-)
Ich habe einen Code in dem Spalten von "I:BG" ausgeblendet werden und die Spalte mit der ActivCell wieder eingeblendet wird. Das ist gut und funktioniert auch.
Nun möchte genau in dieser Spalte mit der ActivCell (Das kann immer eine andere Spalte sein zwischen I:BG) einen bereich von Row 4 bis UsedRange Selektieren. Anschließend soll nach leeren Zellen in diesem Bereich gesucht werden und dann die betreffende Row komplett ausgeblendet werden.
Damit erreiche ich das ich nur noch Zeilen mit einem Wert zu sehen sind.
Mein Makro hängt sich aber immer auf, wenn ich den bereich selektieren möchte. Ich habe diverses ausprobiert:-( - es klappt nichts.
Meinen zum Teil falschen Code hänge ich mal dran.

Code:

Sub Column_weg()
' Spalten ausblenden
' Tastenkombination: Strg+a
Dim bereich As Range
Dim zelle As Range
Dim lng As Long

If ActiveCell.Row = "3" Then
        Columns("I:BG").EntireColumn.Hidden = True  'spalten ausblenden
        ActiveCell.EntireColumn.Hidden = False      'aktive spalte wieder einblenden
        
                [color=red]lng = Sheets("Kasse 2009").UsedRange.Rows.Count
                bereich = Range(ActiveCell, ActiveCell.Offset(lng, 0)).Select
                For Each zelle In bereich
                If zelle.Value = "" Then
                EntireRow.Hidden = True
                End If
                Next zelle[/color]
Else
MsgBox " Bitte die Aktive Zelle nur in Zeile -3- wählen!"
Exit Sub
End If
End Sub

Danke wie immer für die hier stets tolle und freundliche Hilfe.
Gruß Norbert

 

Hallo Norbert,

ungetestet.

Code:

Option Explicit

Sub Column_weg()
    ' Spalten ausblenden
    ' Tastenkombination: Strg+a
    Dim zelle As Range
    Dim lng As Long
    If ActiveCell.Row = "3" Then
        Columns("I:BG").EntireColumn.Hidden = True  'spalten ausblenden
        ActiveCell.EntireColumn.Hidden = False      'aktive spalte wieder einblenden
        lng = Sheets("Kasse 2009").UsedRange.Rows.Count
        For Each zelle In Range(ActiveCell, ActiveCell.Offset(lng, 0))
            If zelle.Value = "" Then
               Rows(zelle.Row).EntireRow.Hidden = True
            End If
        Next zelle
    Else
        MsgBox " Bitte die Aktive Zelle nur in Zeile -3- wählen!"
        Exit Sub
    End If
End Sub

Gruß Hajo

 

Hallo Hajo
funktioniert tipp, topp.
Vielen Dank
Gruß Norbert