Office: VBA: Nur EINMAL +1 Addieren?

Bin ein absoluter VBA Excel-Neuling und komm daher schon bei einer einfachen Sache nicht weiter:
Ich soll in Excel so eine Art "Frage-Antwort-Spiel" erstellen und habe in einer Tabelle insgesamt die 7 Spalten A-G:

A: gibt eine Kategorie an (lz.B. leichte/mittlere/schwere Frage)
B: enthält Fragen
C: Diese Spalte ist versteckt und enthält die zu B zugehörigen Lösungen
D: dort müssen Antworten auf B eingetragen werden
E: soll automatisch anzeigen, ob die Antwort in D der Lösung aus C entspricht ("Richtig") oder falsch ist ("Falsch")
F: zeigt an, wie häufig die jeweilige Frage aus B bereits FALSCH beantwortet wurde
G: zeigt an, wie häufig die jeweilige Frage aus B bereits RICHTIG beantwortet wurde

Nun möchte ich mit Hilfe von VBA erreichen, dass automatisch in der jeweiligen Zeile in F bzw. G zum momentanen Wert +1 dazuaddiert wird, wenn die Antwort "falsch" bzw. "richtig" ist. Bisher sieht mein Code folgendermaßen aus:

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim Antwort As Range
Dim Lösung As Range
Dim wof As Range
Dim Logikwert As Boolean
Set Antwort = ActiveWorkbook.ActiveSheet.Cells(ActiveCell.Row - 1, 4)
Set Lösung = ActiveWorkbook.ActiveSheet.Cells(ActiveCell.Row - 1, 3)
Set wof = ActiveWorkbook.ActiveSheet.Cells(ActiveCell.Row - 1, 5)
Select Case Antwort
Case Is = Lösung
Logikwert = True
wof = "Richtig"
Cells(Target.Row, 7) = Cells(Target.Row, 7) + 1
Case Else
Logikwert = False
wof = "Falsch"
Cells(Target.Row, 6) = Cells(Target.Row, 6) + 1
End Select
End Sub

Hier habe ich das Problem, dass in Zelle G bzw. F nicht nur einmal +1 dazuaddiert wird, sondern unendlich oft, und ich die Prozedur mit ESC schließlich abbrechen muss. Wie kann ich es schaffen, dass nach der einmaligen Addition die Prozedur bereits von selber abgebrochen wird und die nächste Frage beantwortet werden kann?
Soweit ich bisher erfahren habe, hat es irgendetwas mit dem Befehl "If Not Intersect(Target, Range("x:y")) Is Nothing" zu tun, weiß allerdings nicht genau, was der Befehl eigentlich macht und wie ich ihn richtig einbaue, damit er auch funktioniert.
Bin dankbar für jede Hilfe!

Birka

 

Hallo!

Teste mal dies:

Code:

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim Antwort As String
Dim Lösung As String
Dim wof As Range
Dim Logikwert As Boolean    'Brauchst du den noch anderswo? Sonst mach ihn weg.
  If Target.Column = 4 Then 'war die Änderung in Spalte D?
  'Alternativ:
  'If Not Intersect(Target, Column(4)) Is Nothing Then
  'heißt: Wenn die Schnittmenge von Target und Spalte D nicht Nichts ist, dann...
    Antwort = Target.Value
    Lösung = Target.Offset(0, -1).Value
    Set wof = Target.Offset(0, 1)
      If Antwort = Lösung Then
        Logikwert = True    'siehe oben
        wof = "Richtig"
        Target.Offset(0, 2) = Target.Offset(0, 2) + 1
      Else
        Logikwert = False   'siehe oben
        wof = "Falsch"
        Target.Offset(0, 3) = Target.Offset(0, 3) + 1
      End If
  End If
End Sub

 

Vielen Dank! Funktioniert wunderbar jetzt :-D