Office: (Office 2016) VBA Daten in Tabellenblatt 1 Filtern und in Tabellenblatt 2 übertragen

Hallo zusammen,

ich habe mir bereits ein Makro gebaut mit dem ich nach bestimmten Daten in Tabelle 1 filtere/suche. Sind diese vorhanden, werden die kompletten Zeilen in Tabelle 2 kopiert.
Das klappt soweit schon echt super. Einziges Manko, es dauert echt lang. So ca. 2-3 Minuten.
Vielleicht habt ihr einen Verbesserungsvorschlag für mich?

Code:

Sub Kunden_A_&_B()

Dim i As Long, j As Long

Dim lz As Integer

 j = 2

Sheets("Gesamtliste Kunden").Select

For i = 2 To Sheets("Gesamtliste Kunden").Cells(Rows.Count, "M").End(xlUp).Row

   If Sheets("Gesamtliste Kunden").Cells(i, "M") = "Kunde A" Then

     Range(Cells(i, "A"), Cells(i, "Q")).Copy _

       Destination:=Sheets("Kunden A & B").Range("A" & j)

     j = j + 1

   End If

Next

For i = 2 To Sheets("Gesamtliste Kunden").Cells(Rows.Count, "M").End(xlUp).Row

   If Sheets("Gesamtliste Kunden").Cells(i, "M") = "Kunde B" Then

     Range(Cells(i, "A"), Cells(i, "Q")).Copy _

       Destination:=Sheets("Kunden A & B").Range("A" & j)

     j = j + 1

   End If

Next

End Sub

Vielen Dank schon mal
Liebe Grüße
Charlotte

 

Hi Charlotte,

wenn du keine sortierte Übertragung (also erst alle "Kunden A" und danach alle "Kunden B" benötigst) benötigst, kannst du mithilfe einer Select-Case-Anweisung gleichzeitig beide Bedingungen abfangen, also sowohl "Kunde A" als auch "Kunde B":

Code:

Dim i As Long, j As Long
j = 2
With Sheets("Gesamtliste Kunden")
    For i = 2 To .Cells(Rows.Count, "M").End(xlUp).Row
       Select Case .Cells(i, 13)
         Case "Kunde A", "Kunde B"
            .Range(.Cells(i, 1), .Cells(i, 17)).Copy Destination:=Sheets("Kunden A & B").Cells(j, 1)
            j = j + 1
       End Select
    Next
End With

Noch zwei allgemeine Hinweise:
- nach Möglichkeit sollte man bei Zelladressen die Spaltenbezeichnung nicht als Buchstaben sondern als Zahl schreiben, weil Excel intern die Adressen bereits als Cells(Zeilennummer, Spaltennummer) speichert. Wenn man nun anstelle der Spaltennummer den Spaltenbuchstaben verwendet - was natürlich kein Fehler ist!! - muss Excel jedoch intern erst den Spaltenbuchstaben in die Spaltennummer umrechnen - das kostet aber Zeit.
- man kann Code vereinfachen, indem man mit With-Anweisungen auf Objekte (im o.g. Code das Arbeitblatt) referenziert, die man dann im weiteren Verlauf des Codes nicht mehr benennen muss. Zu beachten ist dabei jedoch, dass allen Objekten innerhalb des referenzierten Objektes, wie hier die Zelladressen, ein Punkt (.) vorangestellt werden muss - das ist für Excel das Signal, dass sich dieses Objekt innerhalb des mit With festgelegten Objektes befindet.
Außerdem kann man mit einer Wit-Anweisung auf den Select-Befehl verzichten, der ebenfalls den Code verlangsamt.

---

 

Vielen lieben Dank, Beverly.
Das hilft mir schon sehr. Es geht tatsächlich fixer.
Auch für die beiden Hinweise. Die werde ich sehr gerne für die Zukunft berücksichtigen. :-)