Office: (Office 2013) VBA

Helfe beim Thema VBA in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo zusammen, ich suche nach einer Lösung für ein Makro in Excel 2013 dass mir eine beliebige Ordnerstruktur von einem Rechner bzw. Netzlaufwerk in... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Sylvio82, 21. Oktober 2015.

Seite 1 von 2

SYLVIO82

Sylvio82

VBA

Hallo zusammen,

ich suche nach einer Lösung für ein Makro in Excel 2013 dass mir eine beliebige Ordnerstruktur von einem Rechner bzw. Netzlaufwerk in Excel einliest und auswirft.

Ich habe bereits bei Google und im Forum gesucht aber leider nichts gefunden. *Hoffentlich hab ich nichts übersehen...*

Excel sollte beim ausführen des Makro fragen wo sich der "Quellordner" befindet. Am besten man kann ihn dann in einem Explorer Fenster auswählen.
Nach der Auswahl des Ordners sollte dieser Ordner inkl. aller Unterordner eingelesen werden und wie im Screenshot im Anhang ausgeworfen werden.

Ich habe leider ganz wenig verständnis von VBA. Wäre super wenn mir jemand helfen kann.

Viele Grüße und schonmal Danke.

:)

Sylvio82, 21. Oktober 2015

#1
XLPH

xlph

Ich habe bereits bei Google und im Forum gesucht aber leider nichts gefunden. *Hoffentlich hab ich nichts übersehen...*
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Kaum zu glauben....Google-Such: 'vba Ordner auflisten' -> 6.320 Ergebnisse *mrcool

Code:

Public Sub OrdnerListen_Start()
Dim fso As Object

With ActiveSheet

.UsedRange.ClearContents

Set fso = CreateObject("Scripting.FileSystemObject")

Call OrdnerListen(fso, "E:\Test", .Range("A1")) ' Pfad anpassen!

Set fso = Nothing

End With

End Sub

Private Sub OrdnerListen(fso As Object, Ordnerangabe As String, rng As Range, Optional Zeile As Long, Optional Spalte As Long)
Dim o, uo

Set o = fso.GetFolder(Ordnerangabe)

rng.Offset(Zeile, Spalte).Value = o.Name

Zeile = Zeile + 1

For Each uo In o.SubFolders
Spalte = Spalte + 1
Call OrdnerListen(fso, uo.Path, rng, Zeile, Spalte)
Spalte = Spalte - 1
Next

Set o = Nothing
Set uo = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

xlph, 22. Oktober 2015

#2
SYLVIO82

Sylvio82

Danke dir. Du hast Recht. Solche Beiträge habe ich auch mehr als genug gefunden, aber keiner entspricht der Lösung die ich suche.

In deinem Beispiel steht z.B. Call OrdnerListen(fso, "E:\Test", .Range("A1")) ' Pfad anpassen!

Genau das suche ich aber nicht denn der Pfad ist jedes mal anders.

Ich erkläre mal wofür ich das brauche.

Ich soll auf einem Server regelmäßig eine Ordnerstruktur ergänzen und bekomme von verschiedenen Personen Screenshots mit der zu ergänzenden Ordnerstruktur. Das nervt, denn ich muss jedes mal die Ordner manuell erstellen oder eine OCR Software drüber laufen lassen die die Namen mehr schlecht als recht erkennt.

Ich brauche die Struktur also einfach in Excel weil ich sie damit einfach auf dem Server importieren kann.

Deswegen möchte ich diesen Personen dann einfach die Makro Datei zusenden und sagen, "lesen Sie bitte die Struktur ein und senden Sie mir dann das File zurück".

Deswegen soll eine Abfrage mit dabei sein weil es die Leute möglichst einfach haben sollen.

Grüße

Sylvio82, 23. Oktober 2015

#3
XLPH

xlph

VBA

Genau das suche ich aber nicht denn der Pfad ist jedes mal anders.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ein Start-Verzeichnis muss nun mal angegeben werden, ließe sich auch
durch ein FileDialog abfragen.

"lesen Sie bitte die Struktur ein und senden Sie mir dann das File zurück"
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wie kann eine Ordnerstruktur eingelesen werden die nicht vorhanden ist?

xlph, 23. Oktober 2015

#4
SYLVIO82

Sylvio82

OK. Wäre dann C:\ ausreichend?

"lesen Sie bitte die Struktur ein und senden Sie mir dann das File zurück"
Wie kann eine Ordnerstruktur eingelesen werden die nicht vorhanden ist?
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Die haben die Ordner auf Ihrem Rechner und machen einfach einen Screenshot davon.

Sylvio82, 23. Oktober 2015

#5
SYLVIO82

Sylvio82

Also dein Makro funktioniert super für den Pfad den ich angebe im VBA. Genau so möchte ich die Ordner aufgelistet haben. Vielen Dank schon mal! *mrcool

Das einzige was ich jetzt noch benötige ist eine Abfrage beim ausführen des Makro, wo sich das "Quellverzeichnis" befindet.

Sylvio82, 23. Oktober 2015

#6
XLPH

xlph

Code:

Public Sub OrdnerListen_Start()
Dim fso As Object

Dim strPfad As String

With Application.FileDialog(msoFileDialogFolderPicker)
.Title = "Start-Verzeichnis wählen"
.ButtonName = "übernehmen"
If .Show -1 Then Exit Sub
strPfad = .SelectedItems(1)
End With

With ActiveSheet

.UsedRange.ClearContents

Set fso = CreateObject("Scripting.FileSystemObject")

Call OrdnerListen(fso, strPfad, .Range("A1")) ' Pfad anpassen!

Set fso = Nothing

End With

End Sub

Private Sub OrdnerListen(fso As Object, Ordnerangabe As String, rng As Range, Optional Zeile As Long, Optional Spalte As Long)
Dim o, uo

Set o = fso.GetFolder(Ordnerangabe)

rng.Offset(Zeile, Spalte).Value = o.Name

Zeile = Zeile + 1

For Each uo In o.SubFolders
Spalte = Spalte + 1
Call OrdnerListen(fso, uo.Path, rng, Zeile, Spalte)
Spalte = Spalte - 1
Next

Set o = Nothing
Set uo = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

xlph, 23. Oktober 2015

#7
SYLVIO82

Sylvio82

VBA

xlph du bist genial! Vielen Dank!!! *biggrin.gif*

Das ist genau das was ich suchte. Das erleichtert mir meine Arbeit ungemein.

SPITZE! *hands

Sylvio82, 25. Oktober 2015

#8
SYLVIO82

Sylvio82

xlph wärst du so nett und könntest dir diesen Thread nochmal ansehen.

Das ist jetzt das gleiche nur in die andere Richtung.

Danke.

Sylvio82, 18. November 2015

#9
POLDINA33

poldina33

Hallo Ihr Lieben *biggrin.gif*

Makro hat bei mir super funktioniert, vielen dank euch *biggrin.gif*

Könnte jemand bitte mir bei der Erweiterung des Makros helfen?
Die Ordnerstuktur soll die selbe sein, nur sollen die Dateien, die in den Ordner sind mit angegeben werden + Pfad und die Datei als Hyperlink?

Hauptordner
1. Unterordner
Datei mit Hyperlink + Pfad (in einer neuen Spalte)
2. Unterordner
2.1 Unterordner
Datei mit Hyperlink + Pfad (in einer neuen Spalte
Datei mit Hyperlink + Pfad (in einer neuen Spalte
.
2.2 Unterordner
Datei mit Hyperlink + Pfad (in einer neuen Spalte
.
.
.

wäre super lieb
Danke *biggrin.gif*

poldina33, 28. Juni 2016

#10
XLPH

xlph

Code:

Option Explicit

Public Sub OrdnerListen_Start()
Dim fso As Object

Application.ScreenUpdating = False

With ActiveSheet

.UsedRange.Clear

Set fso = CreateObject("Scripting.FileSystemObject")

Call OrdnerListen(fso, "E:\Test", .Range("A1")) ' Pfad anpassen!

Set fso = Nothing

End With

Application.ScreenUpdating = True

End Sub

Private Sub OrdnerListen(fso As Object, Ordnerangabe As String, rng As Range, Optional Zeile As Long, Optional Spalte As Long)
Dim o, uo, f

Set o = fso.GetFolder(Ordnerangabe)

With rng.Offset(Zeile, Spalte)
.Value = o.Name
.Font.Bold = True
End With

Zeile = Zeile + 1

For Each f In o.Files
With rng.Offset(Zeile, Spalte)
.Value = f.Name
.Hyperlinks.Add .Cells, f.Path, "", f.Path
.IndentLevel = 1
End With
Zeile = Zeile + 1
Next
Set f = Nothing

For Each uo In o.SubFolders
Spalte = Spalte + 1
Call OrdnerListen(fso, uo.Path, rng, Zeile, Spalte)
Spalte = Spalte - 1
Next

Set o = Nothing
Set uo = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

xlph, 28. Juni 2016

#11
XLPH

xlph

Zusatz: Mit Auf-/Zuklappen der einzelnen Ebenen

xlph, 28. Juni 2016

#12
POLDINA33

poldina33

VBA

Vielen Vielen Dank *Smilie *Smilie
Große Hilfe *Smilie *Smilie
Mit auf und Zuklappen ist auch voll cool, ich muss nur ein wenig anders aufbereiten. Danke aber dafür *Smilie

Von VBA hab ich null Ahnung, hab noch ein wenig rumprobiert und den Pfad hinbekommen. Jedoch möchte ich den Pfad neben dem Hyperlink
haben. Auf dem Bild kann man sehen, dass die Pfade weiter unten angegeben werden
Wie kann ich das ändern?

Hab den Code so umgeschrieben
Code:

Option Explicit

Public Sub OrdnerListen_Start()
Dim fso As Object

Application.ScreenUpdating = False

With ActiveSheet

.UsedRange.Clear

Set fso = CreateObject("Scripting.FileSystemObject")

Call OrdnerListen(fso, "S:\VDD-IDI\A.", .Range("A1")) ' Pfad anpassen!

Set fso = Nothing

End With

Application.ScreenUpdating = True

End Sub

Private Sub OrdnerListen(fso As Object, Ordnerangabe As String, rng As Range, Optional Zeile As Long, Optional Spalte As Long)
Dim o, uo, f

Set o = fso.GetFolder(Ordnerangabe)

With rng.Offset(Zeile, Spalte)
.Value = o.Name
.Font.Bold = True
End With

Zeile = Zeile + 1
For Each f In o.Files
With rng.Offset(Zeile, 10)
.Value = f.Name
.Hyperlinks.Add .Cells, f.Path, "", f.Path
' .IndentLevel = 1

End With
Zeile = Zeile + 1

Next

For Each f In o.Files
With rng.Offset(Zeile, 11)
.Value = f.Path
' .IndentLevel = 5
End With
Zeile = Zeile + 1

Next

Set f = Nothing

For Each uo In o.SubFolders
Spalte = Spalte + 1
Call OrdnerListen(fso, uo.Path, rng, Zeile, Spalte)
Spalte = Spalte - 1
Next

Set o = Nothing
Set uo = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

http://www.ms-office-forum.net/forum...1&d=1467192074

Danke *Smilie

poldina33, 28. Juni 2016

#13
XLPH

xlph

Wenn du mit der Maus über dem Link stehen bleibst, dann wird der Pfad angezeigt, langt das nicht?

xlph, 29. Juni 2016

#14
POLDINA33

poldina33

Nein, leider nicht *frown.gif*
Chef möchte das so haben *frown.gif*
Hab ich ihm auch versucht zu erklären.

poldina33, 29. Juni 2016

#15

(Du musst angemeldet oder registriert sein, um eine Antwort erstellen zu können.)

Seite 1 von 2

Thema:

VBA

Die Seite wird geladen...

VBA - Similar Threads - VBA
VBA in einer Zeile zu lang
in Microsoft Excel Hilfe
VBA in einer Zeile zu lang: Moin, mein VBA Code ist für eine Zeile zu lang. Kann mir einer helfen wie ich den auf 2 Zeilen aufteilen Kann? arrSchuhDaten = Array(Range("A6"), Range("F6"), Range("J6"), Range("A7"),...
Listbox wird nicht breiter, Schriftgrösse ändert sich
in Microsoft Excel Hilfe
Listbox wird nicht breiter, Schriftgrösse ändert sich: Hallo, ich habe ein Formular dessen Breite ich mit der Maus ändern kann. Im Formular habe ich einen Rahmen und darin eine Listbox deren Breite an die Formularbreite angepasst wird....
Kontrollkästchen aktivieren ohne VBA - wenn KK1 angekreuzt dann KK2 auch
in Microsoft Excel Hilfe
Kontrollkästchen aktivieren ohne VBA - wenn KK1 angekreuzt dann KK2 auch: Hallo zusammen, erstmal danke für all die Tipps und Kniffe, die ich ohne eigenen Thread gefunden und gelernt habe. Leider finde ich mein Thema nirgendwo... Aktuell habe ich zwei Spalten mit...
Per Hyperlink ausgeblendetes Blatt einblenden
in Microsoft Excel Hilfe
Per Hyperlink ausgeblendetes Blatt einblenden: Hola ins Forum, ich bräuchte mal wieder eure Hilfe. Ich habe ein Tabellenblatt das mir als Register dient und wo Hyperlinks eingefügt sind um auf das dazugehörige Blatt zu springen. Diese Blätter...
Bilder über VBA Größe und DPI ändern für Webshop
in Microsoft Excel Hilfe
Bilder über VBA Größe und DPI ändern für Webshop: Hallo Excel Spezialisten, Ich habe mir eine recht aufwendige Tabelle gebastelt, aus der ich Daten für meinen Webshop generiere und in einer .csv bereitstelle. Es werden neue Preislisten...
VBA: Platzhalter ersetzen und evtl. leere Zeile einfügen
in Microsoft Word Hilfe
VBA: Platzhalter ersetzen und evtl. leere Zeile einfügen: Hallo zusammen, ich habe eine Word-Vorlage mit Platzhaltern, in die ich mit VBA Daten aus einer Excel-Datei einfüge (in eine Excel-Zeile schreibe ich alle Daten für ein neues Word-Dokument). So...
Erstellung eines Dynamischen Kalenders (ggf. VBA)
in Microsoft Word Hilfe
Erstellung eines Dynamischen Kalenders (ggf. VBA): Guten Morgen an Alle, ich hoffe, es geht euch soweit gut :) Ich wende mich heute an euch, weil ich gerade vollkommen verzweifle und irgendwie so ganz und garnicht weiterkomme und irgendwie...

Anmelden oder registrieren

Suche

Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.

Akzeptieren Weitere Informationen...

Information ausblenden