Office: VBA- Verbesserung bei Dateiwechsel

Hallo,

ich habe einen VBA Code, in dem ich immer zwischen Zwei Dateien wechseln muss. Meine Frage: Kann ich es umgehen immer "Thisworkbook.activate" bzw das andere Workbook zu aktivieren?
In meinem Code wechseln die beiden Dateien sich immer ab- ich denke mal das ist nicht gerade sinnvoll. Hat jemand einen Verbesserungsvorschlag?
Irgendwie mit "SET=" Workbook festlegen oder so?

Code:

Sub Formatx(strDatei As String)
  
  Dim lngLastRow As Long, lngZeile As Long, strSuch As String, rngSuche As Range
    Workbooks.OpenText Filename:=OeffnenPfadK119 & strDatei & ".csv", Local:=True, DataType:=xlDelimited, Semicolon:=True
            
    With Worksheets(strDatei)
        lngLastRow = .Cells(1048576, 1).End(xlUp).Row
        For lngZeile = lngLastRow To 4 Step -1
            strSuch = .Cells(lngZeile, 3)
            If strSuch <> "" Then
                ThisWorkbook.Activate
                With Worksheets("Ausnahme")
                    Set rngSuche = .Columns(1).Find(strSuch, lookat:=xlWhole)
                    If Not rngSuche Is Nothing Then
                        Windows(strDatei & ".csv").Activate
                        Rows(lngZeile).EntireRow.Delete
                    End If
                End With
            End If
        Next lngZeile
    End With
End Sub

Ich benutze Excel 2012

Danke

 

Hi Marius,

versuche es mal nach diesem Prinzip:

Code:

Sub Formatx(strDatei As String)
    Dim lngLastRow As Long, lngZeile As Long, strSuch As String, rngSuche As Range
    Workbooks.OpenText Filename:=OeffnenPfadK119 & strDatei & ".csv", Local:=True, DataType:=xlDelimited, Semicolon:=True
'    With Worksheets(strDatei)    '<== ????
    With Workbooks(strDatei & ".csv").Worksheets("TabName")  '<== Tabellenname anpassen
        lngLastRow = IIf(IsEmpty(.Cells(.Rows.Count, 1)), .Cells(.Rows.Count, 1).End(xlUp).Row, .Rows.Count)
        For lngZeile = lngLastRow To 4 Step -1
            strSuch = .Cells(lngZeile, 3)
            If strSuch <> "" Then
                With ThisWorkbook.Worksheets("Ausnahme")
                    Set rngSuche = .Columns(1).Find(strSuch, lookat:=xlWhole)
                    If Not rngSuche Is Nothing Then
                        Workbooks(strDatei & ".csv").Worksheets("TabName").Rows(lngZeile).EntireRow.Delete '<== Tabellenname anpassen
                    End If
                End With
            End If
        Next lngZeile
    End With
End Sub

Leider weiß ich nicht, was auf deiner Variablen strDatei steht und wie der Name des Tabellenblattes in der csv-Datei ist, sodass ich den Code nur prinzipiell angeben konnte. auf jeden Fall musst du diech auf das Wokbook und das Tabellenblatt beziehen.

Bis später,
Karin

 

Danke, das kklappt schon mal sehr gut!
Wenn ich jetzt aber an dem Code weiter arbeite, und díe verschiedenen Daten öfters aufrufen muss, will ich nicht immer so viel schreiben wie zB.

Code:

With Workbooks(strDatei & ".csv").Worksheets(strDatei)

Kann ich eine Variable einsetzen im Sinne von:

Code:

Dim wbDatei as Workbook, wsTabelle as worksheet
With wbDatei.wsTabelle

Bzw kann ich das in einer Variablen dann unterbringen? Das ich dann nur noch schreiben würde:

Code:

With wbwsTest

Oder bin ich ganz falsch?

Danke

 

Hi Marius,

eine Arbeitsmappe und ein Tabellenblatt sind Objekte, die man mittels Set-Befehl der betreffenden Variablen zuweist:

Code:

   Dim wsTabelle As Worksheet
   Set wsTabelle = Workbooks(strDatei & ".csv").Worksheets(strDatei)
   With wsTabelle
       '....
   End With
   Set wsTabelle = Nothing

Wenn du allerdings das Mappe-Objekt auch getrennt vom Tabellenblatt-Objekt verwenden willst, dann so:

Code:

   Dim wbDatei As Workbook, wsTabelle As Worksheet
   Set wbDatei = Workbooks(strDatei & ".csv")
   Set wsTabelle = wbDatei.Worksheets(strDatei)
   With wbDatei
       '...
   End With
   With wsTabelle
       '...
   End With
   Set wbDatei = Nothing
   Set wsTabelle = Nothing

Am Schluss der Prozedur sollte man alle mit dem Set-Befehl zugewiesenen Variablen wieder leeren, auch wenn es sich um lokale Variablen handelt, also Variablen die innerhalb der Prozedur deklariert wurden.

Bis später,
Karin

 

Vielen Dank

 

Hallo nochmal,

ich habe ein Problem bei dem wechseln zwischen worksheets.

Code:

Sub Eingabe1()
Dim wsEingabe As Worksheet, wsBerechnung As Worksheet
  Set wsEingabe = Worksheets("Eingabe")
  Set wsBerechnung = Worksheets("Berechnung")
      
  'Eingaben kopieren
  With wsEingabe
    .Range("A8:G5000").Copy
  End With
  'Eingaben in Berechnungsblatt einfügen
  With wsBerechnung
    .Cells(1048576, 1).End(xlUp).Offset(1, 0).Select
    ActiveSheet.Paste
  End With
  
  Set wsEingabe = Nothing
  Set wsBerechnung = Nothing
End Sub

In der Zeile .Cells(1048576,1).End(xlUP).Offset(1,0).Select kommt immer folgende Fehlermeldung:

"Die Select-Methode des Range Objekts konnte nicht ausgeführt werden."

Was mache ich falsch?

Danke

 

Hi,

ich habe es jetzt nicht getestet, aber versuche es mal so:

Code:

Sub Eingabe1()
  Dim wsEingabe As Worksheet, wsBerechnung As Worksheet
  Dim lngErste As Long
  Set wsEingabe = Worksheets("Eingabe")
  Set wsBerechnung = Worksheets("Berechnung")
      
  With wsBerechnung
     ' erste freie Zeile in Spalte A ermitteln
     lngErste = IIf(IsEmpty(.Cells(.Rows.Count, 1)), .Cells(.Rows.Count, 1).End(xlUp).Row, .Rows.Count) + 1
     ' Eingaben kopieren und in die erste freie Zelle Spalte A einfügen
     wsEingabe.Range("A8:G5000").Copy .Cells(lngErste, 1)
   End With
  
  Set wsEingabe = Nothing
  Set wsBerechnung = Nothing
End Sub

Bis später,
Karin