Office: VBA Lösung gesucht

Guten Tag zusammen.

Ich bin neu hier und auch sehr neu was VBA angeht und bin dabei zu lernen.

Ich benötige für ein Projekt auf der Arbeit nun folgende Lösung.

Ich möchte gerne Per Inputbox nach einem Begriff in einer 2ten Tabelle suchen und diese dann aktiviert haben sodas man sie gleich sieht, wenn der Begriff nicht gefunden wurde soll der Eingegebene Begriff in einer 3ten Tabelle rein kopiert werden. Dieses am besten so das alle gescheiterten Suchen untereinander Aufgelistet werden.

Ich hoffe das war verständlich und mir kann hier geholfen werden. Wäre euch sehr Dankbar dafür.

 

Hallo Sergio,

bitte etwas genauere Angaben, am besten eine Beispieldatei, damit Lösungsvorschläge nicht am Ziel vorbei gehen.

 

Tabelle 1 ist meine Startseite diese hat aktuell 1 Button Dieser öffnet die Inputbox mit der Such anfrage.
Gesucht wird in "tabelle 2" Spalte A
Wenn Der Suchbegriff gefunden wird, soll dieser Aktiviert sein in Tabelle 2 (sprich die suche wird angezeigt)
Wenn kein wert gefunden wird soll dieser in "Tabelle 3", "Spalte a" eingefügt werden.
Werden weitere Suchanfragen nicht in tabelle 2 gefunden sollen diese ebenfalls in "Tabelle 3" "Spalte A" untereinander eingefügt werden.

Hier mein Bisheriger versuch, zumindestens die Suche in gang zu bekommen:

Code:

Private Sub CommandButton2_Click()
Dim zelle As Range
Dim Name As String
Name = InputBox("Bitte Fehlercode eingeben!")
Worksheets("Tabelle 2").Activate
ActiveSheet.Range("A1:A65536").Select
For Each zelle In Selection
If zelle = Name Then
zelle.Select
Exit Sub
End If
Next zelle
MsgBox "Fehlercode nicht vorhanden!"

End Sub

 

Hi Sergio,

Code:

Sub Suche()
    Dim varSuche As Variant
    Dim rngSuche As Range
    Dim lngLetzte As Long
    varSuche = Application.InputBox("Suchbegriff:", "Suche")
    If varSuche <> 0 Then
        Set rngSuche = Worksheets("Tabelle2").Columns(1).Find(varSuche, lookat:=xlWhole, LookIn:=xlValues)
        If Not rngSuche Is Nothing Then
            Application.Goto reference:=rngSuche, scroll:=True
        Else
            With Worksheets("Tabelle3")
                lngLetzte = .Cells(Rows.Count, 1).End(xlUp).Row
                .Cells(lngLetzte + 1, 1) = varSuche
                MsgBox "Begriff nicht gefunden"
            End With
        End If
    End If
End Sub

Gesucht wird im Blatt "Tabelle2", Spalte A. Wenn nicht gefunden, dann wird der Suchbegriff im Blatt "Tabelle3" fortlaufend in Spalte A eingetragen.

---

 

Perfekt,

funktioniert wie es soll.

Vielen Dank dafür.

Klasse Gruppe hier.