Office: (Office 2010) VBA Suchfeld (gehe zu)

Hallo zusammen,

ich habe eine ziemlich große Excelliste mit Artikelnummern, Namen, Preisen, ...

Nun wollte ich für die vereinfachte Suche über die Liste ein Suchfeld setzen. Ähnlich der Funktion Strg + F ...

In A1 soll eine Artikelnummer eingegeben werden und daneben eine Artikel Suchbutton. Wenn ich nun auf den Suchbutton klicke soll der in die Zeile springen, die die Artikelnummer aus Zelle A1 enthält.

Irgendwie stelle ich mich aber etwas blöd an. Habe es mit

Application.Goto Reference:=Range("A1")

versucht. Aber irgendwie klappt das nicht. Muss ich da vielleicht noch irgendwo angegeben, wo der suchen soll? Am ende funktioniert das ganze und der springt immer in A1 weil das die erste Übereinstimmung ist, die er findet? Wenn das so ist, soll er natürlich A1 bei der Suche ausschließen.

Achso, falls das eine Rolle spielen sollte, jede Artikelnummer ist in der Liste nur einmal vorhanden.

Ich hoffe, Ihr könnt mir helfen.

Gruß
Michael

 

Hi Michael,

mit deinem Befehl weist du Excel an, nach Zelle A1 zu springen - du musst aber zuerst die Zelle suchen, in der dein Suchbegriff steht. Dazu verwendet man z.B. die Find-Methode:

Code:

Sub Suchen()
    Dim rngZelle As Range
    Set rngZelle = Columns("B").Find(Range("A1"), lookat:=xlWhole)
    If Not rngZelle Is Nothing Then
        Application.Goto reference:=rngZelle
    Else
        MsgBox "Nicht gefunden"
    End If
    Set rngZelle = Nothing
End Sub

Mit dem Code wird in Spalte B gesucht - das musst du an deine Bedingungen anpassen.

Bis später,
Karin

 

Hallo Karin,

ich habe das gerade mal probiert. Es funktioniert einwandfrei. Vielen Dank dafür. Vielleicht kannst Du mir auch noch ein Stück weiter helfen. Meine VBA-Kenntnisse sind leider recht bescheiden. Ich google mir das meiste zusammen :-(

Momentan kommt ja, danke Deiner Hilfe, eine Msgbox, wenn er die Artikelnummer nicht gefunden hat. Wäre es möglich an dieser Stelle eine Msgbox mit Ja und Nein zu hinterlegen? Wenn ja, soll er ans Ende der Tabelle springen (um einen neuen Artikel einzugeben) und wenn nein, soll er die Msgbox schließen.

Viele Grüße
Michael

 

Hi Michael,

Code:

Sub Suchen()
    Dim rngZelle As Range
    Dim lngLetzte As Long
    Dim varFrage As Variant
    lngLetzte = IIf(IsEmpty(Cells(Rows.Count, 2)), Cells(Rows.Count, 2).End(xlUp).Row, Rows.Count)
    Set rngZelle = Columns("B").Find(Range("A1"), lookat:=xlWhole)
    If Not rngZelle Is Nothing Then
        Application.Goto reference:=rngZelle
    Else
        varFrage = MsgBox("Neuen Eintrag?", vbOKCancel, "Nicht gefunden")
        If varFrage = 1 Then Application.Goto reference:=Cells(lngLetzte + 1, 2)
    End If
    Set rngZelle = Nothing
End Sub

Bis später,
Karin

 

Hi Karin,

jetzt ist es perfekt. Ich danke Dir.

Gruß Michael