Office: (Office 2013) VBA Neuling- Suchfunktion

Einen wunderschönen guten Morgen.
Im Zuge eines Praktikums in meinen Physikstudium soll ich unter Anwendung der VBA Umgebung eine Suchfunktion schreiben. Sie macht eigentlich alles was sie soll. Beim klicken auf die Makro öffnet sich ein schönes Fenster man kann Suchbegriffe einfügen und sie gibt auch alles Suchbegriffe im Dokument wieder (hört nicht auf wenn eins gefunden ist), nur zwei Feature will ich noch hinzufügen, die ich nicht hinkriege (wie erwähnt kleiner Physikstudent mit keinen Händchen zur Informatik). Ich wollte einmal, dass ich durch klicken auf das X der Messagebox den Suchvorgang abbrechen kann und dass die Suchfunktion nur spaltenspezifisch sucht (also beispielsweise nur in Spalte C).

"Meinen Code" (in Grundform gefunden auf irgendeiner Seite die offiziell ausschaut) hab ich einmal hier gepostet.
Vielleicht kann mir ja jemand helfen. Ich bedanke mich schon mal im Voraus :)

Sub Auswahl()
Dim rng As Range
Dim sBegriff, sAddress

sBegriff = InputBox( _
prompt:="Bitte Suchbegriff eingeben:", _
Default:="Suchbegriff")

If sBegriff = "" Then Exit Sub
Set rng = Cells.Find( _
what:=sBegriff, _
lookat:=xlPart, _
LookIn:=xlValues, _
MatchCase:=False, _
after:=ActiveCell)

If rng Is Nothing Then
Beep
MsgBox "Suchbegriff nicht gefunden!", , _
Application.UserName

End If
sAddress = rng.Address
rng.Select
MsgBox rng.Address(False, False)
rng.Offset(1).Select
Do
Cells.FindNext(after:=ActiveCell).Activate
If ActiveCell.Address = sAddress Then Exit Sub
MsgBox ActiveCell.Address(False, False)

Loop

End Sub

 

Moin!
Warum das Rad neu erfinden?
Langeweile im Praktikum? ;)
Spalte markieren
Kann man natürlich auch programmatisch steuern.
Direktfenster:

Code:

?Application.InputBox("Bereich markieren", Type:=8).Address
$E:$E

und dann:

Code:

Application.Dialogs(xlDialogFormulaFind).Show

Wenn Du unbedingt eine Messagebox mit der Adresse der Fundstelle haben willst, kannst Du dies mittels Worksheet_SeletionChange() regeln.

Gruß Ralf

 

Hallo

meinst du so?

Code:

Sub test()
    Dim c As Range
    Dim strBegriff As String
    Dim strFirst As String
    strBegriff = InputBox(prompt:="Bitte Suchbegriff eingeben:", Default:="Suchbegriff")
    If strBegriff = "" Then Exit Sub
    Set c = Columns(3).Find(strBegriff, LookIn:=xlValues, lookat:=xlPart)
    If Not c Is Nothing Then
        strFirst = c.Address
        Do
            c.Activate
            If MsgBox(c.Address, vbOKCancel) = vbCancel Then
                Exit Do
            Else
                Set c = Columns(3).FindNext(c)
            End If
        Loop While Not c Is Nothing And c.Address <> strFirst
    Else
        Beep
        MsgBox "Suchbegriff nicht gefunden!", , _
        Application.UserName
    End If
End Sub

MfG Tom