Office: verschachtelte funktion

hallo profis!

habe ein kleines problem und suche nach hilfe:

ich möchte abfragen ob in der zelle das wort "amt" oder "land" enthalten ist...ist dies der fall, soll die zelle den wert "N/A" enthalten, andererseits "x" hinschreiben.

wüsste jemand rat?

=wenn(finden(oder("amt";"land");C2);"N/A";"x") = meine syntax...aber funzt nicht leider

beste grüße!

 

Hallo!

Versuch's mal so...

	A	B
1	Finanzamt	N/A
2	Amtsgericht	N/A
3	England	N/A
4	Italien	x
5	Tamtam	N/A
6	Orlando	N/A
7	Landesarbeitsamt	N/A

Zelle	Formel
B1	=WENN((ISTFEHL(SUCHEN("land";A1))*ISTFEHL(SUCHEN("amt";A1)));"x";"N/A")
B2	=WENN((ISTFEHL(SUCHEN("land";A2))*ISTFEHL(SUCHEN("amt";A2)));"x";"N/A")
B3	=WENN((ISTFEHL(SUCHEN("land";A3))*ISTFEHL(SUCHEN("amt";A3)));"x";"N/A")
B4	=WENN((ISTFEHL(SUCHEN("land";A4))*ISTFEHL(SUCHEN("amt";A4)));"x";"N/A")
B5	=WENN((ISTFEHL(SUCHEN("land";A5))*ISTFEHL(SUCHEN("amt";A5)));"x";"N/A")
B6	=WENN((ISTFEHL(SUCHEN("land";A6))*ISTFEHL(SUCHEN("amt";A6)));"x";"N/A")
B7	=WENN((ISTFEHL(SUCHEN("land";A7))*ISTFEHL(SUCHEN("amt";A7)));"x";"N/A")

 

krino,

ich danke dir vielmals! wenn du eine ruhige minute hast, könntest du hier bitte deine syntax erklären? der einsatz von istfehl*istfehl ist mir nicht ganz plausibel...aber es funktioniert :)

 

OK, ich versuch's mal...

Betrachte mal diese Formel:
=WENN(SUCHEN("amt";A1);"ja";"nein")

Man sollte meinen, daß sie "ja" oder "nein" ergibt. Tut sie aber nicht, denn wenn SUCHEN nicht findet, kommt eine Fehlermeldung und beendet die Abfrage.

SUCHEN und FINDEN sind eigentlich dafür gemacht, um festzustellen, an welcher Stelle in einer Zeichenkette sich eine Unter-Zeichenkette befindet. Eine Funktion, die mir sagt "ist enthalten" oder "ist nicht enthalten", gibt es schlicht nicht.

Man macht es also "von hinten durch die Brust ins Auge":

Wenn man Excel fragen läßt, ob sich eine Fehlermeldung ergibt oder nicht, dann hat diese Abfrage als Ergebnis WAHR oder FALSCH, bzw. 1 oder 0 (Boolesche Funktion). Damit kann in jedem Fall weitergerechnet werden.

Die beiden ISTFEHLs, die in meiner Formel miteinander multipliziert werden, ergeben beide für sich also 0 oder 1, je nach dem.
Die Multiplikation ist ein Ersatz für UND; man kriegt eine etwas kürzere Formel.

0 x 0 = 0
1 x 0 = 0
0 x 1 = 0
1 x 1 = 1

Auf deutsch: Dann und nur dann, wenn weder land noch amt gefunden wird, schreibe "x".
In den anderen drei Fällen schreibe "N/A".