Office: VBA Funktions Problem

Hallo ich habe folgendes Problem:

Funktion (Modul2):

Code:

Function KW(d As Date) As Integer
    t = DateSerial(Year(d + (8 - WeekDay(d)) Mod 7 - 3), 1, 1)
    KW = (d - t - 3 + (WeekDay(t) + 1) Mod 7) \ 7 + 1
End Function

Quelle:
http://www.schmittis-page.de/index.html?/excel/vba/t22.htm

Aufruf aus dem Hauptmakro (Modul1)

Code:

LUV.Sheets("Sheet1").Cells(3, 3) = KW(Paten.Worksheets("Lfde LUV-Aufträge").Range("CC" & I))

Es handelt sich hierbei um den Versuch, ein Datum der Zelle CC & I aus der einen Datei in die Datei aus der das Makro gestartet wird, via der Funktion in eine KW umzuwandeln, zu vergleichen um dann die richtige Spalte (KW) zu finden in welche die Daten gehören, wobei Cells(3,3) zunächst nur die Hilfsspalte ist, in welche erst einmal das Ergebnis der Funktion geliefert werden soll, um zu sehen was denn da kommt (die Funktion habe ich aus dem Inet) Leider bekomme ich hier immer e...ch falsch bzw. wie kann man das anders lösen?

 

Hi Andy,

ich kenne nicht deine Variablendefinitionen, aber bei mir funktionert der folgende Code problemlos:

Code:

Sub KWErmitteln()
    Dim LUV As Workbook
    Dim Paten As Workbook
    Dim i As Long
    Set LUV = ThisWorkbook
    Set Paten = Workbooks("Mappe1.xls")
    i = 1
    LUV.Sheets("Sheet1").Cells(3, 3) = KW(Paten.Worksheets("Lfde LUV-Aufträge").Range("CC" & i))
    Set LUV = Nothing
    Set Paten = Nothing
End Sub

Function KW(d As Date) As Integer
    Dim t As Date
    t = DateSerial(Year(d + (8 - Weekday(d)) Mod 7 - 3), 1, 1)
    KW = (d - t - 3 + (Weekday(t) + 1) Mod 7) \ 7 + 1
End Function

Bis später,
Karin

 

was solll der Teil Paten.

 

ok..., zunächst handelt es sich hierbei nicht um "Pattern" sondern um Paten als der Pate von etwas

Desweiteren habe ich das Problem gefunden in Form von nicht nichts sondern es wird versucht mehrere Leerzeichen als Datum zu verwenden was logischerweise nicht möglich ist.

Hierzu nun die erweiterte Frage, wie kann man solch einen "Dumpfsinn" ausschliessen indem ich sozusagen anders herum Frage... wenn es ein Datum ist dann wandle in KW....??

 

Hallo AndySmith,

ich habe nicht Deine Function auf rechnerische Richtigkeit überprüft, sondern nur die Syntax:
Dabei ist mir aufgefallen, dass Du die Variable "t" verwendest innerhalb der Function, ohne sie deklariert zu haben.
Falls Du im Modul2 auf Modulebene (also vor der 1. Function bzw. Sub) ebenfalls eine Variable "t" hast, die zB. as STRING deklariert ist, bedeutet das, dass genau diese dann auch innerhalb der Function KW(..) herangezogen wird, was dann angesichts der verwendeten Funktionen eine Typunverträglichkeit bewirkt.

Ganz und gar wichtig beim Programmierung mit VBA (und generell) ist:
1) Als 1. Anweisung in einem Modul stets "Option Explicit" eingeben
2) Jede Variable stets explizit zu deklarieren (an der Stelle, an die sie hingehört).

 

Vielen Dank!! das waren unabhängig des Leerzeichen Problems genau die richtigen Worte!!

 

Hi Andy,

wie du in meinem Beitrag erkennen konntest, ist die Variable t in der Funktion selbst als Date definiert.

Ich würde vorher eine Abfrage machen, ob der Zellinhalt ein Datum ist, so nach diesem Prinzip:

Code:

If IsDate(Paten.Worksheets("Lfde LUV-Aufträge").Range("CC" & i)) Then LUV.Sheets("Sheet1").Cells(3, 3) = ...

Bis später,
Karin

 

Hallo,

man kann die KW-Funktion geringfügig verkürzen bzw. übersichtlicher machen:

Code:

Function KW(d As Date) As Integer
    Dim t As Date 
    t = DateSerial(Year(d - Weekday(d, 2) + 4), 1, 4)
    KW = (d - t + Weekday(t, 2) - 1) \ 7 + 1
End Function

Dabei bedeutet t das fortlaufende Datum des 4.1. entweder des Vorjahres, des lfd. Jahres oder des Folgejahres.
Ferner gibt Weekday(d,2) folgende Werte zurück: 1=Montag, 2=Dienstag,..., 7=Sonntag

 

Vielen Dank an alle, Problem gelösst, das Thema hat sich mit den guten Antworten erledigt!!

THX