Office: (Office 2011 Mac) VBA: Überprüfung, ob Datei existiert und Abfrage vor dem Überschreiben

Liebe Excel/VBA-Community,

ich versuche mit wachsender Verzweiflung ein Makro zu erstellen, das folgende Funktionen erfüllt:

1. Beim Abspielen des Makros wird eine PDF erzeugt (funktioniert)
2. Der Dateiname der PDF wird den Zellen C1-3 entnommen (funktioniert)
3. Dabei Prüfung, ob C1-3 ausgefüllt wurden: Wenn nicht, Fehlermeldung (funktioniert)
4. Die PDF wird an den Ort der Ausgangs-XLSM gespeichert (funktioniert)
5. Prüfung, ob eine Datei mit diesem Dateinamen bereits existiert. Wenn ja, MsgBox (funktioniert nicht). Herausforderung: Die XLSM liegt auf einem Serverpfad, die Vergabe des Dateinamens ist dynamisch (s.o.), es kann also kein lokaler, fixierter Dateiname angegeben werden.
6. Abfrage, ob Datei überschrieben werden soll oder nicht (noch nicht eingebaut, da 5 nicht funktioniert)

Meine aktuellen Versuche sehen wie folgt aus und produzieren beim aktuellen Stand die Fehlermeldung 'Laufzeitfehler "68": Das Gerät ist nicht verfügbar':

****
Sub PDF_Speichern()

Dim name As String
Dim Matrikel As String
Dim Aufgabe As String
Dim Dateiname As String
Dim Pfad As String
Dim Korrektor As String

ChDir ThisWorkbook.Path

name = Range("C1")
Matrikel = Range("C2")
Aufgabe = Range("C3")
Korrektor = Range("B12")
Dateiname = name & "_" & Matrikel & "_" & Aufgabe & "_" & "Bewertung" & ".pdf"

If Len(name) = 0 Then
MsgBox ("Bitte Namen angeben")
Exit Sub
End If
If Len(Matrikel) = 0 Then
MsgBox ("Bitte Matrikelnummer angeben")
Exit Sub
End If
If Len(Aufgabe) = 0 Then
MsgBox ("Bitte Aufgaben-Namen angeben")
Exit Sub
End If
If Len(Korrektor) = 0 Then
MsgBox ("Enter your ID")
Exit Sub
End If

'Ab hier hakt es. Ich habe es schon ohne Anführungsstriche versucht, mit verschiedenen Klammern und mit '= Dateiname Then', leider erfolglos

If Dir("ThisWorkbook.Path & Dateiname") = "" Then
MsgBox ("Achtung! Datei existiert bereits. Überschreiben?")
Else

ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
Dateiname, Quality:=xlQualityStandard, _
IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True
End If
End Sub
****

Meinen bisherigen Recherchen zufolge kann das Problem nicht über ein Object gelöst werden, weil das für Excel für Mac nicht verfügbar ist. Auch bei Ron de Bruin habe ich mich schon umgeschaut und bin zu keiner Lösung gekommen.

Hat jemand einen Lösungsvorschlag?

Vorab schon mal vielen Dank und Grüße
MikroMeso
_____
Excel 2011 für Mac (14.6.3) auf Mac OS X (10.9.5)

 

Hi,

ich würde es so versuchen:

Code:

If Dir(ThisWorkbook.Path & "\" & Dateiname) <> "" Then

Bis später,
Karin

 

Hallo Karin,

vielen Dank für deinen Vorschlag. Leider führt diese Zeile zu 'Laufzeitfehler "13": Typenkonflikt'

Wie gesagt arbeite ich auf Word für Mac und das scheint insbesondere bei der Pfadbezeichnung Eigenheiten zu haben. Ich habe auch schon / und : ausprobiert, mit und ohne Anführungszeichen, jedoch ohne Erfolg. Hast du noch eine alternative Idee?

Danke und Grüßle
MikroMeso

 

Hi,

schau dich mal hier um http://www.herber.de/forum/archiv/1...mloesung_gesucht_fuer_VBA_Code_unter_MAC.html vielleicht hilft das weiter.

Bis später,
Karin

 

Lösung. Danke

Hallo,

nach langem Wühlen und Probieren bin ich nun zu folgendem (vll. nicht eleganten oder einfachen aber funktionierenden) Lösungsweg gekommen:

Code:

If FileOrFolderExistsOnMac(1, ThisWorkbook.Path & Application.PathSeparator & Dateiname) Then
    If MsgBox("Datei existiert bereits. Überschreiben?", vbYesNo + vbQuestion, "ACHTUNG!") = vbYes Then
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
        Dateiname, Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
        Else
        Exit Sub
    End If
Else
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
        Dateiname, Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
End If

Es geht also nicht ohne Ron De Bruines Funktion: https://msdn.microsoft.com/de-de/library/office/jj614412(v=office.14).aspx

Code:

Function FileOrFolderExistsOnMac(FileOrFolder As Long, FileOrFolderstr As String) As Boolean
'By Ron de Bruin
'30-July-2012
'Function to test whether a file or folder exist on a Mac.
'Uses AppleScript to avoid the problem with long file names.
    Dim ScriptToCheckFileFolder As String
    ScriptToCheckFileFolder = "tell application " & Chr(34) & "Finder" & Chr(34) & Chr(13)
    If FileOrFolder = 1 Then
        ScriptToCheckFileFolder = ScriptToCheckFileFolder & "exists file " & _
        Chr(34) & FileOrFolderstr & Chr(34) & Chr(13)
    Else
        ScriptToCheckFileFolder = ScriptToCheckFileFolder & "exists folder " & _
        Chr(34) & FileOrFolderstr & Chr(34) & Chr(13)
    End If
    ScriptToCheckFileFolder = ScriptToCheckFileFolder & "end tell" & Chr(13)
    FileOrFolderExistsOnMac = MacScript(ScriptToCheckFileFolder)
End Function

Danke für die Hinweise

Viele Grüße
MikroMeso