Office: VERWEIS mit mehrfach vorkommenden Suchkriterium

Hallo,

um bei uns im Betrieb die Taxischeine zu automatisieren, wünsche ich mir, dass ab Zelle H11 alle Tage mit Datum angezeigt werden, die in der jeweiligen Namenszeile mit einem "x" markiert sind.

Hat jemand eine Lösung? :roll:

Vielen Dank im voraus,

Klaus Feldmann

 

Hi Klaus,

vielleicht eine Möglichkeit:


Tabelle1

	A	B	C	D	E	F	G
2			01.02.10	03.02.10	05.02.10	08.02.10	10.02.10
3	Name1		e	x	e	e	x
4	Name2		x	x	x	x	x
5	Name3		x	x	x	x	x
6	Name4		x	x	e	x	x
7	Name5		e	e	e	e	e

Tabelle1

	B	C
11	Name1	03.02.2010, 10.02.2010,
12	Name2	01.02.2010, 03.02.2010, 05.02.2010, 08.02.2010, 10.02.2010,
13	Name3	01.02.2010, 03.02.2010, 05.02.2010, 08.02.2010, 10.02.2010,
14	Name4	01.02.2010, 03.02.2010, 08.02.2010, 10.02.2010,
15	Name5

verwendete Formeln
Zelle	Formel
C11	=WENN(C3="x";TEXT(C$2;"TT.MM.JJJJ")&", ";"")&WENN(D3="x";TEXT(D$2;"TT.MM.JJJJ")&", ";"")&WENN(E3="x";TEXT(E$2;"TT.MM.JJJJ")&", ";"")&WENN(F3="x";TEXT(F$2;"TT.MM.JJJJ")&", ";"")&WENN(G3="x";TEXT(G$2;"TT.MM.JJJJ")&", ";"")
C12	=WENN(C4="x";TEXT(C$2;"TT.MM.JJJJ")&", ";"")&WENN(D4="x";TEXT(D$2;"TT.MM.JJJJ")&", ";"")&WENN(E4="x";TEXT(E$2;"TT.MM.JJJJ")&", ";"")&WENN(F4="x";TEXT(F$2;"TT.MM.JJJJ")&", ";"")&WENN(G4="x";TEXT(G$2;"TT.MM.JJJJ")&", ";"")
C13	=WENN(C5="x";TEXT(C$2;"TT.MM.JJJJ")&", ";"")&WENN(D5="x";TEXT(D$2;"TT.MM.JJJJ")&", ";"")&WENN(E5="x";TEXT(E$2;"TT.MM.JJJJ")&", ";"")&WENN(F5="x";TEXT(F$2;"TT.MM.JJJJ")&", ";"")&WENN(G5="x";TEXT(G$2;"TT.MM.JJJJ")&", ";"")
C14	=WENN(C6="x";TEXT(C$2;"TT.MM.JJJJ")&", ";"")&WENN(D6="x";TEXT(D$2;"TT.MM.JJJJ")&", ";"")&WENN(E6="x";TEXT(E$2;"TT.MM.JJJJ")&", ";"")&WENN(F6="x";TEXT(F$2;"TT.MM.JJJJ")&", ";"")&WENN(G6="x";TEXT(G$2;"TT.MM.JJJJ")&", ";"")
C15	=WENN(C7="x";TEXT(C$2;"TT.MM.JJJJ")&", ";"")&WENN(D7="x";TEXT(D$2;"TT.MM.JJJJ")&", ";"")&WENN(E7="x";TEXT(E$2;"TT.MM.JJJJ")&", ";"")&WENN(F7="x";TEXT(F$2;"TT.MM.JJJJ")&", ";"")&WENN(G7="x";TEXT(G$2;"TT.MM.JJJJ")&", ";"")

http://c.excelhost.de/c_beverly/getfile.php?id=122 Tabellendarstellung in Foren Version 5.5


Hinweis: bitte "" unberücksichtigt lassen (sind leere Zellen) - XHTML-Code wird von der Forensoftware nicht richtig umgesetzt.

Bis später,
Karin

 

Hallo,

vielen Dank schon mal für die schnelle Antwort.

Ich suche aber eine etwas elegantere Lösung (´tschuldigung), da ich bis zu 100 wechselnde Namen habe und der Zeitraum sich über den gesamten Monat erstreckt.

Ich stelle mir das so vor, dass ich auf dem nächsten Tabellenblatt einfach den Namen eingebe und dann alle mit "x" markierten Tage angezeigt bekomme.

Es funktioniert mit deiner Lösung, ist aber sehr aufwendig.

Vielen Dank, Klaus

 

Hallo!

Ich könnte eine Lösung mit Hilfszeile anbieten:

	A	B	C	D	E	F	G
1
2			01.02.2010	03.02.2010	05.02.2010	08.02.2010	10.02.2010
3	Name1	Taxi1	e	x	e	e	x
4	Name2	Taxi2	x	x	x	x	x
5	Name3	Taxi1	x	x	x	x	x
6	Name4	Taxi2	x	x	e	x	x
7	Name5	Taxi3	e	e	e	e	e
8
9
10			0	1	1	1	2
11		Name1	03.02.2010	10.02.2010

Zelle	Formel
C10	=ZÄHLENWENN(INDEX($C3:C7;VERGLEICH($B11;$A3:$A7;););"x")
D10	=ZÄHLENWENN(INDEX($C3:D7;VERGLEICH($B11;$A3:$A7;););"x")
E10	=ZÄHLENWENN(INDEX($C3:E7;VERGLEICH($B11;$A3:$A7;););"x")
F10	=ZÄHLENWENN(INDEX($C3:F7;VERGLEICH($B11;$A3:$A7;););"x")
G10	=ZÄHLENWENN(INDEX($C3:G7;VERGLEICH($B11;$A3:$A7;););"x")
C11	=WENN(SPALTE(A1)>MAX(10:10);"";INDEX(2:2;VERGLEICH(SPALTE(A1);10:10;)))
D11	=WENN(SPALTE(B1)>MAX(10:10);"";INDEX(2:2;VERGLEICH(SPALTE(B1);10:10;)))
E11	=WENN(SPALTE(C1)>MAX(10:10);"";INDEX(2:2;VERGLEICH(SPALTE(C1);10:10;)))
F11	=WENN(SPALTE(D1)>MAX(10:10);"";INDEX(2:2;VERGLEICH(SPALTE(D1);10:10;)))
G11	=WENN(SPALTE(E1)>MAX(10:10);"";INDEX(2:2;VERGLEICH(SPALTE(E1);10:10;)))

 

Hallo!

Und auch ohne Hilfszeile:

	A	B	C	D	E	F	G
1
2			01.02.2010	03.02.2010	05.02.2010	08.02.2010	10.02.2010
3	Name1	Taxi1	e	x	e	e	x
4	Name2	Taxi2	x	x	x	x	x
5	Name3	Taxi1	x	x	x	x	x
6	Name4	Taxi2	x	x	e	x	x
7	Name5	Taxi3	e	e	e	e	e
8
9
10
11		Name1	03.02.2010	10.02.2010

Zelle	Formel
C11	{=WENN(SPALTE(A1)>ZÄHLENWENN(INDEX($C3:$G7;VERGLEICH($B11;$A3:$A7;););"x");"";INDEX(2:2;KKLEINSTE(WENN(INDEX($C3:$G7;VERGLEICH($B11;$A3:$A7;);)="x";SPALTE($C:$G));SPALTE(A1))))}
D11	{=WENN(SPALTE(B1)>ZÄHLENWENN(INDEX($C3:$G7;VERGLEICH($B11;$A3:$A7;););"x");"";INDEX(2:2;KKLEINSTE(WENN(INDEX($C3:$G7;VERGLEICH($B11;$A3:$A7;);)="x";SPALTE($C:$G));SPALTE(B1))))}
E11	{=WENN(SPALTE(C1)>ZÄHLENWENN(INDEX($C3:$G7;VERGLEICH($B11;$A3:$A7;););"x");"";INDEX(2:2;KKLEINSTE(WENN(INDEX($C3:$G7;VERGLEICH($B11;$A3:$A7;);)="x";SPALTE($C:$G));SPALTE(C1))))}
F11	{=WENN(SPALTE(D1)>ZÄHLENWENN(INDEX($C3:$G7;VERGLEICH($B11;$A3:$A7;););"x");"";INDEX(2:2;KKLEINSTE(WENN(INDEX($C3:$G7;VERGLEICH($B11;$A3:$A7;);)="x";SPALTE($C:$G));SPALTE(D1))))}
G11	{=WENN(SPALTE(E1)>ZÄHLENWENN(INDEX($C3:$G7;VERGLEICH($B11;$A3:$A7;););"x");"";INDEX(2:2;KKLEINSTE(WENN(INDEX($C3:$G7;VERGLEICH($B11;$A3:$A7;);)="x";SPALTE($C:$G));SPALTE(E1))))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

 

Hallo Schatzi,

vielen, vielen Dank, es klappt!!!!

Nur wenn es Dir nichts ausmacht, aber kannst Du mir das kurz in Klartext übersetzen, versuch es eben auch zu verstehen, warum es funktioniert.

Vielen Dank, klaus

 

Hallo!

Der Formelteil, den du zitierst, ist eigentlich nur der Fehlerabfang, daher erkläre ich mal lieber den wirklich wichtigen Teil:

INDEX(2:2;KKLEINSTE(WENN(INDEX($C3:$G7;VERGLEICH($B11;$A3:$A7;);)="x";SPALTE($C:$G));SPALTE(A1)))

VERGLEICH(B11;A3:A7;) sucht in A3:A7 den Wert aus B11 und gibt die entsprechende Zeile zurück. Hier wird 1 ausgegeben, da B11 in der ersten Zeile von A3:A7 gefunden wird.

INDEX(C3:G7;1;) liefert die erste Zeile der Matrix C3:G7, also C3:G3.

WENN(C3:G3="x";SPALTE(C:G)) checkt, ob in den Zellen ein "x" steht.
Falls ja, dann wird die Spaltennummer ausgegeben.
Falls nein, dann wird FALSCH zurückgegeben.
Im konkreten Beispiel ergibt das das Array {FALSCH;4;FALSCH;FALSCH;7}

KKLEINSTE(Array;1) liefert den kleinsten Wert des Arrays (also 4),
KKLEINSTE(Array;2) liefert den zweitkleinsten Wert (also 7), usw.

INDEX(2:2;4) liefert den Wert aus der vierten Spalte von Zeile 2, also D2,
INDEX(2:2;7) liefert den Wert aus der siebten Spalte von Zeile 2, also G2, usw.

Ich hoffe, das war halbwegs verständlich erklärt!

 

Hallo schatzi,

vielen Dank für Deine Mühe, mit Deiner Hilfe blicke ich jetzt langsam durch und kann es sogar noch auf meine Bedürfnisse besser anpassen.

VG, Klaus Feldmann