Office: VBA - verschiedene Workbooks aktivieren

Hallo zusammen,
folgendes Problem habe ich. Mittels eines VBA Code möchte ich aus einer Excel Datei Daten in eine andere Datei schreiben. Das klappt alles ganz gut. Das Problem ist, die zu öffnende Quelldatei kann verschiedene Namen haben. Beispiel: Vetretung 1.7 WG8.xls oder Vertretung 1.7 WG7.xls. Nun kollabiert mein Makro beim wechsel der einzelnen Workbooks, weil ich folgende Code benutze.

Code:

    Windows("Vertretung 1.7 WG8.xls").Activate

Wie muss der Code aussehen damit er quasi neutral ist?
Hier mal der gesamte Code:

Code:

Sub Personal_kopieren()
' Personal_kopieren von einer alten Version in dei neue Version
        
    Sheets("Personal").Select       'Personalseite öffnen
    Sheets("Personal").Unprotect Password:="***"
    Range("B4:E53").Select
    Selection.ClearContents
    a = Application.GetOpenFilename("Excel-Dateien(*.xl*),*.xl*")   'alte Version suchen und öffnen
    If a = False Then Exit Sub
    Workbooks.Open Filename:=a
    Sheets("Personal").Select       'Personalseite öffnen und kopieren
    Sheets("Personal").Unprotect Password:="***"
    Range("B4:E53").Select
    Selection.Copy
    
    Windows("Vertretung 1.7 WG8.xlsm").Activate
    Range("B4").Select
    Selection.PasteSpecial Paste:=xlPasteValuesAndNumberFormats, Operation:= _
        xlNone, SkipBlanks:=False, Transpose:=False
    Range("F4").Select
    Application.CutCopyMode = False
    Sheets("Personal").Protect Password:="***"
    
    Windows("Vertretung 1.7 WG8.xls").Activate
    ActiveWindow.Close
    
End Sub

Vielen Dank für eure Hilfe
Gruß Norbert

 

Hallo Norbert,

wenn Du mit mehreren Mappen gleichzeitig arbeitest, wird eine ordentliche Referenzierung eigentlich unverzichtbar.
1. habe ich Deinen Code dahingehend abgeändert.
2. kann man in fast allen Fällen auf "Select" verzichten.
3. wofür willst Du in Deiner Quelldatei den Blattschutz deaktivieren? Bist Du sicher das es notwendig ist? Probiere es mal ohne aus.
4. Deine Anfrage und Dein Code haben mir nicht komplett verdeutlicht was genau Du überhaupt wann - wo - wie machen willst, deshalb gehe ich davon aus Dich eventuell irgendwo falsch interpretiert zu haben.

Schau Dir einfach mal den folgenden Code an und beschreibe genau was daran eventuell nicht passt, dann sehen wir weiter:

Code:

Option Explicit

Dim strQuelle As String


Public Sub Personal_kopieren()
    
    With ThisWorkbook.Worksheets("Personal")
        .Unprotect Password:="***"
        .Range("B4:E53").ClearContents
    End With
    
    strQuelle = Application.GetOpenFilename("Excel,*.xl*")
    If strQuelle = "" Then Exit Sub
    Workbooks.Open Filename:=strQuelle
    strQuelle = Split(strQuelle, "\")(UBound(Split(strQuelle, "\")))
    With Workbooks(strQuelle).Worksheets("Personal")
        .Unprotect Password:="*****"
        .Range("B4:E53").Copy
    End With
    
    With ThisWorkbook.Worksheets("Personal")
        .Range("B4").PasteSpecial Paste:=xlPasteValuesAndNumberFormats, Operation:= _
            xlNone, SkipBlanks:=False, Transpose:=False
        .Protect Password:="***"
    End With
    
    Application.CutCopyMode = False
    Workbooks(strQuelle).Close (False)
    
End Sub

Zwei Anmerkung noch:
- Es ist keinerlei Fehlerabfang vorhanden, wenn z.Bsp. irgendwo das Blatt "Personal" nicht existiert (Tippfehler o.ä.), dann läuft das Makro vor die Wand.
- bist Du sicher das Du beim kopieren auch die Formate komplett übernehmen willst? Ich hätte eher damit gerechnet dass nur die Werte übertragen werden sollen:

Code:

Paste:=xlPasteValues

Ich hoffe geholfen zu haben.

 

Hallo Achim,
vielen Dank für deine Hilfe. Dein Code funktioniert einwandfrei.
1. Erklärung was ich machen will.
Es handelt sich hier um eine Übersicht von Vertretern in unserem Verein. Nun Modifiziere ich ab und zu mal was. Es gibt die Datei bei verschiedenen Leuten mit verschiedenen Namen ( WG1 ; WG2;...). In der Datei sind Peronendaten gut geschützt untergebracht, damit sie nicht jeder sehen kann - ist halt so. Wenn nun eine neue Version von mir kommt, musste der Eigentliche Benutzer alle seine Peronendaten neu eingeben. In der alten Version gab es die Daten schon und mit hilfe deines Codes kann man diese Daten jetzt einfach und schnell übernehmen.
2. Blattschutz:
ja du hast recht funktioniert ohne aufheben des Blattschutzes.
Wußte ich nicht :-)
Nochmal Dankeschön
Gruß Norbert