Office: VBA Programm zur Datenauswertung

Hi!

Bin gerade dabei eine Excel Datei zu automatisieren. Das Einlesen der Daten klappt ohne Probleme. Anschließend habe ich eine Tabelle der Form:

A B
1 0
1 0
2 0
3 0
1 1
7 1
1 1
...
3 0,1
4 0,1
...

Ich möchte dies nun dahingehend Auswerten, dass ich alle Werte in A für die B eine gleichen Wert hat (im Beispiel 0 / 1 / 0,1) mittele und deren Standartabweichung bilde. Gleiche Werte in B liegen immer untereinander, haben allerdings abweichende Anzahlen.

Wäre super wenn jmd eine fixe Lösung parat hat

Vielen Dank!

mfg
hegheg

 

Hallo!

Folgende VBA-Makro ist in einem allgem. Codemodul zu speichern und mit der Tastenkombination Alt+F8 aufzurufen:

Code:

Public Sub Mittelw_Stdabw()
  Dim rgDaten As Range
  Dim rgZelle As Range
  Dim lztWertB#, lztZeile&
  Dim nxtWertB#, ZeilDiff&
  
  'Linke obere Ecke der Daten befindet sich in Zelle A1
  Set rgDaten = Range("A1").CurrentRegion
  Set rgDaten = rgDaten.Offset(1, 0).Resize(rgDaten.Rows.Count - 1)
  
  lztZeile& = rgDaten.Row
  lztWertB# = rgDaten(1, 2).Value
  For Each rgZelle In rgDaten.Columns(2).Cells
    With rgZelle
      nxtWertB# = .Offset(1).Value
      If nxtWertB# <> lztWertB# Then
        ZeilDiff& = lztZeile& - .Row
        .Offset(0, 1).FormulaR1C1 = "=AVERAGE(R[" & ZeilDiff & "]C[-2]:RC[-2])"
        .Offset(0, 2).FormulaR1C1 = "=STDEVP(R[" & ZeilDiff & "]C[-3]:RC[-3])"
        lztZeile = .Row + 1
        lztWertB# = nxtWertB#
      End If
    End With
  Next rgZelle
  
End Sub

Es erzeugt die Mittelwert/Standardabw.-Funktionen in den Spalten C und D, wie im folgenden Beispiel dargestellt.
Betreffs verwendeter STABWN-Funktion: diese ermittelt die Standardabweichung von Grundgesamtheiten (und nicht von Stichproben). Da Du keine Angaben diesbezüglich gemacht hast, habe ich diese genommen (und nicht die STABW-Funktion).

	A	B	C	D
1	A	B
2	1	0
3	1	0
4	2	0
5	3	0	1,75	0,8291562
6	1	1
7	7	1
8	1	1	3	2,82842712
9	3	0,1
10	4	0,1	3,5	0,5
11

Zelle	Formel
C5	=MITTELWERT(A2:A5)
D5	=STABWN(A2:A5)
C8	=MITTELWERT(A6:A8)
D8	=STABWN(A6:A8)
C10	=MITTELWERT(A9:A10)
D10	=STABWN(A9:A10)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg