Office: VBA - Was machen bestimmte Teile des Codes?

Hallo zusammen,

seit einigen Stunden versuche ich den folgenden Code zu verstehen, leider komme ich aber nicht weiter.
(Den Code habe ich im Netz gefunden und er macht genau das was ich brauche bloß verstehe ich nicht wie.)

Hier mal der Code im Ganzen:

Sub test2()
Dim strVerzeichnis As String
Dim lngZaehlen As Long
Dim strPfad As String

strPfad = "C:\Dokumente und Einstellungen\bla\Desktop\Excel\"

strVerzeichnis = Dir(strPfad, vbDirectory)
Do While strVerzeichnis <> ""
If strVerzeichnis <> "." And strVerzeichnis <> ".." And _
(GetAttr(strPfad & strVerzeichnis) And vbDirectory) = vbDirectory Then
lngZaehlen = lngZaehlen + 1
Debug.Print lngZaehlen & " " & strVerzeichnis
End If
strVerzeichnis = Dir
Loop
End Sub

Code:

Sub test2()
   Dim strVerzeichnis As String
   Dim lngZaehlen As Long
   Dim strPfad As String

Okay - hier werden die einzelnen Variablen definiert

Code:

 strPfad = "C:\Dokumente und Einstellungen\Bla\Desktop\Excel\"

Hier wird der Pfad festgelegt

Code:

 strVerzeichnis = Dir(strPfad, vbDirectory)

Hier wird festgelegt welche nach was im Pfad gesucht werden soll --> nach Ordnern

Code:

Do While strVerzeichnis <> ""

Es wird eine Do While Schleife erstellt die solange läuft bis strVerzeichnis leer ist

Code:

         If strVerzeichnis <> "." And strVerzeichnis <> ".." And _
         (GetAttr(strPfad & strVerzeichnis) And vbDirectory) = vbDirectory Then

ALSO diesen Part verstehe ich absolut garnicht. Warum wird 1) nach "." gesucht 2) nach ".." gesucht und
3) (GetAttr(strPfad & strVerzeichnis) And vbDirectory) = vbDirectory --> verstehe ich absolut gar nicht ???????? was macht das

Code:

            lngZaehlen = lngZaehlen + 1
            Debug.Print lngZaehlen & " " & strVerzeichnis
      End If

Okay - das ist klar

Code:

strVerzeichnis = Dir

Was passiert hier????

Code:

Loop
End Sub

Die Schleife wird fortgesetzt und das Makro beendet.


Hat einer von Euch eine Idee was die besagten Parts machen?

Schöne Grüße
Tauchmann

 

Hallo Tauchmann,


der Code listet Dir alle Verzeichnisse in einem Verzeichnis auf. Dir() ist eine VBA-Funktion.
Die kannst Du auch in der VBA-Hilfe genauer anschauen, Cursor auf Dir setzen und F1.

Dir() liefert Dir Dateien, Verzeichnisse usw. von einem Ordner zurück. Und - eine Eigenart
von Dir() - wenn Du weitere Dir() Anweisungen in einer Schleife verwendest und dabei keine
Parameter angibst, wird das nächste geforderte Element zurückgegegeben. Das passiert
dann bei strVerzeichnis = Dir.

GetAttr() prüft, ob es sich beim gefundenen Eintrag auch um ein Verzeichnis handelt.
GetAttr() liefert einen Integer Wert für die Attribute zurück. Beinhaltet dieser Wert
den Wert vbDirectory, liefert Wert AND vbDirectory den Wert vbDirectory. Daher
die Anweisung. Zum Testen:

Code:

MsgBox vbDirectory
MsgBox (vbDirectory + vbSystem) AND vbDirectory
MsgBox CBool((vbDirectory + vbSystem) AND vbDirectory = vbDirectory)

Aus DOS-Zeiten stammt noch . und .. die z.b. das Verzeichnis eine Ebene höher meinen.
Beispielsweise geht der Befehl cd .. in einem Kommandozeilenfenster ein Verzeichnis höher.
Deswegen liefert Dir() auch die zwei Elemente . und .., die dann im Code rausgefiltert werden.

Gruß

 

Hallo Maninweb,

vielen Dank für deine Antwort, nun wird mir so einiges klar.
Ich glaube ich muss deinen Code morgen mal testen und dann sollte es hofentlich klarer werden.

Vielen Dank für deine Hilfe
Tauchmann

P.S. Wenn dann noch etwas unklar ist, würde ich mich nochmal melden.