Office: VBA: Mit MsgBox bestimmte Inhalte von Zeile leeren

Helfe beim Thema VBA: Mit MsgBox bestimmte Inhalte von Zeile leeren in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo Excel Freunde, ich habe in der Tabelle, Spalte A fortlaufende ID Nummern hinterlegt (1-200). Jetzt möchte den Inhalt (Zeile) z.B ID 180 leeren.... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Aksa, 29. Januar 2023.

  1. Aksa User

    VBA: Mit MsgBox bestimmte Inhalte von Zeile leeren


    Hallo Excel Freunde,

    ich habe in der Tabelle, Spalte A fortlaufende ID Nummern hinterlegt (1-200).
    Jetzt möchte den Inhalt (Zeile) z.B ID 180 leeren. Dabei soll nicht die ganze Zeile geleert werden, sondern nur die Zellen A bis O. Das ganze soll am besten mit eine MsgBox erfolgen, wo abgefragt wird , welche ID geleert werden soll und ob wirklich geleert werden soll. Ich habe folgende Code gefunden die aber ganze Zeile leert und auch nur die aktiv ausgewählte Zeile. Leider reicht mein Wissen nicht aus um den Code anzupassen und brauche euer mithilfe.

    Code:
    Sub AuswahlLeeren()
    
    'Abfrage, ob wirklich geleert werden soll
    
    Dim Antwort
    
    Antwort = MsgBox("Soll wirklich Zellinhalte geleert werden?", vbYesNo + vbQuestion, "Auswahl Zellinhalte leeren:")
    
    If Antwort = vbYes Then ActiveCell.EntireRow.ClearContents
    
    End Sub
    Danke
     
    Zuletzt bearbeitet: 29. Januar 2023
  2. Hajo_Zi
    Hajo_Zi Erfahrener User
    Code:
    Option Explicit
    
    Sub AuswahlLeeren()
        Dim Antwort
        Dim LoZeile As Long
        Antwort = MsgBox("Soll wirklich Zellinhalte geleert werden?", vbYesNo + vbQuestion, "Auswahl Zellinhalte leeren:")
        If Antwort = vbYes Then
            LoZeile = ActiveCell.Row
            Range("A" & LoZeile & ":O" & LoZeile).ClearContents
        End If
    End Sub
    
    Select, Activate usw. ist in VBA zu 99,8% nicht notwendig.
    Der Cursor ist kein Hund der überall rumgeführt werden muss.
    Select - Hajo's Excelseiten
    Online - Excel Programmierung VBA Makro: Performance (2) - Select Activate Bremsen und ein Beispiel
    Online - Excel Programmierung VBA Makro: Achtung Makrorekorder oder Wer selektiert denn da?.

    VBA: Mit MsgBox bestimmte Inhalte von Zeile leeren GrußformelVBA: Mit MsgBox bestimmte Inhalte von Zeile leeren Homepage
     
    Hajo_Zi, 29. Januar 2023
    #2
    1 Person gefällt das.
  3. Exl121150 Erfahrener User
    Hallo,

    Code:
    Option Explicit
    
    Sub AuswahlLeeren()
      
      Dim Ws As Worksheet, SuchZelle As Range
      Dim Antwort As VbMsgBoxResult
      Dim strID As String, SuchBereich As Range
     
      Set Ws = ActiveSheet:  Set SuchBereich = Ws.Range("A:A")
     
      strID = InputBox(Prompt:="Welche ID soll gelöscht werden?", Title:="ID-Abfrage", Default:="100")
      If Len(strID) Then
         Antwort = MsgBox(Prompt:="Sollen wirklich die Zellinhalte der Zeile mit ID=" & strID & " geleert werden?", _
                          Buttons:=vbYesNo + vbQuestion, _
                          Title:="Auswahl Zellinhalte leeren")
         If Antwort = vbYes Then
            Set SuchZelle = SuchBereich.Find(What:=strID, LookIn:=xlValues, LookAt:=xlWhole)
            If SuchZelle Is Nothing Then
               'strID wurde in Spalte A nicht gefunden
               MsgBox Prompt:="Die Nummer " & strID & " wurde im Bereich " & SuchBereich.Address & " nicht gefunden." & vbNewLine & "-> Abbruch"
            Else
               'strID wurde in Spalte A gefunden:
               'Die Inhalte der Zellen der Spalten A-O leeren
               SuchZelle.Resize(1, 15).ClearContents
            End If
         End If
      End If
    End Sub
    
     
    Exl121150, 29. Januar 2023
    #3
    1 Person gefällt das.
  4. Aksa User

    VBA: Mit MsgBox bestimmte Inhalte von Zeile leeren

    @Exl121150: Vielen Dank, funktioniert bestens nur hab ich ein fehler gemacht.
    Beim testen habe ich festgestellt,Zelle A (ID) darf ich nicht gelöscht werden sondern nur B - O.
    Dachte ich kann das selbst noch anpassen aber komme auf keine Lösung.
    Könntest du das bitte noch anpassen ?

    Danke
     
  5. Exl121150 Erfahrener User
    Hallo,

    Code:
    Option Explicit
    
    Sub AuswahlLeeren()
      
      Dim Ws As Worksheet, SuchZelle As Range
      Dim Antwort As VbMsgBoxResult
      Dim strID As String, SuchBereich As Range
     
      Set Ws = ActiveSheet:  Set SuchBereich = Ws.Range("A:A")
     
      strID = InputBox(Prompt:="Welche ID soll gelöscht werden?", Title:="ID-Abfrage", Default:="100")
      If Len(strID) Then
         Antwort = MsgBox(Prompt:="Sollen wirklich die Zellinhalte der Zeile mit ID=" & strID & " geleert werden?", _
                          Buttons:=vbYesNo + vbQuestion, _
                          Title:="Auswahl Zellinhalte leeren")
         If Antwort = vbYes Then
            Set SuchZelle = SuchBereich.Find(What:=strID, LookIn:=xlValues, LookAt:=xlWhole)
            If SuchZelle Is Nothing Then
               'strID wurde in Spalte A nicht gefunden
               MsgBox Prompt:="Die Nummer " & strID & " wurde im Bereich " & SuchBereich.Address & " nicht gefunden." & vbNewLine & "-> Abbruch"
            Else
               'strID wurde in Spalte A gefunden:
               'Die Inhalte der Zellen der Spalten B-O leeren
               SuchZelle.Offset(0, 1).Resize(1, 14).ClearContents
            End If
         End If
      End If
    End Sub
    
     
    Exl121150, 29. Januar 2023
    #5
    1 Person gefällt das.
Thema:

VBA: Mit MsgBox bestimmte Inhalte von Zeile leeren

Die Seite wird geladen...
  1. VBA: Mit MsgBox bestimmte Inhalte von Zeile leeren - Similar Threads - VBA MsgBox bestimmte

  2. VBA: Spalten auf anderen Worksheeds in der Mappe ausblenden.

    in Microsoft Excel Hilfe
    VBA: Spalten auf anderen Worksheeds in der Mappe ausblenden.: Hallo zusammen, Eine Tabelle mit 9 Worksheets, Datenblatt, Studien, Studie_1 ...Studie_7. Auf dem Deckblatt werden in Zelle B4-B10 die Namen der Studien eingetragen. Davon abhängig ob ein Name...
  3. VBA-Code Arbeitsblatt wechseln

    in Microsoft Excel Hilfe
    VBA-Code Arbeitsblatt wechseln: Hallo zusammen, ich habe mal wieder eine Frage. Aktuell beschäftige ich mich mit VBA-Codes. Beim öffnen meiner Arbeitsmappe erscheint folgender Hinweis: Private Sub Workbook_Open() 'Titel Hinweis...
  4. MsgBox in Excel anzeigen lassen per Word VBA

    in Microsoft Word Hilfe
    MsgBox in Excel anzeigen lassen per Word VBA: Hallo zusammen, ich bin neu hier und versuche aktuell aus Word heraus eine Exceldatei zu öffnen. Das klappt auch alles schon wunderbar. Jetzt möchte ich gerne, wenn die Excel Datei geöffnet ist,...
  5. VBA Neuling- Suchfunktion

    in Microsoft Excel Hilfe
    VBA Neuling- Suchfunktion: Einen wunderschönen guten Morgen. Im Zuge eines Praktikums in meinen Physikstudium soll ich unter Anwendung der VBA Umgebung eine Suchfunktion schreiben. Sie macht eigentlich alles was sie soll....
  6. VBA Zellenwert in MsgBox zurückgeben

    in Microsoft Excel Hilfe
    VBA Zellenwert in MsgBox zurückgeben: Hallo zusammen, habe dazu merkwürdigerweise nichts in der Suche gefunden. Wahrscheinlich hat so eine simple Frage noch niemand gestellt ;-) Meine Frage: Ich möchte über eine MsgBox einen...
  7. VBA: MsgBox beim Öffnen einer Datei

    in Microsoft Excel Hilfe
    VBA: MsgBox beim Öffnen einer Datei: Hallo, da ich im VBA nicht so der Held bin: Ich möchte beim Öffnen einer Datei ein Popup mit einer Textmeldung erhalten. Kann einer kurz mit dem Coding aushelfen? Danke. Anfaenger
  8. MsgBox-ähnliches Gebilde mit Fortschrittsbalken per VBA

    in Microsoft Excel Hilfe
    MsgBox-ähnliches Gebilde mit Fortschrittsbalken per VBA: Hallo, allerseits! Falls diese Frage in einen anderen Bereich gehört, bitte Bescheid sagen, aber direkt zu VBA habe ich nichts gefunden und ich brauch's in der Tat für Excel... ;-) Ich...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden