Office: [VBA] CSV einlesen, mit zeilennummer

Hallo zusammen,

ich versuche eine CSV einzulesen, das klappt recht gut.
Jedoch wrüde ich gerne ein Zeilennummer (ID, Messpunkt) vor meine Daten schreiben lassen.

doch wie mache ich das ohne das ich eine Schleife duchlaufen lassen muss, kann ich die CSV Daten so verändern das mir noch ein Zeilennummer dazu gebaut wird.

das ist mein Aktueller Code:

Code:

Sub test_Inport()
    Call ImportCSV("Export.csv", ";", "W3")
End Sub

Sub ImportCSV(ByVal csvFileName As String, ByVal delimiter As String, ByVal startCell As String)
    Dim csvFilePath As String
    Dim importRange As Range
    Dim ws As Worksheet
    Dim fileSystemObject As Object
    Dim queryTable As queryTable
    Dim rowCount As Long
    Dim i As Long

    ' Aktives Blatt und Startzelle
    Set ws = ActiveSheet
    Set importRange = ws.Range(startCell)

    ' Datei-Pfad
    csvFilePath = ThisWorkbook.Path & "\" & csvFileName
   
    ' Prüfen, ob die Datei existiert
    Set fileSystemObject = CreateObject("Scripting.FileSystemObject")
    If Not fileSystemObject.FileExists(csvFilePath) Then
        MsgBox "Die Datei '" & csvFileName & "' wurde nicht gefunden im Verzeichnis: " & ThisWorkbook.Path, vbExclamation
        Exit Sub
    End If
   
    ' Import der CSV-Datei
    With importRange
        ' Daten-Import
        Set queryTable = ws.QueryTables.Add(Connection:="TEXT;" & csvFilePath, Destination:=importRange)
        With queryTable
            .TextFileParseType = xlDelimited
            .TextFileConsecutiveDelimiter = False
            .TextFileTabDelimiter = False
            .TextFileSemicolonDelimiter = (delimiter = ";")
            .TextFileCommaDelimiter = (delimiter = ",")
            .TextFileSpaceDelimiter = False
            .TextFileOtherDelimiter = IIf(delimiter <> ";" And delimiter <> ",", delimiter, False)
            .Refresh BackgroundQuery:=False
        End With
    End With
   
    ' Zeilennummern hinzufügen
    rowCount = ws.Cells(ws.Rows.Count, importRange.Column).End(xlUp).Row ' Letzte Zeile in der importierten Spalte
    For i = 1 To rowCount
        ws.Cells(importRange.Row + i - 1, importRange.Column - 1).Value = i ' Zeilennummer in die vorherige Spalte setzen
    Next i
   
    ' Entfernen der QueryTable nach dem Import, um die Verbindung zu lösen
    queryTable.Delete

    ' Aufräumen
    Set fileSystemObject = Nothing
    Set queryTable = Nothing
End Sub

 

Moin Muecke,

entweder die Zeilennummer ist in Deiner CSV enthalten, oder Du musst sie beim Import per VBA-Schleife dazu schreiben.
Als einzige mir bekannte Alternative käme noch eine Hilfsspalte mit der Formel =SPALTE() (ggf. mit einem Offset) in Frage.

Grüße

 

Servus,

leider enthält die CSV (beziehungsweise mein Export aus einem anderen Programm) keine Zeilennummer oder ID.

Dann bleinde ich bei der Schleife, wie im Code vorhanden.

Vielen Dank für das Feedback!
Mücke

 

Hi,

lies die Datei doch mit PowerQuery ein, da kannst du dann auch gleich deine Zeilennummer hinzufügen.