Office: (Office 2013) VBA - Zellen verketten und Liste erstellen

Hallo zusammen,

ich bin mit Excel bisher eigentlich recht gut zurechtgekommen, scheitere jetzt aber leider am erstellen eines Makros.
Ich habe versucht ein Makro aufzuzeichnen, um mir die gewünschte Funktion im Editor anzusehen, es sind aber so viele Klicks und eigentlich gleiche Vorgänge, dass es doch sicher mit sowas wie einer Schleife in VBA lösen kann.

Folgendes Problem bzw. Aufgabenstellung:

Ich habe zwei Tabellen.
In Tabelle 1 werden beliebig viele Namen in einer Spalte eingetragen.
z.B. A1: Nummer1
A2: Nummer 2
A3: Nummer 3
usw.

In Tabelle 2 stehen Texte in 20 Zellen. z.b. in Zelle B1-B20
z.B. B1: hallo
B2: ich
B3: bin
B4:da
usw.

Mein Makro soll dann die Zellen miteinander verbinden und in eine Spalte schreiben, und zwar erst Tabelle1 A1 mit allen Zellen der Tabelle 2 usw.
Sollte dann so aussehen:
Spalte F:
F1: Nummer 1 hallo
F2: Nummer 1 ich
F3: Nummer 1 bin
F4: Nummer 1 da
.....
F21: Nummer 2 hallo
F22: Nummer 2 ich
F23: Nummer 2 bin
F24: Nummer 2 da
.....
und so weiter, bis in Spalte A keine weiteren Texte mehr stehen.

Ich hoffe ich hab es einigermaßen verständlich erklärt und ihr könnt mir helfen!
Danke im Voraus!!

 

Hi,

kannst du z.B. mit diesem Code realisieren:

Code:

Sub Verknuepfen()
    Dim lngZeile As Long
    Dim lngZaehler1 As Long
    Dim lngZaehler2 As Long
    Dim lngLetzte As Long
    Dim arrDaten1
    Dim arrDaten2
    lngZeile = 1
    lngLetzte = IIf(IsEmpty(Cells(Rows.Count, 1)), Cells(Rows.Count, 1).End(xlUp).Row, Rows.Count)
    arrDaten1 = Application.Transpose(Range(Cells(1, 1), Cells(lngLetzte, 1)))
    With Worksheets("Tabelle2")
        lngLetzte = IIf(IsEmpty(.Cells(.Rows.Count, 2)), .Cells(.Rows.Count, 2).End(xlUp).Row, .Rows.Count)
        arrDaten2 = Application.Transpose(.Range(.Cells(1, 2), .Cells(lngLetzte, 2)))
    End With
    For lngZaehler1 = 1 To UBound(arrDaten1)
        For lngZaehler2 = 1 To UBound(arrDaten2)
            Cells(lngZeile, 5) = arrDaten1(lngZaehler1) & " " & arrDaten2(lngZaehler2)
            lngZeile = lngZeile + 1
        Next lngZaehler2
    Next lngZaehler1
End Sub

Bis später,
Karin