Office: (Office 2013) VBA Kopfzeile formatieren

Hallo

Ich möchte beim Ausdruck die Kopf und Fußzeile per VBA vorgeben.
Ich habe diesen Code für den Ausdruck:

Code:

Sub Drucken_Verzeichniss_dewei()
    
   
    Dim LoI As Long                                 ' Schleifenvariable
    Dim LoLetzte As Long                            ' Variable für letzte Zeile
    ' letzte Zeile für Spalte Y (25)
    LoLetzte = IIf(IsEmpty(Cells(Rows.Count, 25)), _
        Cells(Rows.Count, 25).End(xlUp).Row, Rows.Count)
    For LoI = LoLetzte To 1 Step -1
        ' Zeilen ausblenden
        If Cells(LoI, 25) = Empty Then Rows(LoI).EntireRow.Hidden = True
    Next LoI
    ActiveSheet.PrintOut Copies:=1, Collate:=True, IgnorePrintareas:=False, Preview:=True         ' Tabelle drucken
    Cells.EntireRow.Hidden = False                                                                ' alle Zeilen einblenden
End Sub

und möchte gerne das hier einfügen:

Code:

  'With sht.PageSetup
  '      .LeftHeader = "&Verzeichniss&B"
   '     .CenterHeader = ""
    '    .RightHeader = ""
     '   .LeftFooter = "Letzte Überarbeitung &D"
      '  .CenterFooter = ""
       ' .RightFooter = "&Z"
  '  End With

Egal wo ich das Einfüge zeigt er mir immer "Objekt erforderlich".
Kann mir das jemand erklären?


Vielen Dank.

Markus

 

Hi Markus,

an welcher Stelle ist denn die Variable sht deklariert und womit wird sie belegt? Nirgendwo - daher der Fehler, würde ich meinen.
M.E. müsste der Code so heißen:

Code:

Sub Drucken_Verzeichniss_dewei()
    Dim LoI As Long                                 ' Schleifenvariable
    Dim LoLetzte As Long                            ' Variable für letzte Zeile
    ' letzte Zeile für Spalte Y (25)
    With ActiveSheet
        LoLetzte = IIf(IsEmpty(.Cells(.Rows.Count, 25)), _
            .Cells(.Rows.Count, 25).End(xlUp).Row, .Rows.Count)
        For LoI = LoLetzte To 1 Step -1
            ' Zeilen ausblenden
            If .Cells(LoI, 25) = Empty Then .Rows(LoI).EntireRow.Hidden = True
        Next LoI
        With .PageSetup
            .LeftHeader = "&Verzeichniss&B"
            .CenterHeader = ""
            .RightHeader = ""
            .LeftFooter = "Letzte Überarbeitung &D"
            .CenterFooter = ""
            .RightFooter = "&Z"
        End With
        .PrintOut Copies:=1, Collate:=True, IgnorePrintareas:=False, Preview:=True    ' Tabelle drucken
        .Cells.EntireRow.Hidden = False                                               ' alle Zeilen einblenden
    End With
End Sub

Bis später,
Karin

 

Hallo Karin,

super das passt. Vielen Dank.

Jetzt habe ich nur noch eine Frage:

Wie füge ich zB.: bei .LeftHeader =
zwei Zeilen ein?


Gruß Markus

 

Hi Markus,

der Zeilenumbruch in VBA ist vbLf oder Chr(10)

Bis später,
Karin