Office: Vergleich String, Listbox filtern

Helfe beim Thema Vergleich String, Listbox filtern in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Guten Abend Ich bin ein kleines Tool am Programmieren und stehe an folgendem Punkt an: Ich habe eine Listbox, wird folgendermassen gefüllt: Code:... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Mani88, 7. August 2011.

Seite 1 von 2

MANI88

Mani88

Vergleich String, Listbox filtern

Guten Abend

Ich bin ein kleines Tool am Programmieren und stehe an folgendem Punkt an:

Ich habe eine Listbox, wird folgendermassen gefüllt:

Code:

With ListBoxSuchergebnisse

ListBoxSuchergebnisse.Clear
ListBoxSuchergebnisse.ColumnCount = 3

For i = 0 To (Sheets("Artikel").Cells(Rows.Count, 1).End(xlUp).Row) - 2

ListBoxSuchergebnisse.AddItem
ListBoxSuchergebnisse.List(i, 0) = Sheets("Artikel").Cells(i + 2, 1)
ListBoxSuchergebnisse.List(i, 1) = Sheets("Artikel").Cells(i + 2, 2)
ListBoxSuchergebnisse.List(i, 2) = Sheets("Artikel").Cells(i + 2, 3)

Next i

End With
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich möchte jetzt gerne die Einträge der Listbox filtern. Nach der ersten Spalte.
Die Spalte hat folgende Werte: 1-9098, 1-4932, 3-4543,...
Ich möchte jetzt gerne den Inhalt des Texfeldes, in der ich meine Suchanfrage eingeben kann mit diesen Werten vergleichen.

Wenn ich aber "1-" eingebe, möchte ich, dass alle Zeilen, welche mit "1-" beginnen angezeigt werden. Wenn ich "1-2" eingebe, alle, welche mit "1-2..." beginnen.

Wie gehe ich sowas an? Vielen Dank für eure Hilfe, Gruss Mani

:)

Mani88, 7. August 2011

#1
CITIZENX

CitizenX

Hi,

wenn es sich um Steurerelemente aus der Steurelemet-Toolbox handelt dann so:

Erstelle eine Textbox und weise ihr folgenden Code zu:

Code:

Option Explicit

Private Sub TextBox1_Change() 'Textboxnamen ggf anpassen

Dim i As Long, lngLast As Long
Dim objList As Object
Dim myArray(), inRow

Set objList = CreateObject("System.Collections.Arraylist")

If LenB(Trim(TextBox1)) Then

With ThisWorkbook.Sheets("Artikel")

lngLast = .Cells(.Rows.Count, 1).End(xlUp).Row

For i = 2 To lngLast - 2
If TextBox1 = Left(.Cells(i, 1), Len(TextBox1)) Then
objList.Add .Cells(i, 1).Text
End If
Next

End With

objList.Sort

ReDim myArray(1 To lngLast)

myArray = objList.toArray

With ListBoxSuchergebnisse

.Clear
.ColumnCount = 3

For i = 0 To UBound(myArray)

.AddItem

.List(i, 0) = myArray(i)

inRow = Application.Match(Trim(myArray(i)), Sheets("Artikel").Columns(1), 0)
If IsNumeric(inRow) Then .List(i, 1) = Sheets("Artikel").Cells(inRow, 2)

inRow = Application.Match(Trim(myArray(i)), Sheets("Artikel").Columns(1), 0)
If IsNumeric(inRow) Then .List(i, 2) = Sheets("Artikel").Cells(inRow, 3)

Next i

End With

Else

With ListBoxSuchergebnisse

.Clear
.ColumnCount = 3

For i = 0 To Sheets("Artikel").Cells(Rows.Count, 1).End(xlUp).Row - 2

.AddItem
.List(i, 0) = Sheets("Artikel").Cells(i + 2, 1)
.List(i, 1) = Sheets("Artikel").Cells(i + 2, 2)
.List(i, 2) = Sheets("Artikel").Cells(i + 2, 3)

Next i

End With

End If

Set objList = Nothing

End Sub

Private Sub TextBox1_GotFocus() 'Textboxnamen ggf anpassen
Dim i&
With ListBoxSuchergebnisse

.Clear
.ColumnCount = 3

For i = 0 To Sheets("Artikel").Cells(Rows.Count, 1).End(xlUp).Row - 2

.AddItem
.List(i, 0) = Sheets("Artikel").Cells(i + 2, 1)
.List(i, 1) = Sheets("Artikel").Cells(i + 2, 2)
.List(i, 2) = Sheets("Artikel").Cells(i + 2, 3)

Next i

End With
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

CitizenX, 9. August 2011

#2
MANI88

Mani88

Vielen Dank für deine schnelle und perfekte Antwort. Genau das habe ich gesucht.

Gruss Mani

Mani88, 9. August 2011

#3
MANI88

Mani88

Vergleich String, Listbox filtern

Was noch hübsch wäre:

Wenn ich in der Suchanfrage die vollständige Artikelnummer eingebe (die existiert in der Liste nur einmal), sollte es mir direkt den Artikel in der Listbox auswählen. Sprich: Wenn die Suchafrage nur einen Treffer ergibt, direkt diesen in der Listbox anwählen.

Was müsste ich da noch einfügen?

Merci und Gruss

Mani88, 9. August 2011

#4
CITIZENX

CitizenX

Hi,

füge folgende Codezeile am Ende des Makros vor Set objList = Nothing ein:

Code:

If TextBox1 = ListBoxSuchergebnisse.List(0, 0) Then ListBoxSuchergebnisse = TextBox1
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

CitizenX, 9. August 2011

#5
MANI88

Mani88

Merci..*wink.gif*

Mani88, 10. August 2011

#6
MANI88

Mani88

So, ich bin nun mein Programm am Testen und habe folgendes Problem:

Wenn ich in mein Blatt "Artikel" Daten von einem anderen Excel Sheet kopiere und nach diesen dann mit deinem Code suchen möchte, funktioniert es einwandfrei.

Sobald ich aber im Blatt Artikel an einer Zeile etwas ändere, wird mir der Eintrag zwar in der istbox noch aufgeführt, wenn ich aber nach der Artikelnummer suche, erhalte ich kein Ergebnis. Seh komisch...

Ich habe bereits die Zellen auf ihre Eigenschaften "Zahl, Text,..." geprüft und keinen Unterschied festgestellt.

Ich hoffe, ihr könnt mir helfen...

Gruss Mani

Mani88, 10. August 2011

#7
MANI88

Mani88

Vergleich String, Listbox filtern

Ah, jetzt habe ich was rausgefunden:

Es geht nur, wenn die Zelle als "Als Text gespeicherte Zahl" formatiert ist (siehe Bild). Was muss ich ändern, damit es auch sonst funktioniert. Denn so ist die Fehlerquelle bei der Angabe sehr gross.

Edit: Stimmt doch nicht ganz. Es funktioniert auch wenn "Als Text gespeicherte Zahl" angewählt ist nicht immer...

Mani88, 10. August 2011

#8
MANI88

Mani88

Eventuell hab ichs jetzt rausgefunden, bitte überprüfe es aber, damit ich nicht später andere Fehler habe:

Dein Code:
Code:

For i = 2 To lngLast - 2
If TextBoxSuchen = Left(.Cells(i, 1), Len(TextBoxSuchen)) Then
objList.Add .Cells(i, 1).Text
'If TextBoxSuchen = Left(.Cells(i, 3), Len(TextBoxSuchen)) Then
'objList.Add .Cells(i, 3).Text
End If
Next
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Meine Änderung:

Code:

For i = 2 To lngLast 'hier habe ich das "-2" entfernt
If TextBoxSuchen = Left(.Cells(i, 1), Len(TextBoxSuchen)) Then
objList.Add .Cells(i, 1).Text
'If TextBoxSuchen = Left(.Cells(i, 3), Len(TextBoxSuchen)) Then
'objList.Add .Cells(i, 3).Text
End If
Next
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ist das so korrekt?

Mani88, 10. August 2011

#9
CITIZENX

CitizenX

Hi Mani,

hier der überarbeitete Code,bitte komplett ersetzen...

Code:

Option Explicit

Private Sub TextBox1_Change() 'Textboxnamen ggf anpassen

Dim i As Long, lngLast As Long
Dim objList As Object
Dim myArray(), inRow

Set objList = CreateObject("System.Collections.Arraylist")

If LenB(Trim(TextBox1)) Then

With ThisWorkbook.Sheets("Artikel")

lngLast = .Cells(.Rows.Count, 1).End(xlUp).Row

For i = 2 To lngLast
If TextBox1 = Left(.Cells(i, 1), Len(TextBox1)) Then
objList.Add .Cells(i, 1).Text
End If
Next

End With

objList.Sort

ReDim myArray(1 To lngLast)

myArray = objList.toArray

With ListBoxSuchergebnisse

.Clear
.ColumnCount = 3

For i = 0 To UBound(myArray)

.AddItem

.List(i, 0) = myArray(i)

Set inRow = Sheets("Artikel").Columns(1).Find(myArray(i), LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=False)

If Not inRow Is Nothing Then
.List(i, 1) = Sheets("Artikel").Cells(inRow.Row, 2)
.List(i, 2) = Sheets("Artikel").Cells(inRow.Row, 3)
End If

Next i

End With

Else

With ListBoxSuchergebnisse

.Clear
.ColumnCount = 3

For i = 0 To Sheets("Artikel").Cells(Rows.Count, 1).End(xlUp).Row - 2

.AddItem
.List(i, 0) = Sheets("Artikel").Cells(i + 2, 1)
.List(i, 1) = Sheets("Artikel").Cells(i + 2, 2)
.List(i, 2) = Sheets("Artikel").Cells(i + 2, 3)

Next i

End With

End If

On Error Resume Next
If ListBoxSuchergebnisse.ListCount = 1 Then ListBoxSuchergebnisse = TextBox1

Set objList = Nothing

End Sub

Private Sub TextBox1_GotFocus() 'Textboxnamen ggf anpassen
Dim i&
With ListBoxSuchergebnisse

.Clear
.ColumnCount = 3

For i = 0 To Sheets("Artikel").Cells(Rows.Count, 1).End(xlUp).Row - 2

.AddItem
.List(i, 0) = Sheets("Artikel").Cells(i + 2, 1)
.List(i, 1) = Sheets("Artikel").Cells(i + 2, 2)
.List(i, 2) = Sheets("Artikel").Cells(i + 2, 3)

Next i

End With
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Edit: Ich bin davon ausgegangen das du nur die Zahlenkombis wie angegeben verwendest (1-9098, 1-4932, 3-4543,...) weil die sind Text, wenn du aber Kombinationen aus Text/Zahlenwerten verarbeiten möchtest dann ist dieser besser..

CitizenX, 10. August 2011

#10
EARLFRED

EarlFred

Hallo zusammen,

hatte mal für eine sehr ähnliche Frage einen Code geschrieben, den ich mal schnell angepasst habe. Ich poste ihn einfach mal informativ:

Code:

Option Explicit
Dim arrListboxList As Variant
Private Sub TextBox1_Change() 'Textboxnamen ggf anpassen
Dim i As Long
With Me.ListBoxSuchergebnisse
.List = arrListboxList
If Not IsNull(Me.TextBox1) Then
For i = .ListCount - 1 To 0 Step -1
If LCase(Left(.List(i, 0), Len(Me.TextBox1))) LCase(Me.TextBox1) Then
.RemoveItem (i)
End If
Next i
End If
If .ListCount = 1 Then .Selected(0) = True
End With
End Sub
Private Sub UserForm_Initialize()
With ListBoxSuchergebnisse
.Clear
.ColumnCount = 3
arrListboxList = Sheets("Artikel").Range("A2:C" & Sheets("Artikel").Cells(Rows.Count, 1).End(xlUp).Row).Value
.List = arrListboxList
End With
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Der Code ist sehr einfach gehalten und sortiert leider nicht wie Steffens Code (nette Sache, übrigens!), sondern erwartet, wenn eine Sortierung erwünscht ist, eine bereits sortierte Liste als Datengrundlage. Vielleicht brauchts mal wer als schnelle Alternative, da die Anpassung wenig Wissen verlangt.

Grüße
EarlFred

EarlFred, 10. August 2011

#11
MANI88

Mani88

okey, merci für deinen neuen Code. Es funktioniert nun.

Kleine Frage noch: Die Listbox hat jetzt länger zum laden als vorher (ca 500 Einträge). Es get zwar nur ein Bruchteil einer Sekunde, ist aber trotzdem etwas mühsam. Könnte man möglicherweise den Code noch ein wenig optimieren?

Mani88, 11. August 2011

#12
CITIZENX

CitizenX

Vergleich String, Listbox filtern

Hi,

teste mal den:

Code:

CitizenX, 11. August 2011

#13
MANI88

Mani88

perfekt..*wink.gif*

Letzt Frage (Hoffentlich) *wink.gif*:

Ich frage in einer Listbox ab, nach was gesucht werden soll. Das heisst nach Artikelnummer (wie bisher) oder nach Artikel. Der Artikel steht auch in der selben Liste, aber in der Spalte 2.

Was muss ich in deinem Code ändern, damit ich nach dem Artikel suchen kann? Ich nehme an, nur einige "1" zu "2" ändern, oder nicht?*wink.gif*

Gruss

Mani88, 11. August 2011

#14
EARLFRED

EarlFred

Hallo Gruss,

eine Variante, die in allen 3 Spalten parallel sucht und bei mir mit ca. 10000 Datensätzen nahezu unverzögert läuft:
Code:

Option Explicit

Dim ListboxListe As Variant
Dim dic As Object

Private Sub TextBox1_Change()
Dim ftemp(0 To 0, 0 To 2) As Variant, fDummy As Variant
Dim blnHit As Boolean, i As Long, j As Long
If Me.TextBox1 = vbNullString Then
Me.ListBoxSuchergebnisse.List = ListboxListe
Else
dic.RemoveAll
With Me.ListBoxSuchergebnisse
For i = LBound(ListboxListe, 1) To UBound(ListboxListe, 1)
fDummy = Split(Me.TextBox1, " ")
For j = LBound(fDummy) To UBound(fDummy)
If InStr(1, ListboxListe(i, 1) & "###" & ListboxListe(i, 2) & "###" & ListboxListe(i, 3), fDummy(j), vbTextCompare) Then
blnHit = True
Else
blnHit = False
Exit For
End If
Next
If blnHit Then
dic(ListboxListe(i, 1) & "###" & ListboxListe(i, 2) & "###" & ListboxListe(i, 3)) _
= Array(ListboxListe(i, 1), ListboxListe(i, 2), ListboxListe(i, 3))
End If
blnHit = False
Next i
Select Case dic.Count
Case Is > 1
.List = WorksheetFunction.Transpose(WorksheetFunction.Transpose(dic.items))
.ListIndex = -1
Case 1
fDummy = dic.items
ftemp(0, 0) = fDummy(0)(0): ftemp(0, 1) = fDummy(0)(1): ftemp(0, 2) = fDummy(0)(2)
.List = ftemp
.Selected(0) = True
Case Else
.Clear
End Select
End With
End If
End Sub

Private Sub UserForm_Initialize()
'ListboxListe = Worksheets("Artikel").Range("A2:C5000").Value
ListboxListe = Intersect(Worksheets("Artikel").UsedRange, Worksheets("Artikel").Columns("A:C")).Value
With Me.ListBoxSuchergebnisse
.List = ListboxListe
.ColumnCount = 3
End With
Set dic = CreateObject("Scripting.Dictionary")
End Sub

Private Sub UserForm_Terminate()
Set dic = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Mehrere (Teil-)Suchbegriffe können mit Leerzeichen getrennt eingegeben werden.

Grüße
EarlFred

EarlFred, 12. August 2011

#15

(Du musst angemeldet oder registriert sein, um eine Antwort erstellen zu können.)

Seite 1 von 2

Thema:

Vergleich String, Listbox filtern

Die Seite wird geladen...

Vergleich String, Listbox filtern - Similar Threads - Vergleich String Listbox
Ergebnis aus INDEX und Vergleich Formel weiter Verwenden
in Microsoft Excel Hilfe
Ergebnis aus INDEX und Vergleich Formel weiter Verwenden: Hallo :-) Ich möchte ein Ergebnis aus einer Formel (Index/Vergleich) mit einer Wenn Funktion auswerten. Wenn sieht aber nicht das Ergebnis in dem Kästchen sondern nur die Formel!...
Zwei Dateien vergleichen - Zielinfo in unterschiedlichen Spalten
in Microsoft Excel Hilfe
Zwei Dateien vergleichen - Zielinfo in unterschiedlichen Spalten: Hallo, ich benötige eure Unterstützung. Ich habe zwei Dateien (Excel) dahingehend abgleichen ob in der einen Datei (Master) Zieldaten (Boxennummern - jede in einer Zeile) und deren Folgedaten...
Strings vergleichen und Unterschiede markieren
in Microsoft Excel Hilfe
Strings vergleichen und Unterschiede markieren: Hallo Leute... Gibt es in VBA die Möglichkeit Strings miteinander zu vergleichen und Unterschiede im Text zu markieren oder irgendwie anders deutlich zu machen? Da tu ich mir im Moment sehr...
String vergleichen mit IF-Anweisung
in Microsoft Excel Hilfe
String vergleichen mit IF-Anweisung: Hallo zusammen, ich versuche gerade, Strings zu vergleichen, bisher jedoch mit mäßigem Erfolg... Und zwar habe ich einen Wert, der über einen Sverweis in eine Zelle eingetragen wird. Der sieht...
Zelleninhalte auslesen und mit strings vergleichen
in Microsoft Excel Hilfe
Zelleninhalte auslesen und mit strings vergleichen: hallo, an alle vba experten ich als anfänger komme leider nicht weiter ich möchte gerne die excel tabelle (Zeilen von anfang bis ende ) und (Spalten von A bis D) mit einer schleife durchlaufen...
Zahlenweiser Vergleich auf String Spalte
in Microsoft Access Hilfe
Zahlenweiser Vergleich auf String Spalte: Guten Tag, ich habe folgendes Problem: ich möchte in einem Formular eine Software Version eintragen und dann per Button klick eine Tabelle durchsuchen die z.B >= der eingetragenen Software...
Vergleich von String-Variablen
in Microsoft Access Hilfe
Vergleich von String-Variablen: Hmmm... ja.... mein Originalthread vom 16.10. ist verschwunden ... also nochmal: Ich möchte zwei Begriffe vergleichen. Einer stammt aus einer Tabelle, der andere stammt aus dem Textfeld eines...

Anmelden oder registrieren

Suche

Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.

Akzeptieren Weitere Informationen...

Information ausblenden