Office: Verknüpfungen aus Ordner auslesen

Moin Mitglieder,
ich wollte alle Verknüpfungen aus einem Ordner auslesen.
Das auslesen der Namen habe ich hiermit hin bekommen...

PHP:

         Sub Test02()
Dim Verzeichnis As String
Dim Zeile As Integer
Dim Dateityp As String
Dim Dateiname As String

Verzeichnis = Sheets("Grunddaten").Cells(38, 3)
Dateityp = "*.lnk"
Dateiname = Dir(Verzeichnis & "\" & Dateityp)
Zeile = 1

Do While Dateiname <> ""
Sheets("Wartefachliste").Cells(Zeile + 10, 5).Value = Dateiname
Zeile = Zeile + 1
Dateiname = Dir
Loop
End Sub


:)

 

Hallo,

ein Beispiel:

Public Sub Verknuepfungen_auslesen()

Dim objShell As Object
Dim objFolder As Object
Dim objFile As Object
Dim objLink As Object

Set objShell = CreateObject("Shell.Application")

Set objFolder = objShell.Namespace("C:\Dokumente und Einstellungen\HP\Desktop\")

For Each objFile In objFolder.items

If objFile.IsLink Then

Set objLink = objFile.GetLink

With objLink

Call MsgBox(.Path & vbLf & .Target.Path & vbLf & .Description)

End With
End If
Next

Set objLink = Nothing
Set objFolder = Nothing
Set objShell = Nothing

End Sub

 

Moin Nepumuk,
erst einmal vielen Dank für Deine Bemühungen.
Dein Beispiel liefert mir leider nicht die gewünschten Werte, ich bekomme folgende
Daten geliefert...
objLink.Path: C:\WINDOWS\explorer.exe
objLink.Target.Path : C:\WINDOWS\explorer.exe

Ich habe hier lange rumprobiert... es liegt anscheinend an den Parametern zum Öffnen
des Ordners, denn wenn ich den Link "zu Fuß" erstelle, also mit Ordner markieren und
Strg+Shift die Verknüfung erstellen, funktioniert Dein Code.

Ich erstelle meine Verknüpfungen wie folgt...

PHP:

         Sub Test05()
Dim objShell As Object, objLink As Object, objFSO As Object
Dim OrdnerMitDenVerknüpungen As String, VerknüpfungsName As String
Dim ProgramPath As String, VerknüpfungsLage As String

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("WScript.Shell")

OrdnerMitDenVerknüpungen = "G:\Verknüpfungsordner\"
VerknüpfterOrdner = "G:Zorro"
VerknüpfungsName = "Hier ist Zorro "
ProgramPath = "%SystemRoot%explorer.exe"

Set objLink = objShell.CreateShortcut(OrdnerMitDenVerknüpungen & VerknüpfungsName & ".lnk")

With objLink
.targetpath = VerknüpfterOrdner      ' welcher Ordner soll geöffnet werden
.targetpath = ProgramPath   'Parameter zum öffnen des Explorers
.Arguments = " /e,/root,   " & Chr(34) & VerknüpfterOrdner & Chr(34)  'Parameter zum öffnen des Explorers
'.IconLocation = IconLage
End With

objLink.Save    'speichern des Links
End Sub


 

Hallo,

na dann so:

Public Sub Verknuepfungen_auslesen()

Dim objShell As Object
Dim objFolder As Object
Dim objFile As Object
Dim objLink As Object

Set objShell = CreateObject("Shell.Application")

Set objFolder = objShell.Namespace("G:\Verknüpfungsordner\")

For Each objFile In objFolder.items

If objFile.IsLink Then

Set objLink = objFile.GetLink

Call MsgBox(objLink.Path & vbLf & objFile.Name)

End If
Next

Set objLink = Nothing
Set objFolder = Nothing
Set objShell = Nothing

End Sub

Hier hast du noch einen Fehler drin:

VerknüpfterOrdner = "G:\Zorro"

 

Moin Nepumuk,
bin erst jetzt dazu gekommen...
hat funktioniert...
Danke
Gruß Pascal