Office: (Office 2019) VBA Code nicht vollständig ausgeführt

Hallo Zusammen

Ich habe einen Code erstellt der eine Liste in Excel importiert und dann alle Zeilen löscht, welche in der Spalte C entweder "Ersatz" oder "Unfall" enthalten.
Wenn ich den Code Schritt für Schritt ausführe, dann macht er alles richtig.
Sobald der Code aber selber ganz durchläuft werden die Positionen "Unfall" und "Ersatz" nicht erkannt und die Zeilen nicht gelöscht.

Kann da vieleicht jemand etwas erkennen?

Private Sub Workbook_Open()

If MsgBox("Um auf die neusten Mitgliederdaten zugreifen zu können, musst du diese zuerst aktualisieren! " & vbCr & vbLf & "Möchtest du das jetzt machen?", vbYesNo) = vbYes Then
MsgBox "Logge dich bei der HG Verwaltung ein." & vbCr & vbLf & "Links im Menü unter Mitglieder -> Mitglieder kannst du anschliessend durch einen Rechtsklick auf das Wort Excel Export (oben in der Mitte) die Daten herunterladen." & vbCr & vbLf & "Erledige dies. " & vbCr & vbLf & "Der Rest wird von Excel erledigt."
ThisWorkbook.FollowHyperlink "HG Verwaltung"

MsgBox "Wenn du die Excel Datei heruntergeladen hast klicke hier auf OK. Excel wird dann die Daten automatisch importieren.", vbOKCancel

ActiveWorkbook.Connections("Abfrage - Mitglieder").Refresh
Application.Wait Now + TimeSerial(0, 0, 4) 'wartet 4 Sekunden
Kill "C:\Users\Bidub\Downloads\mitglieder.xlsx"
MsgBox "Die Daten wurden erfolgreich importiert, ich brauche nun noch einen Moment um Sie zu ordnen..."

Sheets("Daten HG Verwaltung").Visible = True
Sheets("Daten HG Verwaltung").Select

Cells.Replace What:="" & Chr(10) & "", Replacement:="", LookAt:=xlPart, SearchOrder:= _
xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=False

Dim i As Integer, anz As Integer
anz = [=COUNTA(c1:c1000)] + 1

For i = 1 To anz
anz = [=COUNTA(c1:c1000)] + 1
If Cells(i, 3) = "Ersatz" Or Cells(i, 3) = "Unfall" Then
ActiveSheet.Rows(i).Delete
i = i - 1
End If
If i = anz Then
Exit For
End If
Next

Danke für eure Hilfe :)

 

nur wenige schauen auf Deinen Rechner und sehen die Datei.
Ich möchte gerne den Fehler im Original sehen.

Ich baue keine Datei nach. Die Zeit hat schon jemand investiert.

Ein Nachbau sieht meist anders aus als das Original. <B>Darum sollte das Original verlinkt werden.</b>

Wenn du an Stelle einer Demomappe deine Originalmappe hochladen willst, diese aber sensible Daten enthält, kannst du diese Daten
Hinweis - Anonymisierung und Pseudonymisierung von Beispielmappen - MS-Office-Forum
änderrn.
Der Name einer hochgeladenen Mappe wird im Beitrag automatisch angezeigt, sodass es bei Verwendung von aussagekräftigen Namen leichter fällt, sie später im Ablageordner wiederzufinden und sie gedanklich einem bestimmten Thema zuzuordnen. Namen wie Muster*, Test*, Mappe*, Beispiel*, Fehler*, Kalender* usw. sind so allgemein, dass eine Zuordnung zu einem Thema unmöglich gemacht wird.
Es sollte ein aussagekräftiger Name sein.

Benutze hier im Forum die Funktion zum hochladen. Falls Du die nicht benutzen möchtest beachte, von unsicheren Servern wie z.B. www.file-upload.net lade ich keine Datei runter. (lt. Einschätzung meines Virenprogramms)3

Bilder lade ich mir nicht runter, da Excel damit nichts anfangen kann.

Bilder statt Datei | Excel ist sexy!

Hochgeladene Bilder können zwar als solche in Excel importiert werden, sind jedoch bei der Lösung von Problemen nicht sehr hilfreich, da man die eigentlichen Daten nicht ohne große und zeitraubende Umwege direkt in die Tabelle übertragen kann.

Das ist nur meine Meinung zu dem Thema.

 

Guten Abend Hajo

Hiermit lade ich das Dokument, dass einfach diesen Teil enthält, hoch.
Es ist das Dokument "HGD_Verwaltung_Test" und damit es funktioniert müsste die zweite Datei "mitglieder" in den Download Ordner (bei Windows) gespeichert oder der Code angepasst werden.

Freundliche Grüsse
Beat

 

Hallo,

bei mir funktioniert das.

 

Hallo

Danke für die Rückmeldung.
Äusserst komisch...

Bei mir funktioniert es bis ich die letzte MsgBox mit OK bestätige dann erscheinen die gelöschten Werte wieder.

 

Hallo,

ich habe dein Makro etwas modifiziert - insbesondere die Passage, wo du Zeilen aus der Tabelle löschst, war sehr fragwürdig.

Code:

Option Explicit
Private Sub Workbook_Open()

   If MsgBox("Um auf die neusten Mitgliederdaten zugreifen zu können, musst du diese zuerst aktualisieren! " & vbCr & vbLf & _
         "Möchtest du das jetzt machen?", vbYesNo) = vbYes Then
    
      MsgBox "Logge dich bei der HG Verwaltung ein." & vbCr & vbLf & _
         "Links im Menü unter Mitglieder -> Mitglieder kannst du anschliessend durch einen Rechtsklick " & _
         "auf das Wort Excel Export (oben in der Mitte) die Daten herunterladen." & vbCr & vbLf & _
         "Erledige dies. " & vbCr & vbLf & "Der Rest wird von Excel erledigt."
      ThisWorkbook.FollowHyperlink "https://www.hgverwaltung.ch/#/login"
  
      MsgBox "Wenn du die Excel Datei heruntergeladen hast klicke hier auf OK. Excel wird dann die Daten automatisch importieren.", vbOKCancel
    
      ActiveWorkbook.Connections("Abfrage - Mitglieder").Refresh
      Application.Wait Now + TimeSerial(0, 0, 4)  'wartet 4 Sekunden
      Kill "C:\Users\Bidub\Downloads\mitglieder.xlsx"
      MsgBox "Die Daten wurden erfolgreich importiert, ich brauche nun noch einen Moment um Sie zu ordnen..."
    
      Dim lstMitglieder As ListObject, lstRow As ListRow
      Dim IdxNName As Long, NName As String
      Dim Idx As Long
    
      With Sheets("Daten HG Verwaltung")
        .Visible = True
        .Activate
      
        .Cells.Replace What:="" & Chr(10) & "", Replacement:="", LookAt:=xlPart, SearchOrder:= _
              xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=False
        
         Set lstMitglieder = .ListObjects("Mitglieder")
         IdxNName = lstMitglieder.ListColumns("Nachname").Index
        
         For Idx = lstMitglieder.ListRows.Count To 1 Step -1
            Set lstRow = lstMitglieder.ListRows(Idx)
            NName = lstRow.Range.Cells(IdxNName)
            If NName = "Ersatz" Or NName = "Unfall" Then
               lstRow.Delete
            End If
         Next Idx
      End With

      MsgBox "So! Nun bin ich fertig"
  
   Else
      MsgBox "Die Daten wurden nicht erneuert"
   End If
End Sub

Das lässt sich leicht erklären. Du rufst im VBA-Code eine PowerQuery-Abfrage auf:
ActiveWorkbook.Connections("Abfrage - Mitglieder").Refresh
Application.Wait Now + TimeSerial(0, 0, 4) 'wartet 4 Sekunden
und wartest hinterher noch 4 Sekunden, um dann im weiteren Makro fortzufahren.
Schaut man sich die Abfrage-Eigenschaften der Connection "Abfrage - Mitglieder" an:

so sieht man, dass du dort die Checkbox "Aktualisieren im Hintergrund zulassen" angehakt hattest. Entfernt man dieses Häkchen, erfolgt die Abfrageaktualisierung nicht mehr asynchron sondern synchron, d.h. das Makro, das diese Abfrage aufruft, muss warten, bis die Aktualisierung vollständig erfolgt ist, und dann erst kann das Makro weiter fortfahren. Wenn du die Einstellung wie im Bild verwendest, kannst du sogar die 4 Sekunden-Wartezeit entfernen.

 

Guten Abend

Ja das glaube ich sofort das mein Code für Excel kenner an gewissen Stellen sehr fragwürdig daher kommt
Ich habe das Programmieren nie wirklich gelernt und bastle mir jeweils für meinen Eigengebrauch irgendwelche Cods aus Tutorials und Anleitungen zusammen. Oftmals mit Erfolg... wenn auch nicht sonderlich schön oder effizient
Viele Wege führen nach Rom, wobei längst nicht alle asphaltiert sind.
Dennoch herzlichen Dank für den optimierten Code. Ich habe diesen sehr gerne eingebaut und es funktioniert super.

Und herzlichen Dank für den Hinweis mit der Hintergrundaktualisierung. Daran hat es gelegen.
Sobald dieses Häkchen weg war, funktionierte es ohne Probleme.

Merci!

Ich wünsche allen einen schönen Abend.