Office: VBA für Excel 2013:Leere Zeilen und Spalten ausblenden

Michael Schmohl · 27. September 2015

Hallo.

Ich möchte über ein Makro in einer Datei alle leeren Zeilen und Spalten ausblenden. Ich habe zwar schon einiges gefunden aber nur alte Makros. Nicht für den max. Bereich von 1048576 Zeilen und 16384 Spalten.
In unterschiedlichen Dateien können also unterschiedlichen Anzahl von Zeilen und Spalten leer sein.

Kann mir jemand dabei helfen?

Vielen Dank
Michael

:)

RPP63 · 28. September 2015

Hallo Michael!
Mal was für das aktive Worksheet (Du möchtest es ja universell anwenden können):
Code:

Sub Ausblenden()
Application.ScreenUpdating = False
Dim cnt As Long
With ActiveSheet.UsedRange
.Cells.EntireRow.Hidden = False
.Cells.EntireColumn.Hidden = False
For cnt = 1 To .Columns.Count
If WorksheetFunction.CountA(.Columns(cnt)) = 0 Then _
.Columns(cnt).Hidden = True
Next
For cnt = 1 To .Rows.Count
If WorksheetFunction.CountA(.Rows(cnt)) = 0 Then _
.Rows(cnt).Hidden = True
Next
End With
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wie die Performance in Riesen-Tabellen ist habe ich jetzt nicht überprüft, evtl. Berechnung ausschalten.

Gruß Ralf

Michael Schmohl · 28. September 2015

Hallo Ralf,

vielen Dank für die schnelle Antwort, aber...
Ich habe es eingefügt und ausprobiert, aber nichts tut sich?
Habe am Ende nochmal eine Textmeldung ausgeben lassen, um zu überprüfen, ob er überhaupt etwas macht. Die Meldung kommt, es werden aber keine Zeilen und Spalten ausgeblendet. Soll am Ende also wirklich so aussehen, das z.B. 10 Zeilen und 10 Spalten nur noch sichtbar sind und Rest grau, da ausgeblendet.

Grüße
Michael

RPP63 · 28. September 2015

Hi!
Mein obiger Code blendet leere Spalten und Zeilen INNERHALB des Tabellenbereichs aus (wenn Du einen komplett gefüllten Bereich hast, tut sich natürlich nichts).
Dass Du den äußeren Bereich weghaben wolltest, konnte ich nicht aus Deiner Threaderöffnung sehen.
Ist aber kein Problem:
Code:

Sub RestWeg()
Dim colFirst As Long, rowFirst As Long
With ActiveSheet
colFirst = .UsedRange.SpecialCells(xlCellTypeLastCell).Column + 1
rowFirst = .UsedRange.SpecialCells(xlCellTypeLastCell).Row + 1
.Rows(rowFirst & ":" & .Rows.Count).Hidden = True
.Range(.Cells(1, colFirst), .Cells(1, .Columns.Count)).EntireColumn.Hidden = True
End With
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

evtl. iVm obigem Code.

Gruß Ralf

Michael Schmohl · 28. September 2015

Hallo Ralf,

super. Danke
Genau so!

Grüße

Michael

P.S. Stelle gleich noch ein zweites Thema ein, vielleicht kannst Du mir ja auch dabei so schnell helfen.

Beverly · 28. September 2015

Hi Michael,

falls zwischendrin auch noch leere ausgeblendet werden sollen:

Code:

Sub Ausblenden()
Dim lngLetzte As LongPtr
Dim intLetzte As Integer
Dim lngZeile As Long
Dim intSpalte As Integer
Application.ScreenUpdating = False
With Sheets("Tabelle1")
lngLetzte = .UsedRange.SpecialCells(xlCellTypeLastCell).Row
intLetzte = .UsedRange.SpecialCells(xlCellTypeLastCell).Column
.Range(.Cells(1, intLetzte + 1), .Cells(1, .Columns.Count)).EntireColumn.Hidden = True
.Range(.Cells(lngLetzte + 1, 1), .Cells(.Rows.Count, 1)).EntireRow.Hidden = True
For intSpalte = 1 To intLetzte
If Application.CountA(.Columns(intSpalte)) = 0 Then .Columns(intSpalte).Hidden = True
Next intSpalte
For lngZeile = 1 To lngLetzte
If Application.CountA(.Rows(lngZeile)) = 0 Then .Rows(lngZeile).Hidden = True
Next lngZeile
End With
Application.ScreenUpdating = True
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Office: VBA für Excel 2013:Leere Zeilen und Spalten ausblenden

VBA für Excel 2013:Leere Zeilen und Spalten ausblenden

VBA für Excel 2013:Leere Zeilen und Spalten ausblenden

VBA für Excel 2013:Leere Zeilen und Spalten ausblenden

VBA für Excel 2013:Leere Zeilen und Spalten ausblenden - Similar Threads - VBA Excel 2013

Excel-Adressliste mit Bild

VBA Formel die automatisch die Zelle nach dem Namen zusammenrechnet

VBA Tabellenblatt kopieren und fortlaufend benennen

über Button speichern ohne weitere Abfrage

Hilfe excel vba

VBA geht nicht mehr nach Microsoft Dezember Update - Excel 2013

Wenn Zelle richtig dann aktiviere ander Zelle