Office: VBA - Datensätze ans Ende einer anderen Tabelle kopieren

Hallo zusammen,


ich habe gerade eine "Abrechnungs"-Datei für einen Kindergartenbasar erstellt. Es wäre klasse, wenn man per Schaltfläche die Datensätze aus der Tabelle "Kaeufer" ans Ende der Tabelle "Verkaeufe" kopieren könnte und den Tabelleninhalt in Tabelle "Kaeufer" wieder löscht.

Für Hilfe wäre ich sehr dankbar!

Vielen Dank!

 

Hi,

das kannst du z.B. mit folgendem Makro realisieren:

Code:

Sub Verkaeufe()
    Dim lngLetzte1 As Long
    Dim lngLetzte2 As Long
    lngLetzte1 = Cells(Rows.Count, 3).End(xlUp).End(xlUp).Row
    lngLetzte2 = Application.Max(Columns(7)) + 8
    Range(Cells(8, 3), Cells(lngLetzte1, 4)).Copy
    Cells(lngLetzte2, 8).PasteSpecial Paste:=xlValues
    Range(Cells(8, 3), Cells(lngLetzte1, 4)).ClearContents
End Sub

---

 

Hallo,

1) ich weiß nicht, wie du dir das vorgestellt hast: ein Arbeitsblatt, das kennwortgeschützt ist, hier hochzuladen. Zum Glück wusste ich, wie man solch überflüssigen Kennwortschutz entfernt, ohne das Kennwort zu kennen.

2) Im Arbeitsblatt hast du 3 strukturierte Tabellen eingefügt mit jeder Menge Leerzeilen. Bei strukturierten Tabellen tut man das nicht, Leerzeilen (quasi als Vorratszeilen) anzufügen - es ist schade, um den so vernichteten Plattenspeicher durch unnötiges Aufblähen der Excel-Datei. Ich habe daher die Tabellenleerzeilen entfernt.

3) Legt man eine strukturierte Tabelle an, was durchaus viele Vorteile hat, so sollte man den Standard-Tabellennamen, den Excel dabei vergibt, abändern durch einen aussagekräftigen Tabellennamen.
Also statt "Tabelle1" zB. "tbKäufer" bzw. statt "Tabelle2" zB. "tbVerkäufe" und statt "Tabelle3" zB. "tbAbrechnung". Dann weiß man auch in einem halben Jahr, wenn man sich nicht mehr so genau an alle Details der Datei erinnert, sofort, um welche Tabelle es sich handelt.
Ich habe daher vorgenannte Namensänderung durchgeführt.

4) Ferner habe ich die Formel, die in der 1. Spalte von "tbVerkäufe" enthalten ist,
von =WENN(H8>0;1;"") bzw. =WENN(H9>0;G8+1;"") abgeändert auf
die einheitliche Formel =WENN(H8>0;N(G7)+1;"") usw.
Damit gibt es in dieser Spalte keine Formelinkonsistenz und der Spalteninhalt wird automatisch ergänzt, sobald weitere Zeilen an die Tabelle angefügt werden - wie es ja auch durch das nachfolgende Makro geschieht.

4) Ich habe in das allgemeine VBA-Codemodul "Modul2" folgendes Makro eingefügt:

Code:

Option Explicit

Sub AnfügenVerkäufe()
  
   Dim ws As Worksheet
   Dim lstObj1 As ListObject, lstObj2 As ListObject
   Dim rng1 As Range, rng2 As Range
   Dim rowCt1 As Long, rowCt2 As Long, Zl As Long
  
   Set ws = ActiveSheet
 ' ws.Unprotect Password:=""
  
   Set lstObj1 = ws.ListObjects("tbKäufer")   'Tabelle1 -> tbKäufer
   Set lstObj2 = ws.ListObjects("tbVerkäufe") 'Tabelle2 -> tbVerkäufe
  
   Set rng1 = lstObj1.DataBodyRange
   Set rng2 = lstObj2.DataBodyRange
   rowCt1 = lstObj1.ListRows.Count
   rowCt2 = lstObj2.ListRows.Count
  
   rng1.Cut Destination:=rng2.Resize(1, 1).Offset(rowCt2, 1)
  
   For Zl = 1 To rowCt1
     lstObj1.ListRows(1).Delete
   Next Zl
  
 ' ws.Protect Password:=""
  
End Sub

Die beiden Makrozeilen (wovon die erste den Arbeitsblattschutz aufhebt und die zweite den Arbeitsblattschutz wieder einführt) habe ich als Kommentarzeilen eingefügt. Falls du den Arbeitsblattschutz wieder haben möchtest, müsstest du das Hochkomma am Anfang der Zeile entfernen (und ferner das Passwort am Ende der Zeile zwischen den beiden Anführungszeichen im Klartext einfügen). Welchen Schutz das dann bieten sollte, musst du selbst wissen.

5) Ferner habe ich, wie von dir gewünscht, oberhalb der Tabelle "tbVerkäufe" einen Button "Käufer -> Verkäufe" eingefügt und ihn mit obigem Makro verknüpft.

 

Für die Realisierung der Fragestellung muss man keinen Blattschutz aufheben - siehe mein Code...

---