Office: (Office 2019) VBA Formular rechnet nicht

Hallo zusammen,

ich habe ein Problem mit der angehängten Datei.

Diese besteht aus:

• Der Tabelle1 in welcher sich ein CommandButton befindet, der nichts weiter tut, als die UserForm zu öffnen.
• Einer UserForm in der Benutzereingaben getätigt werden sollen.
  
• Einem Basismodul wo die Benutzereingaben in nummerische Werte umgewandelt werden und mit denen dort gerechnet werden soll. Anschließend soll der Ausgabewert in eine Textbox zurückgeschrieben werden.
• Einem Klassenmodul in dem die Eingabewerte validiert werden sollen. Außerdem soll immer wenn eine Textbox geändert wird der Code aus dem Basismodul ausgeführt werden.

Die Erwartungshaltung ist halt, dass die Berechnung durch das Klassenmodul automatisch durchgeführt wird, wenn sich etwas an den Eingaben in der Userform ändert. Das Ergebnis soll dann in die entsprechenden Textboxen übergeben werden. Leider geschieht das nicht.

Falls man sich fragt, warum ich das ganze so komplex aufgebaut habe, dann liegt das daran, dass nachher noch mehrere Formular hinzukommen sollen, die ich dann anhand des UF.Name identifizieren möchte. So muss ich wiederholende Variablen nicht immer wieder erneut deklarieren. Den Code in der Klasse möchte ich auch nur einmal haben um das Ganze wartungsfreundlicher und schlanker zu haben.

Hier nochmal der Übersicht halber der Code aus den Komponenten.

Userform

Code:

'Erstellen des Arrays mit Zuweisung der Klasse zur Eingabevalidierung
Dim MeTxTBox(5)     As New clsWaermetauscherBerohren

'Initialisierung / Einrichtung der Userform
Private Sub UserForm_Initialize()
    'Zuweisung zum Klassenmodul
    Set MeTxTBox(3).TxTBox = txtDurchmesserRohr
    Set MeTxTBox(4).TxTBox = txtWanddickeRohr
    Set MeTxTBox(5).TxTBox = txtLaengeRohr
End Sub

Basismodul

Code:

Option Explicit

'Definition der Variablen
Dim dblDurchmesserRohr      As Double
Dim dblKDurchmesserRohr     As Double
Dim dblWanddickeRohr        As Double
Dim intLaengeRohr           As Integer
Dim dblMasseRohr            As Double
Dim dblVolumen              As Double

'Erstellen der Funktion PI
Public Function PI() As Double
  PI = 4 * CDec(Atn(1))
End Function

'Simuliert den Klick auf einen Berechnungs Button
Sub cmdBerechnung_Click(UF As Object)

'Hier werden die Objekte definiert
  If UF.Name = "frmWaermetauscherBerohren" Then 'Fragt ab ob es sich um die passende Userform handelt.
    With frmWaermetauscherBerohren
      'Eingabewerte in nummerischen Wert konvertieren
      dblDurchmesserRohr = Val(.txtDurchmesserRohr)
      dblWanddickeRohr = Val(.txtWanddickeRohr)
      intLaengeRohr = Val(.txtLaengeRohr)
      
      'Berechnungen der Ausgabewerte
      dblKDurchmesserRohr = dblDurchmesserRohr - 2 * dblWanddickeRohr
      dblVolumen = (PI() * intLaengeRohr / 4) * (dblDurchmesserRohr ^ 2 - dblKDurchmesserRohr ^ 2) / 1000000
      dblMasseRohr = dblVolumen * 8
      
      'Übergabe der Variablen in die Texboxen
      .txtMasseRohr = Format(dblMasseRohr, "0.000#")
    End With
  End If
End Sub

Klassenmodul

Code:

Option Explicit

'Erstellen des public Events
'Dieses wird in allen Modulen verfügbar sein
'Durch Set MeTxTBox(0).TxTBox kann eine Textbox dieser Klasse zugewiesen werden
Public WithEvents TxTBox As MSForms.TextBox

'Wird ausgeführt wenn ein Textfeld geändert wird
Private Sub TxtBox_Change()
  Call cmdBerechnung_Click(TxTBox.Parent)
End Sub

'Validierung von Textboxen
Private Sub TxTBox_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
'Erlaubt nur Ziffern und Komma
If InStr("1234567890.,-" & Chr$(8), Chr$(KeyAscii)) = 0 Then
  KeyAscii = 0
End If
'Umwandlung von Komma in Punkt
If KeyAscii = Asc(",") Then
   KeyAscii = Asc(".")
End If
End Sub

Ich hoffe ich konnte mein Anliegen ausreichend genau schildern, bei Fragen einfach melden.

Vielen Dank im Voraus an alle Hilfsbereiten!

 

Hi,

Dein Userform in der Mappe heißt fraRohr - demnach muss die Abfrage so lauten:

Code:

If UF.Name = "fraRohr" Then 'Fragt ab ob es sich um die passende Userform handelt.
    With UF

 

Hi,

genauer muss es heißen:
TxTBox.Parent liefert fraRohr.

 

ah... das dieser Frame mir das Genick bricht, hatte ich nicht bedacht!

Vielen Dank Boris!

Kann man das beim Debuggen irgendwie herausfinden, oder muss man das einfach wissen?

 

Hi,

Kann man das beim Debuggen irgendwie herausfinden

Ich hab auf die Schnelle nen Haltepunkt gesetzt bei Call cmdBerechnung_Click(TxTBox.Parent) , dann mit F8 weiter, und mir bei cmdBerechnung zu Beginn den UF.Name per MsgBox anzeigen lassen:

Sub cmdBerechnung_Click(UF As Object)
MsgBox UF.Name
....
End Sub

 

okay, dafür muss man natürlich erst einmal auf die Idee kommen, dass es an dem Namen der UserForm handelt.

Da zeigt sich wohl meine mangelnde Erfahrung! Vielen Dank für die Lösung und den Hinweis zur Fehlerfindung.

 

Hi,

noch einfacher kannst Du das übrigens im Lokalfenster sehen.

 

ich glaube ich muss mich mal wirklich mehr mit dem Thema Fehlersuche beschäftigen. Was das Programmieren angeht bin ich eher Quereinsteiger. Dank deiner Anstöße habe ich es mittlerweile herausgefunden, wie ich im Lokalfenster die Werte der Variablen anzeigen lassen kann und anhand von Überwachungsausdrücken diese separat anzeigen lassen kann. Vielen Dank dafür!

 

Hi,

ich glaube ich muss mich mal wirklich mehr mit dem Thema Fehlersuche beschäftigen. Was das Programmieren angeht bin ich eher Quereinsteiger.

Ich finde, Du machst das schon sehr gut! Und das Thema "Fehlersuche" ist - gerade bei umfangreichen Programmen - absolut wichtig/unerlässlich. Hier gibt es bei Vielen doch noch große Defizite. Kann man sich also nicht genug "draufschaffen" ;-)

 

leider habe ich das Problem erneut, aber mit anderer (denke ich) Ursache...

Wie im Eingangsthread erwähnt, soll der Code so wenig wie möglich redundant sein. Deshalb habe ich mich dafür entschieden Funktionen als eine Art Modul in andere Dateien auszulagern.

Die Aufrufende Datei ist die Basis. Diese soll über Buttons andere Module nachladen können, die in einem fest definierten Pfad liegen. Das mit dem Laden der Module und der Userform scheint auch soweit wie gewünscht zu funktionieren.

Wenn sich dann aber anschließend das Formular öffnet und dort Eingaben getätigt werden, rechnet das Formular jedoch nicht.

Das richtige Formular wird jedoch ohne Fehlermeldung aufgerufen.



Auch beim Einzelschrittdurchlauf ist mir jetzt nichts aufgefallen, was ich ungewöhnlich finden würde...

 

Ich hoffe noch mal auf eure Hilfe. Ich habe jetzt diverse Variablen als Überwachungsausdrücke definiert und das Ganze im Einzelschritt-Modus durchlaufen lassen, aber ich finde den Fehler einfach nicht. Was mache ich falsch?