Office: (Office 365) [VBA] .Documents.Open -> Laufzeitfehler 91

Hallo zusammen,

bekomme aktuell den Laufzeitfehler 91 an der Codestelle, wo ich versuche ein Word Dokument zu öffnen (Set wdDoc = wdApp.Documents.Open(wbBook.Path & "\" & stWordDocument)), das im gleichen Pfad wie das Excel Workbook liegt. Hat jemand ne Idee wo im Code der Fehler liegt?

Code:

Sub Export_2_Doc()

    'Bezeichnung der Word Vorlage
    Const stWordDocument As String = "Test_Word.docx"
    
    'Word Objekte
    Dim wdApp As Word.Application
    Dim wdDoc As Word.Document
    
    'Excel Objekte
    Dim wbBook As Workbook
    Dim wsSheet As Worksheet
    
    'Neue Wordinstanz und Wordvorlage "Test_Word.docx" öffnen
    Set wdApp = New Word.Application
    Set wdDoc = wdApp.Documents.Open(wbBook.Path & "\" & stWordDocument)
    
    'Bereich aus Excel inkl. Format kopieren und an Textmarke einfügen
    With wdDoc
        Set wsSheet = ThisWorkbook.Worksheets("Form")
        wsSheet.Range("D3:K31").Copy 'Bereich mit den zu exportierenden Daten
        wdDoc.Bookmarks("test").Range.PasteSpecial Link:=False, DataType:=wdPasteOLEObject, _
        Placement:=wdInLine, DisplayAsIcon:=False
        .SaveAs2 wbBook.Path & "\\MaterialAccess_" & Form.Range("F9") & "_" & Format(Now, "yyyy-mm-dd_hhmm") & ".docx"
        .Save
        .Close
    End With
    
    'Word Applikation schließen
    wdApp.Quit
    
    'Variablen nullen
    Set wdDoc = Nothing
    Set wdApp = Nothing
    
    'Benachrichtigung nach erfolgreichem Export
    MsgBox "Document created", vbInformation

End Sub

 

Hallo denpei,

du bist hier im Excel-Forum...

In Word-VBA kenne ich mich nicht aus, aber auf den ersten Blick würde ich vermuten, dass das Objekt "wbBook" nicht zugewiesen ist. Sthet jedenfalls nirgends im Code.

Gruß,
Lutz

 

Haiaiai, das wars natürlich. Danke für den Hinweis! Habe den obigen Code um "Set wbBook = ThisWorkbook" ergänzt. Nun läufts. Bzgl. Excel Forum bin ich doch mit Excel VBA Code hier richtig, oder nicht?

Herzliche Grüße,
denpei