Office: (Office 2010) VBA - Formel kopieren - variabler bereich

Hallo,

ich will per Makro eine Formel in eine Spalte einfügen. Diese Fomel soll dann per Autofill kopiert werden.

Range("F2").Select
ActiveCell.FormulaR1C1 = _
"=IF(AND(RC[-2]<>""EP"",RC[-2]<>"""",RC[-3]<>""Rose"",RC[-3]<>""Tulpe"",RC[-3]<>""Lilie"",RC[-3]<>""Gummibaum"",RC[-3]<>""Müller""),RC[3],"""")"
Range("F2").Select
Selection.AutoFill Destination:=Range("F2:F151")
Range("F2:F151").Select

Jedoch wird mir im Makro recorder ein fester Bereich aufgezeichnet. Den Bereich zu verlängern bis 65.500 bringt leider nichts, da sonst x leere Seiten angezeigt werden, die ich dann wiederum manuell löschen müsste.

Kennt jemand einen Trick?

Regnerische Grüße

Bernhard

 

Hallo

in meinem Test habe ich zuerst die letzte beschriebene Zeile in Spalte A ermittelt
und dann den Code so abgeändert (ohne das überflüssige select)

Code:

Sub test()
Dim lngLetzte As Long
lngLetzte = Cells(Rows.Count, 1).End(xlUp).Row
Range("F2").FormulaR1C1 = _
"=IF(AND(RC[-2]<>""EP"",RC[-2]<>"""",RC[-3]<>""Rose"",RC[-3]<>""Tulpe"", RC[-3]<>""Lilie"",RC[-3]<>""Gummibaum"",RC[-3]<>""Müller""),RC[3],"""")"
Range("F2").AutoFill Destination:=Range("F2:F" & lngLetzte)
End Sub

MfG Tom

 

Hi Bernhard,

du musst nicht die R1C1-Schreibweise für das Eintragen der Formel verwenden - mittels Eigenschaft .FormulaLocal kannst du die Formel ganz normal eintragen:

Code:

Dim lngLetzte As Long
' letzte belegte Zeile im Tabellenblatt
lngLetzte = Cells.Find(What:="*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
Range("F2").[COLOR=#0000cd][B]FormulaLocal[/B][/COLOR] = "=WENN(UND(D2<>""EP"";D2<>"""";C2<>""Rose"";C2<>""Tulpe"";C2<>""Lilie"";C2<>""Gummibaum"";C2<>""Müller"");I2;"""")"
Range("F2").AutoFill Range(Cells(2, 6), Cells(lngLetzte, 6))

Oder du verwendest die englische Formelschreibweise und die Eigenschaft .Formula

Code:

Range("F2").[COLOR=#0000cd][B]Formula[/B][/COLOR] = "=IF(AND(D2<>""EP"",D2<>"""",C2<>""Rose"",C2<>""Tulpe"",C2<>""Lilie"",C2<>""Gummibaum"",C2<>""Müller""),I2,"""")"

Beachte, dass dabei außer der englischen Funktionsnamen auch das ";" durch "," ersetzt werden muss.



Bis später,
Karin

 

SSSSUUUPPPEERR... danke für die Hilfe. Ich habe mir gleich mal die Formeln gemerkt.

Sonnige Grüße aus Nürnberg

Bernhard