Office: VBA / kopieren+inhalte einfügen--> Fehler 400

Hallo,

ich komme nicht wirklich weiter...
ich versuche einen copy-insertbefehl in ein existierendes makro zu intergrieren und es kommt immer ein Fehler 400

Von 1.xls soll ein bestimmter bereich nach D.xls rüberkopiert werden, aber da dieser Bereich aus vielen formeln besteht und ich die ganze Sache weiterverarbeiten muß soll es als copy-insert sein.

ich habe untenstehend mal meinen aktuellen versuch angegeben (der so wahrscheinlich falsch ist), habe es mit vielen möglichkeiten versucht, ihn stört irgendwie dieses selection.

Habs auch als extrabefehl am Ende schon mal versucht... will er auch nicht.

Danke für eure Hilfe

Dim b

Workbooks.Open "1.xls"

Workbooks(" 1.xls").Worksheets("T").Activate
Worksheets("T").Range("B9:Ac108").Copy Workbooks("D.xls").Worksheets("B1").Range("B9:AC108")
''Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
b = Worksheets("Teilnehmerliste").Range("W1")

Workbooks("D.xls").Worksheets("B1").Range("AD9:AD108") = b
Workbooks("1.xls").Save
Workbooks("1.xls").Close




End Sub

grüße

Boris

 

Hi Boris,

hast du es schon mal so versucht (ungetestet):

Code:

Worksheets("T").Range("B9:Ac108").Copy
Workbooks("D.xls").Worksheets("B1").Range("B9").PasteSpecial Paste:=xlPasteValues

Bis später,
Karin

 

;-)

Besten Dank..

nur warum funktioniert es so? Stört ihn dieser Selectbefehl?

dankeschöön
grüße

Boris

 

Hallo!

Welcher Select-Befehl?
"Selection" kann nur auf etwas zugreifen, was du vorher mit "Select" ausgewählt hast!
Du hast aber nix mit "Select" ausgewählt, und das ist auch gut so, denn "Select" ist in ca.99% aller Fälle überflüssig, wie du an Karin's Lösung sehen kannst.

 

Hi Boris,

Kopieren und Einfügen ist etwas anderes als Kopieren -> Bearbeiten -> Inhalte Einfügen, folglich unterscheiden sich auch die Befehle dafür.

Bis später,
Karin

 

Code:

Dim b

Wenn irgend möglich, vermeide den "Variant" Datentyp, indem Du explizit angibst, welchen Datentyp Du benutzen möchtest. Hier also z.B.

Code:

Dim b as String

Code:

Workbooks.Open "1.xls"
Workbooks(" 1.xls").Worksheets("T").Activate

Die zweite Zeile ist nicht zwingend notwendig, wenn Du nur aus irgendeinem Bereich aus irgendeinem Blatt der Mappe etwas herauskopieren möchtest. (Stört sich das Ding nicht an dem Leerzeichen vor der "1"?)

Code:

Worksheets("T").Range("B9:Ac108").Copy Workbooks("D.xls").Worksheets("B1").Range("B9:AC108")

Wenn Du mit mehreren parallel geöffneten Mappen (workbooks) arbeitest, ist es immer sinnvoll, explizit anzugeben, wo sich das Blatt (worksheets) befindet, das Du gerade ansprichst. Außerdem verwende ich gerne, in erster Linie für die Lesbarkeit, die Angabe des Parameters.

Code:

Workbooks("1.xls").Worksheets("T").Range("B9:Ac108").Copy destination:=Workbooks("D.xls").Worksheets("B1").Range("B9:AC108")

Code:

''Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False

Das Problem hier ist wohl: Du greifst auf eine "Selection" zu, also einen "augewählten Bereich". Du hast aber vorher gar keinen Bereich als "ausgewählt" deklariert:

Code:

Workbooks("D.xls").Worksheets("B1").Range("B9:AC108").Select

Aber: Ein .select ist eigentlich überhaupt nicht notwendig und macht die Abarbeitung eigentlich nur unnötig langsam.

Code:

Workbooks("D.xls").Worksheets("B1").Range("B9:AC108").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False

BTW: Wenn Du mit PasteSpecial nur die Werte einkopieren möchtest, brauchst Du den Kladderadatsch mit destination:=... nicht mehr hinter dem obigen Copy-Befehl. Sonst würdest Du den Kram ja 2x einkopieren:

Code:

Workbooks("1.xls").Worksheets("T").Range("B9:Ac108").Copy
  'destination:=Workbooks("D.xls").Worksheets("B1").Range("B9:AC108")
Workbooks("D.xls").Worksheets("B1").Range("B9:AC108").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False

Code:

b = Worksheets("Teilnehmerliste").Range("W1")

Hier zeigt sich ggf. eine Falle des vereinfachten DIM weiter oben und des Verlassens auf den Default-Wert einer Eigenschaft... Was steht nach dieser Zeile in "b"? In der von Dir verwendeten Version wohl ein Variant mit dem Untertyp z.B. String, in dem sich der Wert aus der Zelle W1 befindet. Aber... Was wäre, wenn in der nächsten Version nicht ".Value" die Standard-Eigenschaft von ".Range()" ist? Es könnte ja auch ein "Range"-Object zurückgegeben werden. Deine DIM-Deklaration würde das grundsätzlich ja auch für "b" zulassen. Dann würd's aber eine Fehlermeldung in der Zeile geben, weil die dann

Code:

Set b = Worksheets("Teilnehmerliste").Range("W1")

heißen _müßte_ (und jetzt auch schon könnte. Von daher empfehle ich, auch wieder für die Lesbarkeit:

Code:

b = Worksheets("Teilnehmerliste").Range("W1").Value

Code:

Workbooks("D.xls").Worksheets("B1").Range("AD9:AD108") = b

Hier dann auch wieder ähnlich:

Code:

Workbooks("D.xls").Worksheets("B1").Range("AD9:AD108").Value = b

Gruß, Michael